media-gfx/feh: 3.10 version bump

Signed-off-by: Piotr Karbowski <slashbeast@gentoo.org>

2 files changed, 72 insertions, 0 deletions

diff --git a/media-gfx/feh/Manifest b/media-gfx/feh/Manifest
index d65a6c16b2c0..e03ad95dd8e0 100644
--- a/media-gfx/feh/Manifest
+++ b/media-gfx/feh/Manifest
@@ -1 +1,2 @@
+DIST feh-3.10.tar.bz2 2109603 BLAKE2B 2c3f52c7536110b5aef7e29fea366b502e39034b2de8b218faa071996f24ce0bf4b3283feeda96bc7542ce15bb6f1e68d2a2895a75949fe2e7c6ba08b779daee SHA512 9dc242a545590ab20847662613c289f4b78d44a1647c3696a65fd05c307628f869adf68fa3a66ca637b3974a309efb0b96d58a7aaa3d29725faf21208f40383e
 DIST feh-3.9.1.tar.bz2 2108873 BLAKE2B af559837224a90e403015648717cb9aa516d18bceb0a49a0635b471435370209c80b77a7a87f66b22c99615d44be0832a0d03152aabde72917417e5f992a5d8a SHA512 78682ec80df6b6655dbc18774ee95b3d68f1711a50129a9befb8adfb8c1a74aeede2493a35955687cdc2aa079978927727dac02543643418ef8deefa0d8c6d05
diff --git a/media-gfx/feh/feh-3.10.ebuild b/media-gfx/feh/feh-3.10.ebuild
new file mode 100644
index 000000000000..ccf4a73ffa70
--- /dev/null
+++ b/media-gfx/feh/feh-3.10.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit toolchain-funcs xdg-utils
+
+DESCRIPTION="A fast, lightweight imageviewer using imlib2"
+HOMEPAGE="https://feh.finalrewind.org/"
+SRC_URI="https://feh.finalrewind.org/${P}.tar.bz2"
+
+LICENSE="feh"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~riscv ~x86"
+IUSE="debug curl exif test xinerama inotify"
+RESTRICT="test" # Tests are broken.
+
+COMMON_DEPEND="
+	media-libs/imlib2[X,text(+)]
+	>=media-libs/libpng-1.2:0=
+	x11-libs/libX11
+	curl? ( net-misc/curl )
+	exif? ( media-libs/libexif )
+	xinerama? ( x11-libs/libXinerama )"
+RDEPEND="${COMMON_DEPEND}
+	media-libs/libjpeg-turbo:0"
+DEPEND="${COMMON_DEPEND}
+	x11-base/xorg-proto
+	x11-libs/libXt
+	test? (
+		>=dev-lang/perl-5.10
+		dev-perl/Test-Command
+		media-libs/imlib2[gif,jpeg,png]
+	)"
+
+PATCHES=( "${FILESDIR}"/${PN}-3.2-debug-cflags.patch )
+
+pkg_setup() {
+	use_feh() { usex $1 1 0; }
+
+	fehopts=(
+		PREFIX="${EPREFIX}"/usr
+		doc_dir='${main_dir}'/share/doc/${PF}
+		example_dir='${main_dir}'/share/doc/${PF}/examples
+		curl=$(use_feh curl)
+		debug=$(use_feh debug)
+		xinerama=$(use_feh xinerama)
+		exif=$(use_feh exif)
+		inotify=$(use_feh inotify)
+	)
+}
+
+src_compile() {
+	tc-export CC
+	emake "${fehopts[@]}"
+}
+
+src_install() {
+	emake "${fehopts[@]}" DESTDIR="${D}" install
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+}