media-libs/grilo: Version bump

Package-Manager: portage-2.3.0_rc1

2 files changed, 91 insertions, 0 deletions

diff --git a/media-libs/grilo/Manifest b/media-libs/grilo/Manifest
index 6e1f86a5f89a..57dec2ffde1c 100644
--- a/media-libs/grilo/Manifest
+++ b/media-libs/grilo/Manifest
@@ -1,2 +1,3 @@
 DIST grilo-0.2.15.tar.xz 627196 SHA256 6f5d2583250a68e76d281edaa08adb880d5a78ed46f9ecd22ae4715f1dd66815 SHA512 ac0a76d9075e5383fe1a56277b23986a8ec8e86f01f3f782ac7dc79539904712c22295c679243604b619f24088a1210622e0699b5601678264bd7651012ded3e WHIRLPOOL 6ea64142e1a4923d0ea3554ec3591f2c3dd6d30fdeaccde9a2a8e48d3e62ff1cd38b23a9eb39aa4c79c3a93c800e7dbfb4ad3a278e92d5ac57cb2e374a18f793
 DIST grilo-0.3.0.tar.xz 623032 SHA256 1fd1a87d606f56adb3086954baec3ea6e25d9ba3fb010f11d1d3ddc9ec66bc60 SHA512 d3d40896cb6ac4f6b02cce894dbf78a346464bab4eb8dbc60a0a0669db51269891071d9dd2c7a97b0befec82c5c1b6096f07d9060f2fbda0d557e2abacba6472 WHIRLPOOL 47d55a0ef09633ea3be8bd3171fe8390572526d82877fdcf5af3f8bedf878915fd49ff2181468ab7ba63fac9f1657fd7d2994088415f047a8f1647873f80ce8d
+DIST grilo-0.3.1.tar.xz 635304 SHA256 ebbdc61dc7920a8cac436895e8625a0ee64d6a4b352987fb5d361ef87243cd4c SHA512 c4815f7624d8f5c7d4de0a4b089161779a4b20d86ac9065d288b1706bb46779f2af2e9437bcddf61616922c3fcd2ed96e860f9598ee4a8213db77d61a84e5bd9 WHIRLPOOL d53d74581bf25566787a537478b75e2e06cdebe049940caa387f22c91ebbbe04f2eecdac65ede7564cad9eb5ea1c8d5e7fb0cb9883492be95f8e371e5a899f49
diff --git a/media-libs/grilo/grilo-0.3.1.ebuild b/media-libs/grilo/grilo-0.3.1.ebuild
new file mode 100644
index 000000000000..7917d8b92389
--- /dev/null
+++ b/media-libs/grilo/grilo-0.3.1.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python2_7 )
+VALA_MIN_API_VERSION="0.28"
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 python-any-r1 vala
+
+DESCRIPTION="A framework for easy media discovery and browsing"
+HOMEPAGE="https://wiki.gnome.org/Projects/Grilo"
+
+LICENSE="LGPL-2.1+"
+SLOT="0.3/0" # subslot is libgrilo-0.3 soname suffix
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="gtk examples +introspection +network playlist test vala"
+REQUIRED_USE="test? ( introspection )"
+
+RDEPEND="
+	>=dev-libs/glib-2.44:2
+	dev-libs/libxml2:2
+	net-libs/liboauth
+	gtk? ( >=x11-libs/gtk+-3:3 )
+	introspection? ( >=dev-libs/gobject-introspection-0.9:= )
+	network? ( >=net-libs/libsoup-2.41.3:2.4 )
+	playlist? ( >=dev-libs/totem-pl-parser-3.4.1 )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.10
+	>=dev-util/intltool-0.40
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+	test? (
+		$(python_gen_any_dep '
+			dev-python/pygobject:2[${PYTHON_USEDEP}]
+			dev-python/pygobject:3[${PYTHON_USEDEP}]')
+		media-plugins/grilo-plugins:0.2 )
+"
+# eautoreconf requires gnome-common
+
+python_check_deps() {
+	has_version "dev-python/pygobject:2[${PYTHON_USEDEP}]" && \
+		has_version "dev-python/pygobject:3[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	sed -e "s:GETTEXT_PACKAGE=grilo$:GETTEXT_PACKAGE=grilo-${SLOT}:" \
+		-i configure.ac configure || die "sed configure.ac configure failed"
+
+	# Don't build examples
+	sed -e '/SUBDIRS/s/examples//' \
+		-i Makefile.am -i Makefile.in || die
+
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# --enable-debug only changes CFLAGS, useless for us
+	gnome2_src_configure \
+		--disable-static \
+		--disable-debug \
+		$(use_enable gtk test-ui) \
+		$(use_enable introspection) \
+		$(use_enable network grl-net) \
+		$(use_enable playlist grl-pls) \
+		$(use_enable test tests) \
+		$(use_enable vala)
+}
+
+src_install() {
+	gnome2_src_install
+	# Upstream made this conditional on gtk-doc build...
+	DOC_MODULE_VERSION=${SLOT%/*} \
+	emake -C doc install DESTDIR="${ED}"
+
+	if use examples; then
+		# Install example code
+		insinto /usr/share/doc/${PF}/examples
+		doins "${S}"/examples/*.c
+	fi
+}