media-libs/openal: bump to 1.22.1, cleanup of dep versions

Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

2 files changed, 84 insertions, 0 deletions

diff --git a/media-libs/openal/Manifest b/media-libs/openal/Manifest
index 7550926d98a7..2aa401c4acf4 100644
--- a/media-libs/openal/Manifest
+++ b/media-libs/openal/Manifest
@@ -1 +1,2 @@
 DIST openal-soft-1.22.0.tar.bz2 606420 BLAKE2B c244c28a253168a6651230d31608449b885d3519d07bf66669befb51a5618c2cab6166496f69230969ff38982eb2c82e1e467a741376a2af38dfe59687143411 SHA512 1e3df371d126e19e369dd01e3c5e95d6a32b664adf54ee37836d51ca7bc829f275d945388d8a40a3ac92c1151380bd68bbab4f8a08f59ea67dd1bd9b9a1d0cbd
+DIST openal-soft-1.22.1.tar.bz2 606062 BLAKE2B a7f18ab35fc67488b31b62ed7049e70b22dadfdf9db1f0d8132bb5391be144611d82ea938692761909edd38ca3b3b9828b4f5a9eb8730c0a7673c346a18321c6 SHA512 1685890c358319a74a9fd1bd0333354d13194287697aa63d149323b98fc56837d574d7c74d2f54e0fdf5671c6effe5909fec54060e471a294d14dc82ba1dc38a
diff --git a/media-libs/openal/openal-1.22.1.ebuild b/media-libs/openal/openal-1.22.1.ebuild
new file mode 100644
index 000000000000..3e5f3a6b9593
--- /dev/null
+++ b/media-libs/openal/openal-1.22.1.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_ECLASS=cmake
+inherit cmake-multilib
+
+MY_P="${PN}-soft-${PV}"
+
+DESCRIPTION="A software implementation of the OpenAL 3D audio API"
+HOMEPAGE="https://www.openal-soft.org/"
+SRC_URI="https://www.openal-soft.org/openal-releases/${MY_P}.tar.bz2"
+
+# See https://github.com/kcat/openal-soft/blob/e0097c18b82d5da37248c4823fde48b6e0002cdd/BSD-3Clause
+# Some components are under BSD
+LICENSE="LGPL-2+ BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="
+	alsa coreaudio debug jack oss portaudio pulseaudio sdl sndio qt5
+	cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse4_1
+	cpu_flags_arm_neon
+"
+
+RDEPEND="
+	alsa? ( media-libs/alsa-lib[${MULTILIB_USEDEP}] )
+	jack? ( virtual/jack[${MULTILIB_USEDEP}] )
+	portaudio? ( media-libs/portaudio[${MULTILIB_USEDEP}] )
+	pulseaudio? ( media-sound/pulseaudio[${MULTILIB_USEDEP}] )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+	)
+	sdl? ( media-libs/libsdl2[${MULTILIB_USEDEP}] )
+	sndio? ( media-sound/sndio:=[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	oss? ( virtual/os-headers )"
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS=( alsoftrc.sample docs/env-vars.txt docs/hrtf.txt ChangeLog README.md )
+
+src_configure() {
+	# -DEXAMPLES=OFF to avoid FFmpeg dependency wrt #481670
+	my_configure() {
+		local mycmakeargs=(
+			-DALSOFT_REQUIRE_ALSA=$(usex alsa)
+			-DALSOFT_REQUIRE_COREAUDIO=$(usex coreaudio)
+			-DALSOFT_REQUIRE_JACK=$(usex jack)
+			-DALSOFT_REQUIRE_OSS=$(usex oss)
+			-DALSOFT_REQUIRE_PORTAUDIO=$(usex portaudio)
+			-DALSOFT_REQUIRE_PULSEAUDIO=$(usex pulseaudio)
+			-DALSOFT_REQUIRE_SDL2=$(usex sdl)
+			# See bug #809314 for getting both options for sndio
+			-DALSOFT_{BACKEND,REQUIRE}_SNDIO=$(usex sndio)
+			-DALSOFT_UTILS=$(multilib_is_native_abi && echo "ON" || echo "OFF")
+			-DALSOFT_NO_CONFIG_UTIL=$(usex qt5 "$(multilib_is_native_abi && echo "OFF" || echo "ON")" ON)
+			-DALSOFT_EXAMPLES=OFF
+		)
+
+		# Avoid unused variable warnings, bug #738240
+		if use amd64 || use x86 ; then
+			mycmakeargs+=(
+				-DALSOFT_CPUEXT_SSE=$(usex cpu_flags_x86_sse)
+				-DALSOFT_CPUEXT_SSE2=$(usex cpu_flags_x86_sse2)
+				-DALSOFT_CPUEXT_SSE4_1=$(usex cpu_flags_x86_sse4_1)
+			)
+		fi
+
+		if use arm || use arm64 ; then
+			mycmakeargs+=(
+				-DALSOFT_CPUEXT_NEON=$(usex cpu_flags_arm_neon)
+			)
+		fi
+
+		cmake_src_configure
+	}
+
+	multilib_parallel_foreach_abi my_configure
+}