media-sound/bluez-alsa: add 4.3.1, update live ebuild

Closes: https://bugs.gentoo.org/937876
Signed-off-by: Filip Kobierski <fkobi@pm.me>
Closes: https://github.com/gentoo/gentoo/pull/38470
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

3 files changed, 124 insertions, 3 deletions

diff --git a/media-sound/bluez-alsa/Manifest b/media-sound/bluez-alsa/Manifest
index b91d3a4d885a..4bd5395b8ab6 100644
--- a/media-sound/bluez-alsa/Manifest
+++ b/media-sound/bluez-alsa/Manifest
@@ -1 +1,2 @@
 DIST bluez-alsa-4.2.0.tar.gz 326233 BLAKE2B 7bea22d45e9897dd8dc62ee31bba381fb2e2dc616673d711ffb2144f9d03ff8312342f175256946cac828cc1ad04fc263ea11e0c0685e3e28e72c80357914f33 SHA512 1c8816d0baf031c5823fb49fac1409f4034f2f5cc8506ba1f377260cfc6437baa3f6ff1611eac72751f9d56c08f525dc43db05d30820baf394c75f3537d65162
+DIST bluez-alsa-4.3.1.tar.gz 334765 BLAKE2B 363eb8672132b0168d2e00dee7d0fc1f1933029412e35cb2d2d6fddb22b5b8b6bf225141fb770088e1f0cec0f4c78f9d55cef36186f1ecb9ce1465131204b141 SHA512 db9ac0ce58c03062d65eab2a0ccaed3ddd23de6eda3572ac0d038557c6bb7f243a3551eebae70593c519bc4db070923b9997a6cc4e6546000a2279c56fe1f2e5
diff --git a/media-sound/bluez-alsa/bluez-alsa-4.3.1.ebuild b/media-sound/bluez-alsa/bluez-alsa-4.3.1.ebuild
new file mode 100644
index 000000000000..bc53466fe635
--- /dev/null
+++ b/media-sound/bluez-alsa/bluez-alsa-4.3.1.ebuild
@@ -0,0 +1,120 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit autotools bash-completion-r1 multilib-minimal readme.gentoo-r1 systemd
+
+DESCRIPTION="Bluetooth Audio ALSA Backend"
+HOMEPAGE="https://github.com/arkq/bluez-alsa"
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/arkq/${PN}"
+else
+	SRC_URI="https://github.com/arkq/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="aac aptx debug hcitop lame ldac liblc3 man mpg123 ofono static-libs systemd test unwind upower"
+
+RESTRICT="!test? ( test )"
+
+# bluez-alsa does not directly link to upower but
+# is using the upower interface via dbus calls.
+RDEPEND="
+	>=dev-libs/glib-2.58.2[${MULTILIB_USEDEP}]
+	>=media-libs/alsa-lib-1.1.2[${MULTILIB_USEDEP}]
+	>=media-libs/sbc-1.5[${MULTILIB_USEDEP}]
+	>=net-wireless/bluez-5.51[${MULTILIB_USEDEP}]
+	sys-apps/dbus[${MULTILIB_USEDEP}]
+	sys-libs/readline:0=
+	aac? ( >=media-libs/fdk-aac-0.1.1:=[${MULTILIB_USEDEP}] )
+	aptx? ( >=media-libs/libfreeaptx-0.1.1 )
+	hcitop? (
+		dev-libs/libbsd
+		sys-libs/ncurses:0=
+	)
+	lame? ( media-sound/lame[${MULTILIB_USEDEP}] )
+	ldac? ( >=media-libs/libldac-2.0.0 )
+	liblc3? ( >=media-sound/liblc3-1.0.0 )
+	mpg123? ( media-sound/mpg123[${MULTILIB_USEDEP}] )
+	ofono? ( net-misc/ofono )
+	systemd? ( sys-apps/systemd )
+	unwind? ( sys-libs/libunwind[${MULTILIB_USEDEP}] )
+	upower? ( sys-power/upower )
+"
+DEPEND="${RDEPEND}
+	test? (
+		>=dev-libs/check-0.11.0
+		media-libs/libsndfile
+	)
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	virtual/pkgconfig
+	man? ( virtual/pandoc )
+"
+
+PATCHES=(
+	"${FILESDIR}/${P}-fix-include-freeaptx.patch"
+	# https://github.com/arkq/bluez-alsa/issues/718
+	"${FILESDIR}/${P}-test-alsa-midi-checkdev.patch"
+	# https://github.com/arkq/bluez-alsa/issues/717
+	"${FILESDIR}/${P}-ldpreload.patch"
+)
+
+DOC_CONTENTS="Users can use this service when they are members of the \"audio\" group."
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--enable-cli
+		--enable-faststream
+		--enable-midi
+		--enable-rfcomm
+		--with-bash-completion="$(get_bashcompdir)"
+		$(use_enable aac)
+		$(use_enable debug)
+		$(use_enable lame mp3lame)
+		$(use_enable man manpages)
+		$(use_enable mpg123)
+		$(use_enable static-libs static)
+		$(use_enable systemd)
+		$(use_enable test)
+		$(use_with systemd systemdsystemunitdir $(systemd_get_systemunitdir))
+		$(multilib_native_use_enable aptx)
+		$(multilib_native_use_enable aptx aptx-hd)
+		$(multilib_native_use_with aptx libfreeaptx)
+		$(multilib_native_use_enable hcitop)
+		$(multilib_native_use_enable ldac)
+		$(multilib_native_use_enable liblc3 lc3-swb)
+		$(multilib_native_use_enable ofono)
+		$(multilib_native_use_enable upower)
+		$(use_with unwind libunwind)
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	default
+	find "${ED}" -type f -name "*.la" -delete || die
+
+	newinitd "${FILESDIR}"/bluealsa-init.d bluealsa
+	newconfd "${FILESDIR}"/bluealsa-conf.d-2-r1 bluealsa
+
+	# Add config file to alsa datadir as well to preserve changes in /etc
+	insinto "/usr/share/alsa/alsa.conf.d/"
+	doins "src/asound/20-bluealsa.conf.in"
+
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	readme.gentoo_print_elog
+}
diff --git a/media-sound/bluez-alsa/bluez-alsa-9999.ebuild b/media-sound/bluez-alsa/bluez-alsa-9999.ebuild
index 188dc69cbacd..88b416794de8 100644
--- a/media-sound/bluez-alsa/bluez-alsa-9999.ebuild
+++ b/media-sound/bluez-alsa/bluez-alsa-9999.ebuild
@@ -5,13 +5,13 @@ EAPI=8
 inherit autotools bash-completion-r1 multilib-minimal readme.gentoo-r1 systemd
 
 DESCRIPTION="Bluetooth Audio ALSA Backend"
-HOMEPAGE="https://github.com/Arkq/bluez-alsa"
+HOMEPAGE="https://github.com/arkq/bluez-alsa"
 
 if [[ ${PV} == "9999" ]] ; then
 	inherit git-r3
-	EGIT_REPO_URI="https://github.com/Arkq/${PN}"
+	EGIT_REPO_URI="https://github.com/arkq/${PN}"
 else
-	SRC_URI="https://github.com/Arkq/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	SRC_URI="https://github.com/arkq/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
 	KEYWORDS="~amd64 ~arm64 ~x86"
 fi