media-video/totem-3.32: ebuild touchups

* Port to EAPI-7 (BDEPEND + removal of obsolete gnome2_icon_cache_update).
* Drop USE=nautilus and always build save-file plugin (it communicates
  with nautilus via dbus only at runtime).
* Fix tests (an actual first test was added, needing virtx)
* Drop X11 requirements - it will add minimal things for X automagically
  at build time based on gtk+[X] being around or not during build; which
  is the unfortunate status quo elsewhere as well. This change however
  should allow using totem on a pure-wayland system. The libX11 dep is
  also dropped for this, but we can rely on it being there whenever it
  is needed.
* User help got ported to pure its, so now docbook-xml-dtd:4.5 should
  only be necessary for gtk-doc.
* Resort enabled plugin list and drop obsolete comments.
* Restore -Dgst-inspect=false to avoid sandbox issues
* Drop unnecessary src_prepare(), as only xdg_src_prepare is called now,
  which will be the case without src_prepare() in ebuild too.

Package-Manager: Portage-2.3.69, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

1 files changed, 21 insertions, 27 deletions

diff --git a/media-video/totem/totem-3.32.1.ebuild b/media-video/totem/totem-3.32.1-r1.ebuild
index 1046a2c110e9..b06daab34a8b 100644
--- a/media-video/totem/totem-3.32.1.ebuild
+++ b/media-video/totem/totem-3.32.1-r1.ebuild
@@ -1,32 +1,33 @@
 # Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=7
 PYTHON_COMPAT=( python{3_5,3_6} )
 PYTHON_REQ_USE="threads"
 
-inherit gnome.org gnome2-utils meson xdg python-single-r1
+inherit gnome.org gnome2-utils meson virtualx xdg python-single-r1
 
 DESCRIPTION="Media player for GNOME"
 HOMEPAGE="https://wiki.gnome.org/Apps/Videos"
 
 LICENSE="GPL-2+ LGPL-2+"
 SLOT="0"
-IUSE="cdr gtk-doc +introspection lirc nautilus +python test"
+IUSE="cdr gtk-doc +introspection lirc +python test"
 # see bug #359379
 REQUIRED_USE="
 	python? ( introspection ${PYTHON_REQUIRED_USE} )
 "
+RESTRICT="!test? ( test )"
 
 KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
 
 # FIXME:
 # Runtime dependency on gnome-session-2.91
-COMMON_DEPEND="
+DEPEND="
 	>=dev-libs/glib-2.43.4:2
-	>=x11-libs/gtk+-3.19.4:3[X,introspection?]
+	>=x11-libs/gtk+-3.19.4:3[introspection?]
 	>=media-libs/gstreamer-1.6.0:1.0
-	>=media-libs/gst-plugins-base-1.6.0:1.0[X,pango]
+	>=media-libs/gst-plugins-base-1.6.0:1.0[pango]
 	>=media-libs/gst-plugins-good-1.6.0:1.0
 	>=media-libs/grilo-0.3.0:0.3[playlist]
 	>=dev-libs/libpeas-1.1.0[gtk]
@@ -36,19 +37,17 @@ COMMON_DEPEND="
 	>=media-libs/clutter-gtk-1.8.1:1.0
 	gnome-base/gnome-desktop:3=
 	gnome-base/gsettings-desktop-schemas
-	x11-libs/libX11
 	>=x11-libs/cairo-1.14
 	x11-libs/gdk-pixbuf:2
 	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
 
 	cdr? ( >=dev-libs/libxml2-2.6:2 )
 	lirc? ( app-misc/lirc )
-	nautilus? ( >=gnome-base/nautilus-2.91.3 )
 	python? (
 		${PYTHON_DEPS}
 		>=dev-python/pygobject-2.90.3:3[${PYTHON_USEDEP}] )
 "
-RDEPEND="${COMMON_DEPEND}
+RDEPEND="${DEPEND}
 	media-plugins/grilo-plugins:0.3
 	media-plugins/gst-plugins-meta:1.0
 	media-plugins/gst-plugins-taglib:1.0
@@ -57,10 +56,10 @@ RDEPEND="${COMMON_DEPEND}
 		>=dev-libs/libpeas-1.1.0[python,${PYTHON_USEDEP}]
 		dev-python/dbus-python[${PYTHON_USEDEP}] )
 "
-DEPEND="${COMMON_DEPEND}
+BDEPEND="
 	dev-lang/perl
-	app-text/docbook-xml-dtd:4.5
-	gtk-doc? ( >=dev-util/gtk-doc-1.14 )
+	gtk-doc? ( >=dev-util/gtk-doc-1.14
+		app-text/docbook-xml-dtd:4.5 )
 	dev-util/glib-utils
 	dev-util/itstool
 	>=sys-devel/gettext-0.19.8
@@ -68,7 +67,6 @@ DEPEND="${COMMON_DEPEND}
 	x11-base/xorg-proto
 "
 # perl for pod2man
-# docbook-xml-dtd is needed for user doc
 # Prevent dev-python/pylint dep, bug #482538
 
 PATCHES=(
@@ -80,21 +78,14 @@ pkg_setup() {
 	use python && python-single-r1_pkg_setup
 }
 
-src_prepare() {
-	xdg_src_prepare
-}
-
 src_configure() {
-	# Disabled: sample-python, zeitgeist-dp
-	# brasero-disc-recorder and gromit require gtk+[X], but totem itself does
-	# for now still too, so no point in optionality based on that yet.
+	# Disabled: samplepython
 	local plugins="apple-trailers,autoload-subtitles"
-	plugins+=",im-status,media-player-keys"
-	plugins+=",properties,recent,screensaver,screenshot"
-	plugins+=",skipto,variable-rate,vimeo,rotation"
+	plugins+=",im-status,media-player-keys,properties"
+	plugins+=",recent,rotation,save-file,screensaver,screenshot"
+	plugins+=",skipto,variable-rate,vimeo"
 	use cdr && plugins+=",brasero-disc-recorder"
 	use lirc && plugins+=",lirc"
-	use nautilus && plugins+=",save-file"
 	use python && plugins+=",dbusservice,pythonconsole,opensubtitles"
 
 	local emesonargs=(
@@ -103,6 +94,7 @@ src_configure() {
 		-Dwith-plugins=${plugins}
 		$(meson_use gtk-doc enable-gtk-doc)
 		-Denable-introspection=$(usex introspection yes no)
+		-Dgst-inspect=false
 	)
 	meson_src_configure
 }
@@ -110,18 +102,20 @@ src_configure() {
 src_install() {
 	meson_src_install
 	if use python ; then
-		python_optimize "${ED}"usr/$(get_libdir)/totem/plugins/
+		python_optimize "${ED}"/usr/$(get_libdir)/totem/plugins/
 	fi
 }
 
 pkg_postinst() {
 	xdg_pkg_postinst
-	gnome2_icon_cache_update
 	gnome2_schemas_update
 }
 
 pkg_postrm() {
 	xdg_pkg_postrm
-	gnome2_icon_cache_update
 	gnome2_schemas_update
 }
+
+src_test() {
+	virtx meson_src_test
+}