net-im/qtox: drop IUSE="notification" due to a deprecated dependency

Upstream had some work done towards moving away, but the project
has been archived.

Bug: https://bugs.gentoo.org/877307
Bug: https://bugs.gentoo.org/877311
Signed-off-by: Jimi Huotari <chiitoo@gentoo.org>

2 files changed, 93 insertions, 4 deletions

diff --git a/net-im/qtox/qtox-1.17.6-r2.ebuild b/net-im/qtox/qtox-1.17.6-r2.ebuild
new file mode 100644
index 000000000000..26c612874adc
--- /dev/null
+++ b/net-im/qtox/qtox-1.17.6-r2.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake xdg
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/qTox/qTox.git"
+else
+	MY_P="qTox-${PV}"
+	SRC_URI="https://github.com/qTox/qTox/releases/download/v${PV}/v${PV}.tar.gz -> ${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/qTox"
+fi
+
+DESCRIPTION="Instant messaging client using the encrypted p2p Tox protocol"
+HOMEPAGE="https://qtox.github.io/"
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="+spellcheck test X"
+
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	virtual/pkgconfig
+"
+RDEPEND="
+	dev-db/sqlcipher
+	dev-libs/libsodium:=
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5[gif(+),jpeg,png,X(-)]
+	dev-qt/qtnetwork:5
+	dev-qt/qtopengl:5
+	dev-qt/qtsvg:5
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	media-gfx/qrencode:=
+	media-libs/libexif
+	media-libs/openal
+	media-video/ffmpeg:=[webp,v4l]
+	>=net-libs/tox-0.2.13:=[av]
+	spellcheck? ( kde-frameworks/sonnet:5 )
+	X? (
+		x11-libs/libX11
+		x11-libs/libXScrnSaver
+	)
+"
+DEPEND="${RDEPEND}
+	test? ( dev-qt/qttest:5 )
+	X? ( x11-base/xorg-proto )
+"
+
+DOCS=( CHANGELOG.md README.md doc/user_manual_en.md )
+
+src_prepare() {
+	cmake_src_prepare
+
+	# bug 628574
+	if ! use test; then
+		sed -i CMakeLists.txt -e "/include(Testing)/d" || die
+		sed -i cmake/Dependencies.cmake -e "/find_package(Qt5Test/d" || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPLATFORM_EXTENSIONS=$(usex X)
+		-DUPDATE_CHECK=OFF
+		-DUSE_CCACHE=OFF
+		-DSPELL_CHECK=$(usex spellcheck)
+		-DSVGZ_ICON=ON
+		-DASAN=OFF
+		-DDESKTOP_NOTIFICATIONS=OFF
+		-DSTRICT_OPTIONS=OFF
+	)
+
+	[[ ${PV} != 9999 ]] && mycmakeargs+=( -DGIT_DESCRIBE=${PV} )
+
+	cmake_src_configure
+}
+
+src_test() {
+	# The excluded tests require network access.
+	cmake_src_test -E "test_(bsu|core)"
+}
diff --git a/net-im/qtox/qtox-9999.ebuild b/net-im/qtox/qtox-9999.ebuild
index fe8a64494ea3..efe18c5045f9 100644
--- a/net-im/qtox/qtox-9999.ebuild
+++ b/net-im/qtox/qtox-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2022 Gentoo Authors
+# Copyright 1999-2023 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=8
@@ -20,7 +20,7 @@ HOMEPAGE="https://qtox.github.io/"
 
 LICENSE="GPL-3+"
 SLOT="0"
-IUSE="notification +spellcheck test X"
+IUSE="+spellcheck test X"
 
 RESTRICT="!test? ( test )"
 
@@ -46,7 +46,6 @@ RDEPEND="
 	>=net-libs/tox-0.2.13:=[av]
 	>=net-libs/toxext-0.0.3
 	>=net-libs/tox_extension_messages-0.0.3
-	notification? ( x11-libs/snorenotify )
 	spellcheck? ( kde-frameworks/sonnet:5 )
 	X? (
 		x11-libs/libX11
@@ -78,7 +77,7 @@ src_configure() {
 		-DSPELL_CHECK=$(usex spellcheck)
 		-DSVGZ_ICON=ON
 		-DASAN=OFF
-		-DDESKTOP_NOTIFICATIONS=$(usex notification)
+		-DDESKTOP_NOTIFICATIONS=OFF
 		-DSTRICT_OPTIONS=OFF
 	)