net-misc/freerdp: new snapshot for 2.0.0

2 files changed, 116 insertions, 0 deletions

diff --git a/net-misc/freerdp/Manifest b/net-misc/freerdp/Manifest
index 5de8bd79f790..5d06680883e3 100644
--- a/net-misc/freerdp/Manifest
+++ b/net-misc/freerdp/Manifest
@@ -1 +1,2 @@
 DIST freerdp-1.2.1_pre20150326.tar.gz 6146857 SHA256 c0646f224ea30a485e165fb31eb8a039af2ca3f257cdf784b319e1b5c13e0425 SHA512 ca1499d56ecb9c9bc624de2ecc976eb9633b795050ac01e16fcc9e0a8951d274cc63644a0e2b830e75f66de894f6a22274864fd20a9351834f6d664874e65ec8 WHIRLPOOL 1ff6ce70d454a7e0cbb3cd4fbafe1fb4191dadc3b2f8a6dbff10d8c725b8fc2838a863837d9b01f6daa670483fe40266fb57569904ad8ac8503549d6605c9e64
+DIST freerdp-2.0.0_pre20160722.tar.gz 6412437 SHA256 17d6b7b9ec6bcfbb78d72ecda034e1ed6bdae4f95a8100297096a5e5e095463a SHA512 3b67de8f31740ccba0ce59f0035328bda6c1602e6197a31008bdd5bcab15e85f473c6c4eca5cb87670b34fa174e4b0da21a7f75be99686df485bb7f9cda6f589 WHIRLPOOL b494070185435da954e9d998915fbe4b47286c803c03bc4839afa583082434fc4d51776b62db27255b9ba62ecb8ef9c95af96e2920414e0fff9b27dceecb4cd4
diff --git a/net-misc/freerdp/freerdp-2.0.0_pre20160722.ebuild b/net-misc/freerdp/freerdp-2.0.0_pre20160722.ebuild
new file mode 100644
index 000000000000..f11763bf6996
--- /dev/null
+++ b/net-misc/freerdp/freerdp-2.0.0_pre20160722.ebuild
@@ -0,0 +1,115 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="6"
+
+inherit cmake-utils
+
+if [[ ${PV} != 9999 ]]; then
+	inherit vcs-snapshot
+	COMMIT="5b2455f3147aca395a441fc65b602938600f0788"
+	SRC_URI="https://github.com/FreeRDP/FreeRDP/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~x86"
+else
+	inherit git-r3
+	SRC_URI=""
+	EGIT_REPO_URI="git://github.com/FreeRDP/FreeRDP.git
+		https://github.com/FreeRDP/FreeRDP.git"
+fi
+
+DESCRIPTION="Free implementation of the Remote Desktop Protocol"
+HOMEPAGE="http://www.freerdp.com/"
+
+LICENSE="Apache-2.0"
+SLOT="0/2"
+IUSE="alsa +client cpu_flags_x86_sse2 cups debug doc ffmpeg gstreamer jpeg libressl neon pulseaudio server smartcard systemd test usb wayland X xinerama xv"
+
+RDEPEND="
+	!libressl? ( dev-libs/openssl:0 )
+	libressl? ( dev-libs/libressl )
+	sys-libs/zlib:0
+	alsa? ( media-libs/alsa-lib )
+	cups? ( net-print/cups )
+	client? (
+		usb? (
+			virtual/libudev:0=
+			sys-apps/util-linux:0=
+			dev-libs/dbus-glib:0=
+			virtual/libusb:1=
+		)
+		X? (
+			x11-libs/libXcursor
+			x11-libs/libXext
+			x11-libs/libXi
+			x11-libs/libXrender
+			xinerama? ( x11-libs/libXinerama )
+			xv? ( x11-libs/libXv )
+		)
+	)
+	ffmpeg? ( virtual/ffmpeg )
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+		x11-libs/libXrandr
+	)
+	jpeg? ( virtual/jpeg:0 )
+	pulseaudio? ( media-sound/pulseaudio )
+	server? (
+		X? (
+			x11-libs/libXcursor
+			x11-libs/libXdamage
+			x11-libs/libXext
+			x11-libs/libXfixes
+			xinerama? ( x11-libs/libXinerama )
+		)
+	)
+	smartcard? ( sys-apps/pcsc-lite )
+	systemd? ( sys-apps/systemd:0= )
+	wayland? (
+		dev-libs/wayland
+		x11-libs/libxkbcommon
+	)
+	X? (
+		x11-libs/libX11
+		x11-libs/libxkbfile
+	)
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	client? ( X? ( doc? (
+		app-text/docbook-xml-dtd:4.1.2
+		app-text/xmlto
+	) ) )
+"
+
+DOCS=( README )
+
+src_configure() {
+	onoff() {
+		usex "$1" ON OFF
+	}
+	local mycmakeargs=(
+		-DWITH_ALSA=$(onoff alsa)
+		-DWITH_CLIENT=$(onoff client)
+		-DWITH_CUPS=$(onoff cups)
+		-DWITH_DEBUG_ALL=$(onoff debug)
+		-DWITH_MANPAGES=$(onoff doc)
+		-DWITH_FFMPEG=$(onoff ffmpeg)
+		-DWITH_GSTREAMER_1_0=$(onoff gstreamer)
+		-DWITH_JPEG=$(onoff jpeg)
+		-DWITH_NEON=$(onoff neon)
+		-DWITH_PULSE=$(onoff pulseaudio)
+		-DWITH_SERVER=$(onoff server)
+		-DWITH_PCSC=$(onoff smartcard)
+		-DWITH_LIBSYSTEMD=$(onoff systemd)
+		-DWITH_SSE2=$(onoff cpu_flags_x86_sse2)
+		-DCHANNEL_URBDRC=$(onoff usb)
+		-DWITH_X11=$(onoff X)
+		-DWITH_XINERAMA=$(onoff xinerama)
+		-DWITH_XV=$(onoff xv)
+		-DBUILD_TESTING=$(onoff test)
+		-DWITH_WAYLAND=$(onoff wayland)
+	)
+	cmake-utils_src_configure
+}