net-vpn/logmein-hamachi: version bump, LICENSE update, ebuild cleanup

Closes: https://bugs.gentoo.org/661688
Closes: https://github.com/gentoo/gentoo/pull/9298
Package-Manager: Portage-2.3.40, Repoman-2.3.9

3 files changed, 71 insertions, 5 deletions

diff --git a/net-vpn/logmein-hamachi/Manifest b/net-vpn/logmein-hamachi/Manifest
index f96497f479a9..8ef27ad859db 100644
--- a/net-vpn/logmein-hamachi/Manifest
+++ b/net-vpn/logmein-hamachi/Manifest
@@ -1,2 +1,4 @@
 DIST logmein-hamachi-2.1.0.174-x64.tgz 1367599 BLAKE2B 338ccdcf8ab6d94bd689908dd22522c34a3a40206181dd175d9e40c42bbb6d7d2073378955e37ec1e884dcdc0013c8a9eb8ee83978d93b8fabc3218bf16a181f SHA512 d1d81a15f209361f66636035f7fd8a010657dbc0712a56ae240e102f083e9b04629c852cbd4259229166c297a1cd116da07e5bdeac63795cacba8fd7e3021050
 DIST logmein-hamachi-2.1.0.174-x86.tgz 1290587 BLAKE2B efcb3629097822360c126a4951293f43a885925f9c273e0f70b71f6613b6c7b8d78253e5d0d1a9f63218536359d92095b60ceacff2579854f0102c44c8dd7d66 SHA512 0f8da40d6508dab71680a74065649d51288c345849f74c7e2682040b720536f5324d142690aa879f9c5e8f1717654ab93357f4b960a567f5b584609bd814e82f
+DIST logmein-hamachi-2.1.0.198-x64.tgz 1332004 BLAKE2B 72447c4a87e32aaafc424abcfece72645881e8da0cfd20f12e6e4f9470005c9f735588269541c1ef12cc92cf287cd7804f14ec32e56ac860e6d034271f688b9d SHA512 7ac7fb64c2ae1864f023138778f05681f852a5b4289638ca4905bf9c4ef7612e657b3641193abf33900e145c667391e9d438aadfcdbc710c0be5790816777d8f
+DIST logmein-hamachi-2.1.0.198-x86.tgz 1242014 BLAKE2B 41c2efc83f2dac62b18286a10f219e9df479473b403f10ac2306350694435804725e91053c841ac06b4414264071e39dbc26caaeea500de8815dce681a01aa5b SHA512 67a465359ebe11c572308f38d6a0221bbd61b1a96eddb5235c112db6c060f392a9d05cb88b7ef82d6011b468e89bc72269e39bf421b656a815df4c9c1ff19113
diff --git a/net-vpn/logmein-hamachi/logmein-hamachi-2.1.0.174.ebuild b/net-vpn/logmein-hamachi/logmein-hamachi-2.1.0.174.ebuild
index d340b702289f..edef3a07d1af 100644
--- a/net-vpn/logmein-hamachi/logmein-hamachi-2.1.0.174.ebuild
+++ b/net-vpn/logmein-hamachi/logmein-hamachi-2.1.0.174.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
@@ -9,7 +9,7 @@ HOMEPAGE="https://www.vpn.net/"
 SRC_URI="x86?	( https://www.vpn.net/installers/${P}-x86.tgz )
 	amd64?	( https://www.vpn.net/installers/${P}-x64.tgz )"
 
-LICENSE="LogMeIn"
+LICENSE="LogMeIn-2013"
 SLOT="0"
 KEYWORDS="-* ~amd64 ~x86"
 IUSE=""
@@ -30,16 +30,16 @@ pkg_setup() {
 
 src_unpack() {
 	unpack ${A}
-	mv "${P}-$(use x86 && echo x86 || echo x64)" "${S}" || die
+	mv "${P}-$(usex x86 x86 x64)" "${S}" || die
 }
 
 src_install() {
 	into /opt/${PN}
 	dobin hamachid dnsup dnsdown
-	dosym /opt/${PN}/bin/hamachid /usr/bin/hamachi
+	dosym ../../opt/${PN}/bin/hamachid /usr/bin/hamachi
 
 	# Config and log directory
-	dodir /var/lib/${PN}
+	keepdir /var/lib/${PN}
 
 	newconfd "${FILESDIR}"/${PN}.confd ${PN}
 	newinitd "${FILESDIR}"/${PN}.initd ${PN}
diff --git a/net-vpn/logmein-hamachi/logmein-hamachi-2.1.0.198.ebuild b/net-vpn/logmein-hamachi/logmein-hamachi-2.1.0.198.ebuild
new file mode 100644
index 000000000000..d5d603fe4559
--- /dev/null
+++ b/net-vpn/logmein-hamachi/logmein-hamachi-2.1.0.198.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit linux-info systemd
+
+DESCRIPTION="LogMeIn Hamachi VPN tunneling engine"
+HOMEPAGE="https://www.vpn.net/"
+SRC_URI="x86?	( https://www.vpn.net/installers/${P}-x86.tgz )
+	amd64?	( https://www.vpn.net/installers/${P}-x64.tgz )"
+
+LICENSE="LogMeIn"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+IUSE=""
+
+RDEPEND="!net-misc/hamachi"
+
+RESTRICT="mirror"
+
+QA_PREBUILT="/opt/${PN}/bin/hamachid"
+QA_PRESTRIPPED="/opt/${PN}/bin/hamachid"
+QA_WX_LOAD="/opt/${PN}/bin/hamachid"
+
+pkg_setup() {
+	einfo "Checking your kernel configuration for TUN/TAP support."
+	CONFIG_CHECK="~TUN"
+	check_extra_config
+}
+
+src_unpack() {
+	unpack ${A}
+	mv "${P}-$(usex x86 x86 x64)" "${S}" || die
+}
+
+src_install() {
+	into /opt/${PN}
+	dobin hamachid dnsup dnsdown
+	dosym ../../opt/${PN}/bin/hamachid /usr/bin/hamachi
+
+	# Config and log directory
+	keepdir /var/lib/${PN}
+
+	newconfd "${FILESDIR}"/${PN}.confd ${PN}
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	systemd_dounit "${FILESDIR}"/${PN}.service
+
+	dodoc CHANGES README
+}
+
+pkg_postinst() {
+	elog "LogMeIn Hamachi2 is installed."
+	elog "Consult the README file on how to configure your client."
+	elog "You can run the client 'hamachi' as root,"
+	elog "or as a user if you add a newline terminated line:"
+	elog "Ipc.User      <login name>"
+	elog "to the file '/var/lib/${PN}/h2-engine-override.cfg'"
+	elog "and restart the daemon with"
+	elog "/etc/init.d/${PN} restart"
+	elog "or:"
+	elog "systemctl restart ${PN}"
+	elog "To enable auto-login when the service starts set a nickname in"
+	elog "/etc/conf.d/${PN} (only supported using openRC)"
+}