proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 56 insertions, 0 deletions

diff --git a/sci-chemistry/pymol-apbs-plugin/pymol-apbs-plugin-2.1_p26.ebuild b/sci-chemistry/pymol-apbs-plugin/pymol-apbs-plugin-2.1_p26.ebuild
new file mode 100644
index 000000000000..5f4c1affc3de
--- /dev/null
+++ b/sci-chemistry/pymol-apbs-plugin/pymol-apbs-plugin-2.1_p26.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit eutils python-r1
+
+MY_PV="${PV##*_p}"
+
+DESCRIPTION="APBS plugin for pymol"
+HOMEPAGE="http://sourceforge.net/projects/pymolapbsplugin/"
+SRC_URI="http://sourceforge.net/p/pymolapbsplugin/code/${MY_PV}/tree/trunk/src/apbsplugin.py?format=raw -> ${P}.py"
+
+SLOT="0"
+KEYWORDS="amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"
+LICENSE="pymol"
+IUSE=""
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	sci-chemistry/apbs
+	sci-chemistry/pdb2pqr
+	!<sci-chemistry/pymol-1.2.2-r1"
+DEPEND="${RDEPEND}"
+
+src_unpack() {
+	mkdir "${S}"
+	cp "${DISTDIR}"/${P}.py "${S}"/
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-tcltk8.6.patch
+	python_copy_sources
+}
+
+src_install() {
+	installation() {
+		cd "${BUILD_DIR}" || die
+		sed \
+			-e "s:^APBS_BINARY_LOCATION.*:APBS_BINARY_LOCATION = \"${EPREFIX}/usr/bin/apbs\":g" \
+			-e "s:^APBS_PSIZE_LOCATION.*:APBS_PSIZE_LOCATION = \"${EPREFIX}/$(python_get_sitedir)/pdb2pqr/src/\":g" \
+			-e "s:^APBS_PDB2PQR_LOCATION.*:APBS_PDB2PQR_LOCATION = \"${EPREFIX}/$(python_get_sitedir)/pdb2pqr/\":g" \
+			-e "s:^TEMPORARY_FILE_DIR.*:TEMPORARY_FILE_DIR = \"./\":g" \
+			${P}.py > apbs_tools.py
+
+		python_moduleinto pmg_tk/startup
+		python_domodule apbs_tools.py || die
+		python_optimize
+	}
+	python_parallel_foreach_impl installation
+}