sci-libs/indilib: Drop 1.9.6 (r0)

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

1 files changed, 0 insertions, 69 deletions

diff --git a/sci-libs/indilib/indilib-1.9.6.ebuild b/sci-libs/indilib/indilib-1.9.6.ebuild
deleted file mode 100644
index b6d000763a3b..000000000000
--- a/sci-libs/indilib/indilib-1.9.6.ebuild
+++ /dev/null
@@ -1,69 +0,0 @@
-# Copyright 1999-2022 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-inherit cmake udev
-
-DESCRIPTION="INDI Astronomical Control Protocol library"
-HOMEPAGE="https://www.indilib.org/"
-SRC_URI="https://github.com/${PN}/${PN/lib/}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-S="${WORKDIR}/${P/lib/}"
-
-LICENSE="BSD GPL-2+ LGPL-2+ LGPL-2.1+"
-SLOT="0/1"
-KEYWORDS="~amd64 ~ppc ~ppc64 ~riscv ~x86"
-IUSE="ogg rtlsdr test websocket"
-
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	net-misc/curl
-	sci-libs/cfitsio:=
-	sci-libs/fftw:3.0=
-	sci-libs/gsl:=
-	sci-libs/libnova:=
-	sys-libs/zlib
-	virtual/jpeg:0
-	virtual/libusb:0
-	ogg? (
-		media-libs/libogg
-		media-libs/libtheora
-	)
-	rtlsdr? ( net-wireless/rtl-sdr )
-	websocket? ( dev-libs/boost:= )
-"
-DEPEND="${RDEPEND}
-	kernel_linux? ( sys-kernel/linux-headers )
-	test? ( >=dev-cpp/gtest-1.8.0 )
-	websocket? ( dev-cpp/websocketpp )
-"
-
-src_configure() {
-	local mycmakeargs=(
-		-DINDI_BUILD_QT5_CLIENT=OFF
-		-DUDEVRULES_INSTALL_DIR="${EPREFIX}$(get_udevdir)"/rules.d
-		$(cmake_use_find_package ogg OggTheora)
-		$(cmake_use_find_package rtlsdr RTLSDR)
-		-DINDI_BUILD_UNITTESTS=$(usex test)
-		-DINDI_BUILD_WEBSOCKET=$(usex websocket)
-	)
-
-	cmake_src_configure
-}
-
-src_test() {
-	local myctestargs=()
-
-	if use ppc || use ppc64 || use sparc ; then
-		# Broken on big endian for quite some time.
-		# Reported upstream: file needs to be replaced w/ a normal library
-		# for b64.
-		# bug #763126
-		myctestargs+=(
-			-E "(test_base64)"
-		)
-	fi
-
-	BUILD_DIR="${BUILD_DIR}"/test cmake_src_test
-}