www-client/opera: automated bump (105.0.4970.48)

Signed-off-by: Matt Jolly <Matt.Jolly@footclan.ninja>
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 171 insertions, 0 deletions

diff --git a/www-client/opera/Manifest b/www-client/opera/Manifest
index 39469ce324bf..3bac566fa768 100644
--- a/www-client/opera/Manifest
+++ b/www-client/opera/Manifest
@@ -1,2 +1,3 @@
 DIST opera-ffmpeg-codecs-114.0.5735.9.tar.xz 1315192 BLAKE2B ef9a0cfc8c30ac0a837863644f3c2d5e78059575e2b8f6fda9253304f4815a39d021602e802dac7e1d5a1685aa5015a02019c4a0399f0bdc81136f956cc1d55f SHA512 bdad66bd5d238bdeb81a4e2a956f0a814633360f05c7bed2161df9506d2ccc444445ba452cc8974c755fe0d3f46adceb90324a472a5dac72e9c65391ae7a841c
 DIST opera-stable_105.0.4970.34_amd64.deb 112027992 BLAKE2B a7ac7b0ce516eb1d72c1e44daf9732131e0b3dc1f544122cb311825391bd04dfbab635ae5bd84e5aeeab92f98dd8c30f1ed510942b091af722d5bac8acb3fd59 SHA512 d61947fcc51ecefbbb3cecd2aaa90e8732405e0158c784348807a384892fbf16dff4b818d757c8bc57d0b453baa09cbf234ec597af67763a590e768538464c22
+DIST opera-stable_105.0.4970.48_amd64.deb 112013184 BLAKE2B 6bb4dcbf81c5d60df3a31e6d58b55dabc1d7faa8999696bf55457722f45f7c6f4763450b2b6d104d163b9f13538443fccbadc9dbbaa2d3b7d016774854728438 SHA512 57430e7652d3e243f173ac910bf5f8a197216f9c9ed6f7c40eb6c6955c5ba06406098390a1cbd3f71a5f121c5ff33fcde118b5feb99242181c6fd51ffd726583
diff --git a/www-client/opera/opera-105.0.4970.48.ebuild b/www-client/opera/opera-105.0.4970.48.ebuild
new file mode 100644
index 000000000000..fa627a202454
--- /dev/null
+++ b/www-client/opera/opera-105.0.4970.48.ebuild
@@ -0,0 +1,170 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CHROMIUM_LANGS="
+	bg bn ca cs da de el en-GB en-US es-419 es fil fi fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+
+# These are intended for ebuild maintainer use to force RPM if DEB is not available.
+: ${OPERA_FORCE_RPM=no}
+
+inherit chromium-2 pax-utils xdg
+
+if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+	inherit rpm
+	OPERA_ARCHIVE_EXT="rpm"
+else
+	inherit unpacker
+	OPERA_ARCHIVE_EXT="deb"
+fi
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2018"
+SLOT="0"
+
+SRC_URI_BASE=(
+	"https://download1.operacdn.com/pub/${PN}"
+	"https://download2.operacdn.com/pub/${PN}"
+	"https://download3.operacdn.com/pub/${PN}"
+	"https://download4.operacdn.com/pub/${PN}"
+)
+
+if [[ ${PN} == opera ]]; then
+	MY_PN=${PN}-stable
+	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
+else
+	MY_PN=${PN}
+fi
+
+KEYWORDS="-* ~amd64"
+
+FFMPEG_VERSION="114.0.5735.9"
+
+SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.${OPERA_ARCHIVE_EXT}}
+	proprietary-codecs? (
+		mirror+https://dev.gentoo.org/~sultan/distfiles/www-client/opera/opera-ffmpeg-codecs-${FFMPEG_VERSION}.tar.xz
+	)"
+
+IUSE="+proprietary-codecs +suid qt5 qt6"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gsettings-desktop-schemas
+	media-libs/alsa-lib
+	media-libs/mesa[gbm(+)]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/pango
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5[X]
+		dev-qt/qtwidgets:5
+	)
+	qt6? ( dev-qt/qtbase:6[gui,widgets] )
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+OPERA_HOME="opt/opera${PN#opera}"
+
+pkg_pretend() {
+	# Protect against people using autounmask overzealously
+	use amd64 || die "opera only works on amd64"
+}
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rpm_src_unpack "${A[0]}"
+	else
+		unpacker
+	fi
+
+	# move to /opt, bug #573052
+	mkdir -p "${OPERA_HOME%${PN}}"
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		mv "usr/lib64/${PN}" "${OPERA_HOME%${PN}}" || die
+	else
+		mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
+	fi
+	rm -r "usr/lib" || die
+
+	# disable auto update
+	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
+
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rm "${OPERA_HOME}/setup_repo.sh" || die
+	else
+		rm -r "usr/share/lintian" || die
+
+		# fix docs
+		mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+		gzip -d usr/share/doc/${PF}/changelog.gz || die
+	fi
+
+	# fix desktop file
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+
+	# remove unused language packs
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	# setup opera symlink
+	rm "usr/bin/${PN}" || die
+	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
+
+	# install proprietary codecs
+	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
+	if use proprietary-codecs; then
+		mv lib_extra "${OPERA_HOME}"
+	fi
+
+	if ! use qt5; then
+		rm "${OPERA_HOME}/libqt5_shim.so" || die
+	fi
+	if ! use qt6; then
+		rm "${OPERA_HOME}/libqt6_shim.so" || die
+	fi
+
+	# pax mark opera, bug #562038
+	pax-mark m "${OPERA_HOME}/opera"
+	# enable suid sandbox if requested
+	use suid && fperms 4711 "/${OPERA_HOME}/opera_sandbox"
+}