www-client/opera-beta: Version 72.0.3815.49

Package-Manager: Portage-3.0.8, Repoman-3.0.1
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

2 files changed, 104 insertions, 0 deletions

diff --git a/www-client/opera-beta/Manifest b/www-client/opera-beta/Manifest
index 7332f7a4f425..30ef56ab88f9 100644
--- a/www-client/opera-beta/Manifest
+++ b/www-client/opera-beta/Manifest
@@ -1 +1,2 @@
 DIST opera-beta_71.0.3770.126_amd64.deb 68278732 BLAKE2B edb569db1a790964f36fa0cc8620fb966d60459a6ec75b53a7a8b9130eefa8798d29d4dc44fea8fe9385e54fd5b86513be4de3967b5c795f8063d672fa63b581 SHA512 0a2d3fe294c7a4611ddcd86dd31c33707974cf2760c378af6afa2f85a5c9c4d84ba95b11a11f22aae022ecba0cb971039df3696c6891c217911f2a93164d020b
+DIST opera-beta_72.0.3815.49_amd64.deb 72273100 BLAKE2B 55349662ab55f2954baaff2357cd19a31e6c39403655e01cabffa7b185f99caf8252fb3fe016b7a1660b6f9712e8f8cffa3f69c0b6f96069664742f3fa79f35a SHA512 6c8c13d2906155f8b348afab0acc72c9b4e76f2f4580e74638a3ad8125dac4ac26970be14cffc543cd51ca332b53a943c0bb8983f762c7f288b1285c2fb4f641
diff --git a/www-client/opera-beta/opera-beta-72.0.3815.49.ebuild b/www-client/opera-beta/opera-beta-72.0.3815.49.ebuild
new file mode 100644
index 000000000000..dff5217c967f
--- /dev/null
+++ b/www-client/opera-beta/opera-beta-72.0.3815.49.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+CHROMIUM_LANGS="
+	be bg bn ca cs da de el en-GB es es-419 fi fil fr fr-CA hi hr hu id it
+	ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+inherit chromium-2 multilib unpacker xdg
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2014"
+SLOT="0"
+SRC_URI_BASE="
+	https://download1.operacdn.com/pub/
+	https://download2.operacdn.com/pub/
+	https://download3.operacdn.com/pub/
+	https://download4.operacdn.com/pub/
+"
+SRC_URI="amd64? ("
+for uri in ${SRC_URI_BASE}; do
+SRC_URI+="
+	"${uri}${PN}/${PV}/linux/${PN}_${PV}_amd64.deb"
+"
+done
+SRC_URI+=")"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gconf:2
+	media-libs/alsa-lib
+	media-libs/fontconfig
+	media-libs/freetype
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libXScrnSaver
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/libnotify
+	x11-libs/pango[X]
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+
+pkg_setup() {
+	OPERA_HOME="usr/$(get_libdir)/${PN}"
+}
+
+src_unpack() {
+	unpack_deb ${A}
+}
+
+src_prepare() {
+	default
+
+	case ${ARCH} in
+		amd64)
+			mv usr/lib/x86_64-linux-gnu usr/$(get_libdir) || die
+			rm -r usr/lib || die
+			;;
+		x86)
+			mv usr/lib/i386-linux-gnu/${PN} usr/$(get_libdir)/ || die
+			;;
+	esac
+
+	mv usr/share/doc/${PN} usr/share/doc/${PF} || die
+	gunzip usr/share/doc/${PF}/changelog.gz || die
+
+	rm usr/bin/${PN} || die
+
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+}
+
+src_install() {
+	mv * "${D}" || die
+	dosym ../$(get_libdir)/${PN}/${PN} /usr/bin/${PN}
+	fperms 4711 /usr/$(get_libdir)/${PN}/opera_sandbox
+}