www-plugins/lightspark: Bump to 0.8.0_p20180401 snapshot

Closes: https://bugs.gentoo.org/652074

2 files changed, 98 insertions, 0 deletions

diff --git a/www-plugins/lightspark/Manifest b/www-plugins/lightspark/Manifest
index 1a819324fc5b..d4255c1bae15 100644
--- a/www-plugins/lightspark/Manifest
+++ b/www-plugins/lightspark/Manifest
@@ -1,2 +1,3 @@
 DIST lightspark-0.7.2_p20160107.tar.gz 1803064 BLAKE2B 95b7522ed5e8c757e6b6de7251dbdd862a3094fd2779d9c49e049ef3518b65ef9747be304e1a6ce2ff1ca8f5ccbfc98516f9d614666c4a37c0fe147d18fcba2d SHA512 937352c8d428579a9ac89a45724db2beb624eba874da59d684e07d9d306305d85937f4b2e692c56750a1b5e6ca485e05d9997409d3bc934fab209124cd471601
 DIST lightspark-0.8.0.tar.gz 1830071 BLAKE2B 5fe10d3795cdaedc88ffbc6479957c863440b8400fb4d90bc06a302730343c95e24898e115e4c59f0962cce952ccd51c0a21141091cc0e57cfb6635c1c868619 SHA512 333de501caf5f5ed9c8581cfda5bf1e6e04170c90f1c2f6150c9c2343f9de20e140a041d066f693e406d24fa24e7a5c3464675a583f4a5c104f5214ebee072b9
+DIST lightspark-f6ed8284810ad91c277ed5d0835b215e7329450e.tar.gz 1880249 BLAKE2B 031dc48f40956fcfb5a8b0fd825da8a2a0dba6daa4646296a385d5f90f13027d44cbb09562f6bf57b8d5d415a278fa06974624aee42e14b75892c36798dceda0 SHA512 a75ebf5e666daec0f244285bfd1029feb6fcfa2aeba800f175bb07bc148d39e76435d77868c964b2e149019b763498990bf0db25ba632cf21b91ad0958412332
diff --git a/www-plugins/lightspark/lightspark-0.8.0_p20180401.ebuild b/www-plugins/lightspark/lightspark-0.8.0_p20180401.ebuild
new file mode 100644
index 000000000000..eb9a35fde59a
--- /dev/null
+++ b/www-plugins/lightspark/lightspark-0.8.0_p20180401.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit cmake-utils gnome2-utils nsplugins toolchain-funcs xdg-utils
+
+EGIT_COMMIT="f6ed8284810ad91c277ed5d0835b215e7329450e"
+DESCRIPTION="High performance flash player"
+HOMEPAGE="http://lightspark.github.io/"
+SRC_URI="https://github.com/lightspark/lightspark/archive/${EGIT_COMMIT}.tar.gz -> ${PN}-${EGIT_COMMIT}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cpu_flags_x86_sse2 curl ffmpeg gles libav nsplugin ppapi profile rtmp"
+
+RDEPEND="app-arch/xz-utils:0=
+	dev-cpp/glibmm:2=
+	>=dev-libs/boost-1.42:0=
+	dev-libs/glib:2=
+	dev-libs/libpcre:3=[cxx]
+	media-fonts/liberation-fonts
+	media-libs/freetype:2=
+	media-libs/libpng:0=
+	media-libs/libsdl2:0=
+	media-libs/sdl2-mixer:0=
+	>=sys-devel/llvm-3.4:=
+	sys-libs/zlib:0=
+	x11-libs/cairo:0=
+	x11-libs/libX11:0=
+	x11-libs/pango:0=
+	virtual/jpeg:0=
+	curl? ( net-misc/curl:0= )
+	ffmpeg? (
+		libav? ( media-video/libav:0= )
+		!libav? ( media-video/ffmpeg:0= )
+	)
+	gles? ( media-libs/mesa:0=[gles2] )
+	!gles? (
+		>=media-libs/glew-1.5.3:0=
+		virtual/opengl:0=
+	)
+	rtmp? ( media-video/rtmpdump:0= )"
+DEPEND="${RDEPEND}
+	amd64? ( dev-lang/nasm )
+	x86? ( dev-lang/nasm )
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${PN}-${EGIT_COMMIT}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_CURL=$(usex curl)
+		-DENABLE_GLES2=$(usex gles)
+		-DENABLE_LIBAVCODEC=$(usex ffmpeg)
+		-DENABLE_RTMP=$(usex rtmp)
+
+		-DENABLE_MEMORY_USAGE_PROFILING=$(usex profile)
+		-DENABLE_PROFILING=$(usex profile)
+		-DENABLE_SSE2=$(usex cpu_flags_x86_sse2)
+
+		-DCOMPILE_NPAPI_PLUGIN=$(usex nsplugin)
+		-DPLUGIN_DIRECTORY="${EPREFIX}"/usr/$(get_libdir)/${PN}/plugins
+		# TODO: install /etc/chromium file? block adobe-flash?
+		-DCOMPILE_PPAPI_PLUGIN=$(usex ppapi)
+		-DPPAPI_PLUGIN_DIRECTORY="${EPREFIX}"/usr/$(get_libdir)/chromium-browser/${PN}
+	)
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	use nsplugin && inst_plugin /usr/$(get_libdir)/${PN}/plugins/liblightsparkplugin.so
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+
+	if use nsplugin && ! has_version www-plugins/gnash; then
+		elog "Lightspark now supports gnash fallback for its browser plugin."
+		elog "Install www-plugins/gnash to take advantage of it."
+	fi
+	if use nsplugin && has_version "www-plugins/gnash[nsplugin]"; then
+		elog "Having two plugins installed for the same MIME type may confuse"
+		elog "Mozilla based browsers. It is recommended to disable the nsplugin"
+		elog "USE flag for either gnash or lightspark. For details, see"
+		elog "https://bugzilla.mozilla.org/show_bug.cgi?id=581848"
+	fi
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}