1 files changed, 48 insertions, 0 deletions
diff --git a/app-admin/mcelog/mcelog-179-r1.ebuild b/app-admin/mcelog/mcelog-179-r1.ebuild
new file mode 100644
index 000000000000..147b65e40b9d
--- /dev/null
+++ b/app-admin/mcelog/mcelog-179-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit linux-info systemd toolchain-funcs
+
+DESCRIPTION="A tool to log and decode Machine Check Exceptions"
+HOMEPAGE="http://mcelog.org/"
+SRC_URI="https://github.com/andikleen/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="selinux"
+
+RDEPEND="selinux? ( sec-policy/selinux-mcelog )"
+
+# TODO: add mce-inject to the tree to support test phase
+RESTRICT="test"
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != buildonly ]]; then
+		local CONFIG_CHECK="~X86_MCE"
+		kernel_is -ge 4 12 && CONFIG_CHECK+=" ~X86_MCELOG_LEGACY"
+		check_extra_config
+	fi
+}
+
+src_prepare() {
+	eapply "${FILESDIR}"/${PN}-0.8_pre1-timestamp-${PN}.patch \
+		"${FILESDIR}"/${PN}-129-debugflags.patch \
+		"${FILESDIR}"/${PN}-179-fix-logrotate.patch
+	eapply_user
+	tc-export CC
+}
+
+src_install() {
+	default
+
+	insinto /etc/logrotate.d/
+	newins ${PN}.logrotate ${PN}
+
+	newinitd "${FILESDIR}"/${PN}.init-r1 ${PN}
+	systemd_dounit ${PN}.service
+
+	dodoc *.pdf
+}