1 files changed, 47 insertions, 0 deletions
diff --git a/dev-python/flask-sqlalchemy/flask-sqlalchemy-2.0.ebuild b/dev-python/flask-sqlalchemy/flask-sqlalchemy-2.0.ebuild
new file mode 100644
index 000000000000..2b0b5f45012f
--- /dev/null
+++ b/dev-python/flask-sqlalchemy/flask-sqlalchemy-2.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
+
+inherit distutils-r1
+
+MY_PN="Flask-SQLAlchemy"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="SQLAlchemy support for Flask applications"
+HOMEPAGE="http://pypi.python.org/pypi/Flask-SQLAlchemy"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="doc"
+
+RDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/flask-0.10[${PYTHON_USEDEP}]
+	dev-python/sqlalchemy[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
+
+# Patch out un-needed d'loading of obj.inv files in doc build
+PATCHES=( "${FILESDIR}"/mapping.patch )
+
+# Req'd for tests in py3
+DISTUTILS_IN_SOURCE_BUILD=1
+
+S="${WORKDIR}/${MY_P}"
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( "${BUILD_DIR}"/sphinx/html/. )
+	distutils-r1_python_install_all
+}