1 files changed, 45 insertions, 0 deletions
diff --git a/games-emulation/prosystem-jg/prosystem-jg-1.5.2.ebuild b/games-emulation/prosystem-jg/prosystem-jg-1.5.2.ebuild
new file mode 100644
index 000000000000..212b4dd7a4b3
--- /dev/null
+++ b/games-emulation/prosystem-jg/prosystem-jg-1.5.2.ebuild
@@ -0,0 +1,45 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+MY_PN=${PN%-*}
+MY_P=${MY_PN}-${PV}
+DESCRIPTION="Jolly Good Fork of ProSystem"
+HOMEPAGE="https://gitlab.com/jgemu/prosystem"
+if [[ "${PV}" == *9999 ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://gitlab.com/jgemu/${MY_PN}.git"
+else
+	SRC_URI="https://gitlab.com/jgemu/${MY_PN}/-/archive/${PV}/${MY_P}.tar.bz2"
+	S="${WORKDIR}/${MY_P}"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="BSD GPL-2+"
+SLOT="1"
+
+DEPEND="
+	media-libs/jg:1=
+"
+RDEPEND="
+	${DEPEND}
+	games-emulation/jgrf
+"
+BDEPEND="
+	virtual/pkgconfig
+"
+
+src_compile() {
+	emake CC="$(tc-getCC)" PKG_CONFIG="$(tc-getPKG_CONFIG)"
+}
+
+src_install() {
+	emake install \
+		DESTDIR="${D}" \
+		PREFIX="${EPREFIX}"/usr \
+		DOCDIR="${EPREFIX}"/usr/share/doc/${PF} \
+		LIBDIR="${EPREFIX}/usr/$(get_libdir)"
+}