1 files changed, 52 insertions, 0 deletions
diff --git a/x11-libs/gtksourceview/gtksourceview-3.24.11-r1.ebuild b/x11-libs/gtksourceview/gtksourceview-3.24.11-r1.ebuild
new file mode 100644
index 000000000000..c2c1e31bf88e
--- /dev/null
+++ b/x11-libs/gtksourceview/gtksourceview-3.24.11-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+VALA_USE_DEPEND="vapigen"
+inherit gnome2 vala virtualx
+
+DESCRIPTION="A text widget implementing syntax highlighting and other features"
+HOMEPAGE="https://wiki.gnome.org/Projects/GtkSourceView"
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="3.0/3"
+KEYWORDS="~alpha amd64 arm arm64 ~ia64 ~mips ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-solaris"
+IUSE="glade +introspection +vala"
+REQUIRED_USE="vala? ( introspection )"
+
+RDEPEND="
+	>=dev-libs/glib-2.48:2
+	>=dev-libs/libxml2-2.6:2
+	>=x11-libs/gtk+-3.20:3[introspection?]
+	glade? ( >=dev-util/glade-3.9:3.10 )
+	introspection? ( >=dev-libs/gobject-introspection-1.42:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	>=dev-util/gtk-doc-am-1.25
+	>=sys-devel/gettext-0.19.4
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+src_configure() {
+	use vala && vala_setup
+
+	gnome2_src_configure \
+		$(use_enable glade glade-catalog) \
+		$(use_enable introspection) \
+		$(use_enable vala)
+}
+
+src_test() {
+	virtx emake check
+}
+
+src_install() {
+	gnome2_src_install
+
+	insinto /usr/share/${PN}-3.0/language-specs
+	doins "${FILESDIR}"/2.0/gentoo.lang
+}