blob: f1b26023303902d90921c5d062ac82cf0bf07e30 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
|
# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI="5"
USE_RUBY="ruby20 ruby21"
RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"
RUBY_FAKEGEM_GEMSPEC="vagrant.gemspec"
RUBY_FAKEGEM_EXTRAINSTALL="keys plugins templates version.txt"
RUBY_FAKEGEM_TASK_DOC=""
inherit bash-completion-r1 ruby-fakegem eutils
DESCRIPTION="A tool for building and distributing development environments"
HOMEPAGE="http://vagrantup.com/"
SRC_URI="https://github.com/mitchellh/vagrant/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+virtualbox"
RDEPEND="${RDEPEND}
app-arch/libarchive
net-misc/curl
virtualbox? ( || ( <app-emulation/virtualbox-5.1 <app-emulation/virtualbox-bin-5.1 ) )"
ruby_add_rdepend "
>=dev-ruby/bundler-1.12.5
>=dev-ruby/childprocess-0.5.0
>=dev-ruby/erubis-2.7.0
>=dev-ruby/i18n-0.6.0:* <dev-ruby/i18n-0.8.0:*
>=dev-ruby/listen-3.0.2
>=dev-ruby/hashicorp-checkpoint-0.1.1
>=dev-ruby/log4r-1.1.9 <dev-ruby/log4r-1.1.11
>=dev-ruby/net-ssh-3.0.1
>=dev-ruby/net-sftp-2.1
>=dev-ruby/net-scp-1.1.0
>=dev-ruby/rest-client-1.6.0:0
>=dev-ruby/nokogiri-1.6.7.1
>=dev-ruby/mime-types-2.6.2:* <dev-ruby/mime-types-3:*
"
ruby_add_bdepend "
dev-ruby/rake
"
all_ruby_prepare() {
# remove bundler support
sed -i '/[Bb]undler/d' Rakefile || die
rm Gemfile || die
# loosen dependencies
sed -e '/hashicorp-checkpoint\|listen\|net-ssh\|net-scp/s/~>/>=/' \
-e '/nokogiri\|bundler/s/=/>=/' \
-i ${PN}.gemspec || die
# remove windows-specific gems
sed -e '/wdm\|winrm/d' \
-i ${PN}.gemspec || die
# remove bsd-specific gems
sed -e '/rb-kqueue/d' \
-i ${PN}.gemspec || die
# see https://github.com/mitchellh/vagrant/pull/5877
epatch "${FILESDIR}"/${P}-install-plugins-in-isolation.patch
# disable embedded CA certs and use system ones
epatch "${FILESDIR}"/${PN}-1.8.1-disable-embedded-cacert.patch
# fix rvm issue (bug #474476)
epatch "${FILESDIR}"/${PN}-1.8.1-rvm.patch
}
all_ruby_install() {
newbashcomp contrib/bash/completion.sh ${PN}
all_fakegem_install
# provide executable similar to upstream:
# https://github.com/mitchellh/vagrant-installers/blob/master/substrate/modules/vagrant_installer/templates/vagrant.erb
newbin "${FILESDIR}/${P}" "${PN}"
# directory for plugins.json
dodir /var/lib/vagrant
}
|
GitWeb