blob: e96ea5fa7b6ddea7733e3b38c3439bc2de08fd0d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit flag-o-matic autotools prefix
CONFVER="1.9"
DESCRIPTION="Enhanced version of the Berkeley C shell (csh)"
HOMEPAGE="https://www.tcsh.org/"
SRC_URI="
ftp://ftp.astron.com/pub/tcsh/${P}.tar.gz
ftp://ftp.astron.com/pub/tcsh/old/${P}.tar.gz
https://dev.gentoo.org/~grobian/distfiles/tcsh-gentoo-patches-r${CONFVER}.tar.bz2"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris"
IUSE="nls doc"
RESTRICT="test"
# we need gettext because we run autoconf (AM_ICONV)
RDEPEND="
>=sys-libs/ncurses-5.1:0=
virtual/libcrypt:=
virtual/libiconv"
DEPEND="${RDEPEND}
sys-devel/gettext
doc? ( dev-lang/perl )"
CONFDIR=${WORKDIR}/tcsh-gentoo-patches-r${CONFVER}
PATCHES=(
"${FILESDIR}"/${PN}-6.23.02-dircolors.patch # bug #120792
"${FILESDIR}"/${PN}-6.21.04-no-nls.patch
"${FILESDIR}"/${PN}-6.21.00-use-ncurses.patch
)
src_prepare() {
default
eautoreconf
# fix gencat usage
sed \
-e 's/cat \$\^ \$> | \$(GENCAT) \$@/rm -f $@; $(GENCAT) $@ $> $^/' \
-i nls/Makefile.in || die
# always use sysmalloc, the builtin malloc fails on Darwin, musl,
# etc. it's already used for glibc-linux, so this doesn't change
# anything for the majority of users
sed -i -e 's/undef SYSMALLOC/define SYSMALLOC/' config_f.h || die
# unify ECHO behaviour
echo "#undef ECHO_STYLE" >> config_f.h
echo "#define ECHO_STYLE BOTH_ECHO" >> config_f.h
eprefixify "${CONFDIR}"/*
# activate the right default PATH
if [[ -z ${EPREFIX} ]] ; then
sed -i \
-e 's/^#MAIN//' -e '/^#PREFIX/d' \
"${CONFDIR}"/csh.login || die
else
sed -i \
-e 's/^#PREFIX//' -e '/^#MAIN/d' \
"${CONFDIR}"/csh.login || die
fi
eapply_user
}
src_configure() {
# make tcsh look and live along the lines of the prefix
append-cppflags -D_PATH_DOTCSHRC="'"'"${EPREFIX}/etc/csh.cshrc"'"'"
append-cppflags -D_PATH_DOTLOGIN="'"'"${EPREFIX}/etc/csh.login"'"'"
append-cppflags -D_PATH_DOTLOGOUT="'"'"${EPREFIX}/etc/csh.logout"'"'"
append-cppflags -D_PATH_USRBIN="'"'"${EPREFIX}/usr/bin"'"'"
append-cppflags -D_PATH_BIN="'"'"${EPREFIX}/bin"'"'"
# musl's utmp is non-functional
if use elibc_musl ; then
export ac_cv_header_utmp_h=no
export ac_cv_header_utmpx_h=no
fi
econf \
--prefix="${EPREFIX:-}" \
--datarootdir='${prefix}/usr/share' \
$(use_enable nls)
}
src_install() {
emake DESTDIR="${D}" install install.man
DOCS=( FAQ Fixes NewThings Ported README.md WishList Y2K )
if use doc ; then
perl tcsh.man2html tcsh.man || die
HTML_DOCS=( tcsh.html/*.html )
fi
einstalldocs
insinto /etc
doins \
"${CONFDIR}"/csh.cshrc \
"${CONFDIR}"/csh.login
# bug #119703: add csh -> tcsh symlink
dosym tcsh /bin/csh
}
|
GitWeb