blob: 1b4757120c67e88b5b8949dbde2756e7ec69de33 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
PYTHON_COMPAT=( python2_7 python3_6 )
inherit vim-plugin python-single-r1
DESCRIPTION="A comprehensive set of tools to view, edit and compile LaTeX documents"
HOMEPAGE="http://vim-latex.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
LICENSE="vim"
KEYWORDS="alpha amd64 ia64 ppc ppc64 ~sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris"
IUSE=""
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
RDEPEND="
${PYTHON_DEPS}
|| (
app-editors/vim[python,${PYTHON_USEDEP}]
app-editors/gvim[python,${PYTHON_USEDEP}]
)
virtual/latex-base
!app-vim/vimtex"
VIM_PLUGIN_HELPFILES="latex-suite.txt latex-suite-quickstart.txt latexhelp.txt imaps.txt"
src_compile() { :; }
src_install() {
# remove unused metadata
rm vim-latex.metainfo.xml || die
# don't mess up vim's doc dir with random files
mv doc mydoc || die
mkdir doc || die
mv mydoc/*.txt doc/ || die
rm -rf mydoc || die
# don't install buggy tags scripts, use ctags instead
rm latextags ltags || die
vim-plugin_src_install
# use executable permissions (bug #352403)
fperms a+x /usr/share/vim/vimfiles/ftplugin/latex-suite/outline.py
python_fix_shebang "${ED}"
}
pkg_postinst() {
vim-plugin_pkg_postinst
if [[ -z ${REPLACING_VERSIONS} ]]; then
echo
elog "To use the vim-latex plugin add:"
elog " filetype plugin on"
elog ' set grepprg=grep\ -nH\ $*'
elog " let g:tex_flavor='latex'"
elog "to your ~/.vimrc-file"
echo
fi
}
|
GitWeb
