dev-python/python-evdev/python-evdev-1.6.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_EXT=1
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{9..12} )

inherit distutils-r1

DESCRIPTION="Python library for evdev bindings"
HOMEPAGE="
	https://python-evdev.readthedocs.io/
	https://github.com/gvalkov/python-evdev/
	https://pypi.org/project/evdev/
"
SRC_URI="
	https://github.com/gvalkov/python-evdev/archive/v${PV}.tar.gz
		-> ${P}.gh.tar.gz
"

LICENSE="BSD"
SLOT="0"
KEYWORDS="amd64 ~arm x86"

distutils_enable_tests pytest

EPYTEST_DESELECT=(
	tests/test_uinput.py
)

python_configure_all() {
	esetup.py build_ecodes \
		--evdev-headers \
		"${ESYSROOT}/usr/include/linux/input.h:${ESYSROOT}/usr/include/linux/input-event-codes.h"
}

src_test() {
	cd tests || die
	distutils-r1_src_test
}