blob: a4ea7325d2549735987e963b46f24361d050a8b3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_EXT=1
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{10..11} )
inherit distutils-r1 optfeature pypi
DESCRIPTION="Statistical computations and models for use with SciPy"
HOMEPAGE="
https://www.statsmodels.org/stable/index.html
https://github.com/statsmodels/statsmodels/
https://pypi.org/project/statsmodels/
"
LICENSE="BSD"
SLOT="0"
KEYWORDS="amd64 ~arm arm64 ~ppc ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux"
IUSE="examples"
DEPEND="
>=dev-python/numpy-1.17[${PYTHON_USEDEP}]
>=dev-python/scipy-1.3[${PYTHON_USEDEP}]
"
RDEPEND="
${DEPEND}
>=dev-python/numpy-1.17[${PYTHON_USEDEP}]
>=dev-python/packaging-21.3[${PYTHON_USEDEP}]
>=dev-python/pandas-0.25[${PYTHON_USEDEP}]
>=dev-python/patsy-0.5.2[${PYTHON_USEDEP}]
>=dev-python/scipy-1.3[${PYTHON_USEDEP}]
"
BDEPEND="
${DEPEND}
>=dev-python/cython-0.29.33[${PYTHON_USEDEP}]
>=dev-python/setuptools-scm-8[${PYTHON_USEDEP}]
"
distutils_enable_sphinx docs \
'dev-python/ipykernel' \
'dev-python/jupyter-client' \
'dev-python/matplotlib' \
'dev-python/nbconvert' \
'dev-python/numpydoc'
EPYTEST_XDIST=1
distutils_enable_tests pytest
python_prepare_all() {
export VARTEXFONTS="${T}"/fonts
export MPLCONFIGDIR="${T}"
printf -- 'backend : Agg\n' > "${MPLCONFIGDIR}"/matplotlibrc || die
distutils-r1_python_prepare_all
}
python_test() {
local -x MKL_NUM_THREADS=1
local -x OMP_NUM_THREADS=1
local EPYTEST_DESELECT=(
# note that test path should be without "statsmodels/" prefix
imputation/tests/test_mice.py::TestMICE::test_combine
stats/tests/test_mediation.py::test_mixedlm
"stats/tests/test_corrpsd.py::test_corrpsd_threshold[0]"
)
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
epytest statsmodels
}
python_install_all() {
if use examples; then
docompress -x /usr/share/doc/${PF}/examples
dodoc -r examples
fi
distutils-r1_python_install_all
}
pkg_postinst() {
optfeature "Plotting functionality" "dev-python/matplotlib"
}
|
GitWeb