blob: 52d658ae0a125ce1d3e1f1a5a47133e1abecb50b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Copyright 2023-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit qt6-build
DESCRIPTION="Text-to-speech library for the Qt6 framework"
if [[ ${QT6_BUILD_TYPE} == release ]]; then
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~riscv ~x86"
fi
IUSE="flite qml +speechd"
# can build with neither, but then it is just mock tts and may be confusing
REQUIRED_USE="|| ( flite speechd )"
# TODO: tests are known failing with clang and needs looking into, albeit
# it is still usable at runtime save for applications segfaulting on exit
# similarly to QTBUG-90626 (not that this has in-tree revdeps as of writing
# of this). Restricting because also seen this result in hanging. Note that
# qtspeech:6 is still somewhat new (started in 6.4.0), and should review
# status on new major versions.
RESTRICT="test"
RDEPEND="
~dev-qt/qtbase-${PV}:6
~dev-qt/qtmultimedia-${PV}:6
flite? ( app-accessibility/flite )
qml? ( ~dev-qt/qtdeclarative-${PV}:6 )
speechd? ( app-accessibility/speech-dispatcher )
"
DEPEND="${RDEPEND}"
src_configure() {
local mycmakeargs=(
$(cmake_use_find_package qml Qt6Qml)
$(qt_feature flite)
$(qt_feature speechd)
# flite_alsa was likely to work around old issues in flite, it does
# nothing but add -lasound (no code change, and is unneeded)
-DQT_FEATURE_flite_alsa=OFF
)
qt6-build_src_configure
}
|
GitWeb
