blob: f2441b774c9818a445a28dd6463ede6bf620dd17 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI="8"
inherit autotools
MY_P="${P^g}"
MY_P="${MY_P/_p/-p}"
DESCRIPTION="A Unix system friendly Scheme Interpreter"
HOMEPAGE="http://practical-scheme.net/gauche/"
SRC_URI="https://github.com/shirok/${PN^g}/releases/download/release${PV//./_}/${MY_P}.tgz"
LICENSE="BSD"
SLOT="0/$(ver_cut 1-2)8"
KEYWORDS="~alpha amd64 ~ia64 ~ppc ~ppc64 ~sparc x86 ~amd64-linux ~x86-linux"
IUSE="ipv6 test"
RESTRICT="!test? ( test )"
RDEPEND="net-libs/mbedtls:=
sys-libs/gdbm
virtual/libcrypt:="
DEPEND="${RDEPEND}"
S="${WORKDIR}/${MY_P}"
PATCHES=(
"${FILESDIR}"/${PN}-ext-ldflags.patch
"${FILESDIR}"/${PN}-gauche.m4.patch
"${FILESDIR}"/${PN}-info.patch
"${FILESDIR}"/${PN}-xz-info.patch
)
DOCS=( AUTHORS ChangeLog HACKING.adoc README.adoc )
src_prepare() {
default
eautoreconf
}
src_configure() {
econf \
$(use_enable ipv6) \
--with-ca-bundle="${EPREFIX}"/etc/ssl/certs/ca-certificates.crt \
--with-slib="${EPREFIX}"/usr/share/slib \
--with-tls=mbedtls
}
src_test() {
emake -j1 -s check
}
src_install() {
emake DESTDIR="${D}" install-pkg install-doc
einstalldocs
}
|
GitWeb
