blob: 8b20939f47e307283ba17ae7e8d432cf8d94187f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools
MAJOR="2.2"
DESCRIPTION="GNU Ubiquitous Intelligent Language for Extensions"
HOMEPAGE="https://www.gnu.org/software/guile/"
SRC_URI="mirror://gnu/guile/${P}.tar.xz"
LICENSE="LGPL-3+"
SLOT="12/2.2-1" # libguile-2.2.so.1 => 2.2-1
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos"
IUSE="debug debug-malloc +deprecated +networking +nls +regex +threads" # upstream recommended +networking +nls
REQUIRED_USE="regex" # workaround for bug 596322
RESTRICT="strip"
RDEPEND="
>=dev-libs/boehm-gc-7.0:=[threads?]
dev-libs/gmp:=
dev-libs/libffi:=
dev-libs/libltdl:=
dev-libs/libunistring:0=
sys-libs/ncurses:0=
sys-libs/readline:0=
virtual/libcrypt:="
DEPEND="${RDEPEND}"
BDEPEND="
virtual/pkgconfig
dev-build/libtool
sys-devel/gettext"
PATCHES=(
"${FILESDIR}/${PN}-2.2.3-gentoo-sandbox.patch"
"${FILESDIR}/${PN}-2.2.7-stack-up.patch"
# Modern C bug in round.m4
# /bin/sh bug in timegm.m4
"${FILESDIR}"/${PN}-2.2.7-fix-buggy-gnulib.patch
)
# guile generates ELF files without use of C or machine code
# It's a portage's false positive. bug #677600
QA_PREBUILT='*[.]go'
DOCS=( GUILE-VERSION HACKING README )
src_prepare() {
default
eautoreconf
}
src_configure() {
# see bug #676468
mv prebuilt/32-bit-big-endian{,.broken} || die
econf \
--disable-error-on-warning \
--disable-rpath \
--enable-posix \
--without-libgmp-prefix \
--without-libiconv-prefix \
--without-libintl-prefix \
--without-libltdl-prefix \
--without-libreadline-prefix \
--without-libunistring-prefix \
$(use_enable debug guile-debug) \
$(use_enable debug-malloc) \
$(use_enable deprecated) \
$(use_enable networking) \
$(use_enable nls) \
$(use_enable regex) \
$(use_with threads)
}
src_install() {
default
# From Novell
# https://bugzilla.novell.com/show_bug.cgi?id=874028#c0
dodir /usr/share/gdb/auto-load/$(get_libdir)
mv "${ED}"/usr/$(get_libdir)/libguile-*-gdb.scm "${ED}"/usr/share/gdb/auto-load/$(get_libdir) || die
# necessary for registering slib, see bug 206896
keepdir /usr/share/guile/site
find "${D}" -name '*.la' -delete || die
}
|
GitWeb