blob: 7b23baf99045283dea2f56a5110f30423789a1c6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit meson xdg vala virtualx
MY_P="${PN}-v${PV}"
DESCRIPTION="Library with GTK widgets for mobile phones"
HOMEPAGE="https://source.puri.sm/Librem5/libhandy/"
SRC_URI="https://source.puri.sm/Librem5/libhandy/-/archive/v${PV}/${MY_P}.tar.bz2"
S="${WORKDIR}/${MY_P}"
LICENSE="LGPL-2.1+"
SLOT="0.0/0" # It may or may not break ABI in future versions at this point; if new
# SLOT happens, it'll likely file conflict on gtk-doc and glade library and catalog
KEYWORDS="amd64 ~arm64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="examples glade gtk-doc +introspection test +vala"
REQUIRED_USE="vala? ( introspection )"
RESTRICT="!test? ( test )"
RDEPEND="
>=dev-libs/glib-2.44:2
>=x11-libs/gtk+-3.24.1:3[introspection?]
glade? ( dev-util/glade:3.10= )
introspection? ( >=dev-libs/gobject-introspection-1.54:= )
"
DEPEND="${RDEPEND}"
BDEPEND="
vala? ( $(vala_depend) )
dev-libs/libxml2:2
dev-util/glib-utils
>=sys-devel/gettext-0.19.8
virtual/pkgconfig
gtk-doc? ( dev-util/gtk-doc
app-text/docbook-xml-dtd:4.3 )
"
src_prepare() {
use vala && vala_src_prepare
xdg_src_prepare
}
src_configure() {
local emesonargs=(
-Dprofiling=false # -pg passing
-Dstatic=false
$(meson_feature introspection)
$(meson_use vala vapi)
$(meson_use gtk-doc gtk_doc)
$(meson_use test tests)
$(meson_use examples)
$(meson_feature glade glade_catalog)
)
meson_src_configure
}
src_test() {
virtx meson_src_test
}
|
GitWeb
