blob: f24247ff6504757566658e910b0a07d4607f0014 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Copyright 2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools qmake-utils
DESCRIPTION="Application and libary for hinting TrueType fonts"
HOMEPAGE="https://freetype.org/ttfautohint"
SRC_URI="https://download.savannah.gnu.org/releases/freetype/${P}.tar.gz"
LICENSE="|| ( FTL GPL-2+ )"
SLOT="0/1.0.3"
KEYWORDS="~amd64"
IUSE="qt5"
RDEPEND="
media-libs/freetype
media-libs/harfbuzz:=
qt5? (
dev-qt/qtcore:5
dev-qt/qtgui:5
dev-qt/qtwidgets:5
)
"
DEPEND="${RDEPEND}"
BDEPEND="
sys-apps/help2man
virtual/pkgconfig
"
src_prepare() {
default
# Don't invoke git to get the version number.
sed "s|m4_esyscmd.*VERSION)|${PV//_/-}|" -i configure.ac || die
eautoreconf
}
src_configure() {
local myeconfargs=(
--disable-static
--without-doc
--with-qt="$(usex qt5 $(qt5_get_bindir) no)"
)
econf "${myeconfargs[@]}"
}
src_install() {
default
doman frontend/ttfautohint.1
use qt5 && doman frontend/ttfautohintGUI.1
find "${ED}" -name '*.la' -delete || die
}
|
GitWeb
