blob: 12645639cc620aadaf6acee9f9892de34bdb48a9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools multilib-minimal
DESCRIPTION="A library for accessing a CDDB server"
HOMEPAGE="http://libcddb.sourceforge.net/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
LICENSE="LGPL-2"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~loong ~mips ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux ~x86-solaris"
IUSE="doc static-libs"
RDEPEND=">=virtual/libiconv-0-r1[${MULTILIB_USEDEP}]"
DEPEND="${RDEPEND}"
BDEPEND="doc? ( app-doc/doxygen )"
RESTRICT="test"
DOCS=( AUTHORS ChangeLog NEWS README THANKS TODO )
MULTILIB_WRAPPED_HEADERS=( /usr/include/cddb/version.h )
src_prepare() {
default
# Required for CONFIG_SHELL != bash (bug #528012)
eautoreconf
}
multilib_src_configure() {
local myeconfargs=(
--without-cdio
$(use_enable static-libs static)
)
ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
}
multilib_src_compile() {
default
if use doc ; then
cd "${S}"/doc || die
doxygen doxygen.conf || die
fi
}
multilib_src_install_all() {
default
find "${ED}" -type f -name "*.la" -delete || die
if use doc ; then
docinto html
dodoc "${S}"/doc/html/*
fi
}
|
GitWeb
