blob: 1343401528abf93381ac6a847c28305d62539bc9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools bash-completion-r1 multilib-minimal systemd
DESCRIPTION="Bluetooth Audio ALSA Backend"
HOMEPAGE="https://github.com/Arkq/bluez-alsa"
if [[ ${PV} == "9999" ]] ; then
inherit git-r3
EGIT_REPO_URI="https://github.com/Arkq/${PN}"
else
SRC_URI="https://github.com/Arkq/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~amd64 ~arm64 ~x86"
fi
LICENSE="MIT"
SLOT="0"
IUSE="aac aptx debug hcitop lame ldac man mpg123 ofono static-libs systemd test unwind upower"
RESTRICT="!test? ( test )"
# bluez-alsa does not directly link to upower but
# is using the upower interface via dbus calls.
RDEPEND="
>=dev-libs/glib-2.32[${MULTILIB_USEDEP}]
>=media-libs/alsa-lib-1.1.2[${MULTILIB_USEDEP}]
>=media-libs/sbc-1.2[${MULTILIB_USEDEP}]
>=net-wireless/bluez-5.0[${MULTILIB_USEDEP}]
sys-apps/dbus[${MULTILIB_USEDEP}]
sys-libs/readline:0=
aac? ( >=media-libs/fdk-aac-0.1.1:=[${MULTILIB_USEDEP}] )
aptx? ( media-libs/libopenaptx )
lame? ( media-sound/lame[${MULTILIB_USEDEP}] )
mpg123? ( media-sound/mpg123[${MULTILIB_USEDEP}] )
hcitop? (
dev-libs/libbsd
sys-libs/ncurses:0=
)
ldac? ( >=media-libs/libldac-2.0.0 )
ofono? ( net-misc/ofono )
systemd? ( sys-apps/systemd )
unwind? ( sys-libs/libunwind[${MULTILIB_USEDEP}] )
upower? ( sys-power/upower )
"
DEPEND="${RDEPEND}
test? (
dev-libs/check
media-libs/libsndfile
)"
BDEPEND="
virtual/pkgconfig
man? ( app-text/pandoc )
"
src_prepare() {
default
eautoreconf
}
multilib_src_configure() {
local myeconfargs=(
--enable-cli
--enable-faststream
--enable-rfcomm
--with-bash-completion="$(get_bashcompdir)"
$(use_enable aac)
$(use_enable debug)
$(use_enable lame mp3lame)
$(use_enable man manpages)
$(use_enable mpg123)
$(use_enable static-libs static)
$(use_enable systemd)
$(use_enable test)
$(use_with systemd systemdsystemunitdir $(systemd_get_systemunitdir))
$(multilib_native_use_enable aptx)
$(multilib_native_use_enable hcitop)
$(multilib_native_use_enable ldac)
$(multilib_native_use_enable ofono)
$(multilib_native_use_enable upower)
$(multilib_native_use_with aptx libopenaptx)
$(use_with unwind libunwind)
)
ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
}
multilib_src_install_all() {
default
find "${ED}" -type f -name "*.la" -delete || die
newinitd "${FILESDIR}"/bluealsa-init.d bluealsa
newconfd "${FILESDIR}"/bluealsa-conf.d-2 bluealsa
#systemd_dounit "${FILESDIR}"/bluealsa.service
# Add config file to alsa datadir as well to preserve changes in /etc
insinto "/usr/share/alsa/alsa.conf.d/"
doins "src/asound/20-bluealsa.conf"
}
pkg_postinst() {
elog "Users can use this service when they are members of the \"audio\" group."
}
|
GitWeb