blob: 5f72e2a7662b9ca9f3a68679d7cbe89cd83867c2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI="6"
inherit autotools
DESCRIPTION="A brokerless kernel"
HOMEPAGE="http://www.zeromq.org/"
SRC_URI="https://github.com/zeromq/libzmq/releases/download/v${PV}/${P}.tar.gz"
LICENSE="LGPL-3"
SLOT="0/5"
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
IUSE="pgm +sodium static-libs test elibc_Darwin"
RDEPEND="
!elibc_Darwin? ( sys-libs/libunwind )
sodium? ( dev-libs/libsodium:= )
pgm? ( =net-libs/openpgm-5.2.122 )"
DEPEND="${RDEPEND}
app-text/asciidoc
app-text/xmlto
!elibc_Darwin? ( sys-apps/util-linux )
pgm? ( virtual/pkgconfig )"
PATCHES=( "${FILESDIR}"/${PN}-4.2.1-disable-experimental-zmq_poll-implementation.patch )
src_prepare() {
sed \
-e '/libzmq_werror=/s:yes:no:g' \
-i configure.ac || die
default
eautoreconf
}
src_configure() {
local myeconfargs=(
--enable-shared
$(use_enable static-libs static)
$(use_with sodium libsodium)
$(use_with pgm)
)
econf "${myeconfargs[@]}"
}
src_test() {
# Restricting to one job because multiple tests are using the same port.
# Upstream knows the problem and says it doesn't support parallel test
# execution, see ${S}/INSTALL.
emake -j1 check
}
src_install() {
default
find "${ED}"usr/lib* -name '*.la' -delete || die
}
|
GitWeb
