New version supporting multiple gles implementations

Package-Manager: portage-2.2.0_alpha110/cvs/Linux x86_64

1 files changed, 57 insertions, 0 deletions

diff --git a/app-admin/eselect-opengl/eselect-opengl-1.2.6.ebuild b/app-admin/eselect-opengl/eselect-opengl-1.2.6.ebuild
new file mode 100644
index 000000000000..83d36a1c2f8b
--- /dev/null
+++ b/app-admin/eselect-opengl/eselect-opengl-1.2.6.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/eselect-opengl/eselect-opengl-1.2.6.ebuild,v 1.1 2012/06/05 11:40:27 lu_zero Exp $
+
+EAPI=4
+
+inherit multilib
+
+DESCRIPTION="Utility to change the OpenGL interface being used"
+HOMEPAGE="http://www.gentoo.org/"
+
+# Source:
+# http://www.opengl.org/registry/api/glext.h
+# http://www.opengl.org/registry/api/glxext.h
+GLEXT="75"
+GLXEXT="33"
+
+MIRROR="http://dev.gentooexperimental.org/~scarabeus/"
+SRC_URI="${MIRROR}/glext.h.${GLEXT}.xz
+	${MIRROR}/glxext.h.${GLXEXT}.xz
+	http://dev.gentoo.org/~lu_zero/distfiles/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~x64-freebsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE=""
+
+DEPEND="app-arch/xz-utils"
+RDEPEND=">=app-admin/eselect-1.2.4
+		 !<media-libs/mesa-8.0.3-r1
+		 !<x11-proto/glproto-1.4.15-r1"
+
+pkg_postinst() {
+	local impl="$(eselect opengl show)"
+	if [[ -n "${impl}"  && "${impl}" != '(none)' ]] ; then
+		eselect opengl set "${impl}"
+	fi
+}
+
+src_prepare() {
+	# don't die on Darwin users
+	if [[ ${CHOST} == *-darwin* ]] ; then
+		sed -i -e 's/libGL\.so/libGL.dylib/' opengl.eselect || die
+	fi
+}
+
+src_install() {
+	insinto "/usr/share/eselect/modules"
+	doins opengl.eselect
+	doman opengl.eselect.5
+
+	# Install global glext.h and glxext.h
+	insinto "/usr/$(get_libdir)/opengl/global/include/GL/"
+	cd "${WORKDIR}"
+	newins glext.h.${GLEXT} glext.h
+	newins glxext.h.${GLXEXT} glxext.h
+}