version bump

Package-Manager: portage-2.1.9.7/cvs/Linux x86_64

3 files changed, 247 insertions, 2 deletions

diff --git a/app-emulation/libvirt/ChangeLog b/app-emulation/libvirt/ChangeLog
index fa65d80b70c6..7d94dd276ec2 100644
--- a/app-emulation/libvirt/ChangeLog
+++ b/app-emulation/libvirt/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-emulation/libvirt
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.74 2010/09/12 15:35:41 jmbsvicetto Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/ChangeLog,v 1.75 2010/09/17 17:58:34 cardoe Exp $
+
+*libvirt-0.8.4 (17 Sep 2010)
+
+  17 Sep 2010; Doug Goldstein <cardoe@gentoo.org> +libvirt-0.8.4.ebuild:
+  version bump
 
   12 Sep 2010; Jorge Manuel B. S. Vicetto <jmbsvicetto@gentoo.org>
   libvirt-0.8.3-r1.ebuild:
diff --git a/app-emulation/libvirt/Manifest b/app-emulation/libvirt/Manifest
index 61ede3d33fbb..9ffdcb56e31d 100644
--- a/app-emulation/libvirt/Manifest
+++ b/app-emulation/libvirt/Manifest
@@ -6,8 +6,10 @@ DIST libvirt-0.8.2.tar.gz 12230368 RMD160 280c95e74c41c56686a50892105b2c41b196a1
 DIST libvirt-0.8.3-backports-2.tar.bz2 3667 RMD160 609e1fe166e9c27ed8d3fac04a1db6d2fd374b54 SHA1 5a7faada120ec91088c7e8a357e6554729e3d2c3 SHA256 0dc2d15229acabb6bec3ce1dcf41f483d0a180e82605c274b52af658a4b19529
 DIST libvirt-0.8.3-backports-3.tar.bz2 10617 RMD160 95c85f39cf670cbf9ad5151a00870205791bcb68 SHA1 0ce917e4a1d2210d7528323ef3a892391d3ffb49 SHA256 d9077e107b8e3976a7404090dbf158776fd99837225b4cec65dcca5fd00b0d4c
 DIST libvirt-0.8.3.tar.gz 12430752 RMD160 0ff7561efc45f472c44fc950153cba180222096b SHA1 4dc92139031f2af3141c2b1d0813b57ecd735c5d SHA256 35e1836c3947ac3edd7b4a1948cf13f5f13dd3e5bb31933d627d771b1e997a1f
+DIST libvirt-0.8.4.tar.gz 12726557 RMD160 c4fe8756aa952a6fa3ff276e5bcccb99020294a4 SHA1 dd960237bc54daa3260632763fea21bbb4774c04 SHA256 9c683b910a0b1d22c64065efa79668c954fa378a1699e06ea7393f4822f7ae29
 EBUILD libvirt-0.8.2-r1.ebuild 6939 RMD160 c43ffaab435a3da080299654b78f9c9be23fe1fc SHA1 0c18d51ea742aeed29f5e5fcec2b67cf371c853f SHA256 40216ed24efcbfc7d61004949ae6f2ed9b5c0f877a70174c2100023099cdc751
 EBUILD libvirt-0.8.3-r1.ebuild 7165 RMD160 f343cbc5a6d7a1691a665690e2c1cd6ae94cc39e SHA1 6800ad7303724c412f7a92198be46dfa73df91c6 SHA256 36fabe87c7423e7a6ddf8bdaca1170d020968772f7bff10262ac356a69658b32
 EBUILD libvirt-0.8.3.ebuild 7073 RMD160 b6b3a4f066b596b75428927f7738a035a8b3b11d SHA1 c6f26e2a7bf01923992cedc209f8759149b01e40 SHA256 bddf8af7df11a963855564d2634686c28a9357c57a50e444ea6d5ab8adf856c4
-MISC ChangeLog 17001 RMD160 0fb098908286fae07bee9059db1ccc47b6f1711d SHA1 035e3b5f85d2c542cdca84460b8b9c9acb5a9410 SHA256 90cbd02e1ea46226b776aebf193a34a14c2dd75152926be66344943db4b9a927
+EBUILD libvirt-0.8.4.ebuild 7158 RMD160 cf61d91f1c3ce1a4bf2044ec5d62be3bdf5f61ba SHA1 5a8d6a2a66d49fa5225e0eca244a17d8bc96ce43 SHA256 2b0937ac50c59f7f578342db9626b719bd68e2b7be10df7ac8d0133530425685
+MISC ChangeLog 17115 RMD160 5693f5984f24bc2a24bf790f72a010d06fd10051 SHA1 5b5574f465c3d3f4c4a02cb38f9e5c055770f561 SHA256 2164f279f1dfbfd56794ed74adb55c024ead36c2caaded6aaec372ab3b917011
 MISC metadata.xml 1984 RMD160 0cc10b41e5080a8041cf05f9a37262ab7901fb4f SHA1 abefbdf96e86e4ca4ac2b9017c3c07a9d5fb7c9e SHA256 c69015c29667266301606d74334da95d61fd26f06e3ec1ca434f141e3a8107eb
diff --git a/app-emulation/libvirt/libvirt-0.8.4.ebuild b/app-emulation/libvirt/libvirt-0.8.4.ebuild
new file mode 100644
index 000000000000..151b99a7b2a6
--- /dev/null
+++ b/app-emulation/libvirt/libvirt-0.8.4.ebuild
@@ -0,0 +1,238 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/libvirt/libvirt-0.8.4.ebuild,v 1.1 2010/09/17 17:58:34 cardoe Exp $
+
+#BACKPORTS=3
+
+EAPI="2"
+
+PYTHON_DEPEND="python? 2:2.4"
+#RESTRICT_PYTHON_ABIS="3.*"
+#SUPPORT_PYTHON_ABIS="1"
+
+inherit eutils python autotools
+
+DESCRIPTION="C toolkit to manipulate virtual machines"
+HOMEPAGE="http://www.libvirt.org/"
+SRC_URI="http://libvirt.org/sources/${P}.tar.gz
+	${BACKPORTS:+mirror://gentoo/${P}-backports-${BACKPORTS}.tar.bz2}"
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="avahi caps debug iscsi +libvirtd lvm +lxc macvtap +network nfs nls \
+	numa openvz parted pcap phyp policykit python qemu sasl selinux
+	uml virtualbox xen udev"
+# IUSE=one : bug #293416 & bug #299011
+
+RDEPEND="sys-libs/readline
+	sys-libs/ncurses
+	>=net-misc/curl-7.18.0
+	>=dev-libs/libxml2-2.7.6
+	>=dev-libs/libnl-1.1
+	>=net-libs/gnutls-1.0.25
+	sys-fs/sysfsutils
+	sys-apps/util-linux
+	>=net-analyzer/netcat6-1.0-r2
+	avahi? ( >=net-dns/avahi-0.6[dbus] )
+	caps? ( sys-libs/libcap-ng )
+	iscsi? ( sys-block/open-iscsi )
+	libvirtd? ( net-misc/bridge-utils )
+	lvm? ( >=sys-fs/lvm2-2.02.48-r2 )
+	macvtap? ( >=dev-libs/libnl-1.1 )
+	nfs? ( net-fs/nfs-utils )
+	numa? ( sys-process/numactl )
+	openvz? ( sys-kernel/openvz-sources )
+	parted? ( >=sys-block/parted-1.8[device-mapper] )
+	pcap? ( >=net-libs/libpcap-1.0.0 )
+	phyp? ( net-libs/libssh2 )
+	policykit? ( >=sys-auth/polkit-0.9 )
+	qemu? ( || ( app-emulation/qemu-kvm >=app-emulation/qemu-0.10.0 app-emulation/qemu-kvm-spice ) )
+	sasl? ( dev-libs/cyrus-sasl )
+	selinux? ( >=sys-libs/libselinux-2.0.85 )
+	virtualbox? ( || ( >=app-emulation/virtualbox-ose-2.2.0 >=app-emulation/virtualbox-bin-2.2.0 ) )
+	xen? ( app-emulation/xen-tools app-emulation/xen )
+	udev? ( >=sys-fs/udev-145 >=x11-libs/libpciaccess-0.10.9 )"
+# one? ( dev-libs/xmlrpc-c )
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+pkg_setup() {
+	python_set_active_version 2
+}
+
+src_prepare() {
+	[[ -n ${BACKPORTS} ]] && \
+		EPATCH_FORCE=yes EPATCH_SUFFIX="patch" EPATCH_SOURCE="${S}/patches" \
+			epatch
+
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=""
+
+	myconf="${myconf} $(use_enable debug)"
+
+	## enable/disable daemon, otherwise client only utils
+	myconf="${myconf} $(use_with libvirtd)"
+
+	## enable/disable the daemon using avahi to find VMs
+	myconf="${myconf} $(use_with avahi)"
+
+	## hypervisors on the local host
+	myconf="${myconf} $(use_with xen) $(use_with xen xen-inotify)"
+	if ! use policykit && use xen; then
+		myconf="${myconf} --with-xen-proxy"
+	fi
+	myconf="${myconf} $(use_with openvz)"
+	myconf="${myconf} $(use_with lxc)"
+	if use virtualbox && has_version app-emulation/virtualbox-ose; then
+		myconf="${myconf} --with-vbox=/usr/lib/virtualbox-ose/"
+	else
+		myconf="${myconf} $(use_with virtualbox vbox)"
+	fi
+	myconf="${myconf} $(use_with uml)"
+	myconf="${myconf} $(use_with qemu)"
+	# doesn't belong with hypervisors but links to libvirtd for some reason
+	#myconf="${myconf} $(use_with one)"
+
+	## hypervisor protocols
+	myconf="${myconf} $(use_with phyp)"
+	myconf="${myconf} --with-esx"
+
+	## additional host drivers
+	myconf="${myconf} $(use_with network)"
+	myconf="${myconf} --with-storage-fs"
+	myconf="${myconf} $(use_with lvm storage-lvm)"
+	myconf="${myconf} $(use_with iscsi storage-iscsi)"
+	myconf="${myconf} $(use_with parted storage-disk)"
+	myconf="${myconf} $(use_with lvm storage-mpath)"
+	myconf="${myconf} $(use_with numa numactl)"
+	myconf="${myconf} $(use_with selinux)"
+
+	# udev for device support details
+	myconf="${myconf} $(use_with udev)"
+
+	# linux capability support so we don't need privileged accounts
+	myconf="${myconf} $(use_with caps capng)"
+
+	## auth stuff
+	myconf="${myconf} $(use_with policykit polkit)"
+	myconf="${myconf} $(use_with sasl)"
+
+	# network biits
+	myconf="${myconf} $(use_with pcap libpcap)"
+	myconf="${myconf} $(use_with macvtap)"
+
+	## other
+	myconf="${myconf} $(use_enable nls)"
+	myconf="${myconf} $(use_with python)"
+
+	## stuff we don't yet support
+	myconf="${myconf} --without-netcf"
+
+	# we use udev over hal
+	myconf="${myconf} --without-hal"
+
+	# this is a nasty trick to work around the problem in bug
+	# #275073. The reason why we don't solve this properly is that
+	# it'll require us to rebuild autotools (and we don't really want
+	# to do that right now). The proper solution has been sent
+	# upstream and should hopefully land in 0.7.7, in the mean time,
+	# mime the same functionality with this.
+	case ${CHOST} in
+		*cygwin* | *mingw* )
+			;;
+		*)
+			ac_cv_prog_WINDRES=no
+			;;
+	esac
+
+	econf \
+		${myconf} \
+		--disable-static \
+		--docdir=/usr/share/doc/${PF} \
+		--with-remote \
+		--localstatedir=/var \
+		--with-remote-pid-file=/var/run/libvirtd.pid
+}
+
+src_test() {
+	# Explicitly allow parallel build of tests
+	emake check || die "tests failed"
+}
+
+src_install() {
+	emake install \
+		DESTDIR="${D}" \
+		HTML_DIR=/usr/share/doc/${PF}/html \
+		DOCS_DIR=/usr/share/doc/${PF}/python \
+		EXAMPLE_DIR=/usr/share/doc/${PF}/python/examples \
+		|| die "emake install failed"
+
+	find "${D}" -name '*.la' -delete || die
+
+	use libvirtd || return 0
+	# From here, only libvirtd-related instructions, be warned!
+
+	newinitd "${FILESDIR}/libvirtd.init-r1" libvirtd || die
+	newconfd "${FILESDIR}/libvirtd.confd-r1" libvirtd || die
+
+	keepdir /var/lib/libvirt/images
+}
+
+pkg_preinst() {
+	# we only ever want to generate this once
+	if [[ -e "${ROOT}"/etc/libvirt/qemu/networks/default.xml ]]; then
+		rm -rf "${D}"/etc/libvirt/qemu/networks/default.xml
+	fi
+
+	# We really don't want to use or support old PolicyKit cause it
+	# screws with the new polkit integration
+	if has_version sys-auth/policykit; then
+		rm -rf "${D}"/usr/share/PolicyKit/policy/org.libvirt.unix.policy
+	fi
+}
+
+pkg_postinst() {
+	use python && python_mod_optimize $(python_get_sitedir)/libvirt.py
+
+	elog
+	if use policykit && has_version sys-auth/policykit; then
+		elog "You must have run the following at least once:"
+		elog
+		elog "$ polkit-auth --grant org.libvirt.unix.manage --user \"USERNAME\""
+		elog
+		elog "to grant USERNAME access to libvirt when using USE=policykit"
+	else
+		elog "To allow normal users to connect to libvirtd you must change the"
+		elog " unix sock group and/or perms in /etc/libvirt/libvirtd.conf"
+	fi
+
+	use libvirtd || return 0
+	# From here, only libvirtd-related instructions, be warned!
+
+	elog
+	elog "For the basic networking support (bridged and routed networks)"
+	elog "you don't need any extra software. For more complex network modes"
+	elog "including but not limited to NATed network, you'll need the"
+	elog "following packages":
+	elog
+	elog "	net-dns/dnsmasq"
+	elog "	>=net-firewall/iptables-1.4.9"
+	elog "	net-firewall/ebtables"
+	elog
+	if has_version net-dns/dnsmasq; then
+		ewarn "If you have a DNS server setup on your machine, you will have"
+		ewarn "to configure /etc/dnsmasq.conf to enable the following settings: "
+		ewarn " bind-interfaces"
+		ewarn " interface or except-interface"
+		ewarn
+		ewarn "Otherwise you might have issues with your existing DNS server."
+	fi
+}
+
+pkg_postrm() {
+	use python && python_mod_cleanup $(python_get_sitedir)/libvirt.py
+}