Fix documentation install breakage with glibmm-2.27.97

Package-Manager: portage-2.1.9.42/cvs/Linux x86_64

2 files changed, 58 insertions, 1 deletions

diff --git a/dev-cpp/libxmlpp/ChangeLog b/dev-cpp/libxmlpp/ChangeLog
index 64f5d1b6f771..2bdaa511de40 100644
--- a/dev-cpp/libxmlpp/ChangeLog
+++ b/dev-cpp/libxmlpp/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-cpp/libxmlpp
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-cpp/libxmlpp/ChangeLog,v 1.104 2011/03/12 19:50:01 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-cpp/libxmlpp/ChangeLog,v 1.105 2011/03/21 01:23:24 nirbheek Exp $
+
+*libxmlpp-2.32.0-r1 (21 Mar 2011)
+
+  21 Mar 2011; Nirbheek Chauhan <nirbheek@gentoo.org>
+  +libxmlpp-2.32.0-r1.ebuild:
+  Fix documentation install breakage with glibmm-2.27.97
 
   12 Mar 2011; Raúl Porcel <armin76@gentoo.org> libxmlpp-2.32.0.ebuild:
   alpha/ia64/sparc stable wrt #353436
diff --git a/dev-cpp/libxmlpp/libxmlpp-2.32.0-r1.ebuild b/dev-cpp/libxmlpp/libxmlpp-2.32.0-r1.ebuild
new file mode 100644
index 000000000000..f409011c0b01
--- /dev/null
+++ b/dev-cpp/libxmlpp/libxmlpp-2.32.0-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-cpp/libxmlpp/libxmlpp-2.32.0-r1.ebuild,v 1.1 2011/03/21 01:23:24 nirbheek Exp $
+
+EAPI="3"
+
+inherit autotools gnome2
+
+MY_PN="${PN/pp/++}"
+MY_P="${MY_PN}-${PV}"
+S="${WORKDIR}/${MY_P}"
+
+DESCRIPTION="C++ wrapper for the libxml2 XML parser library"
+HOMEPAGE="http://libxmlplusplus.sourceforge.net/"
+SRC_URI="mirror://gnome/sources/libxml++/${PV%.*}/${MY_P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="2.6"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="doc"
+
+RDEPEND=">=dev-libs/libxml2-2.6.1
+	>=dev-cpp/glibmm-2.4"
+
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	doc? ( >=dev-cpp/mm-common-0.9.3 )"
+
+DOCS="AUTHORS ChangeLog NEWS README*"
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# don't waste time building the examples
+	sed 's/^\(SUBDIRS =.*\)examples\(.*\)$/\1\2/' \
+		-i Makefile.am Makefile.in || die "sed Makefile.in failed"
+
+	# doc-install.pl was removed from glibmm, and is provided by mm-common now
+	# This should not be needed if the tarball is generated with mm-common-0.9.3
+	if use doc && has_version '>=dev-cpp/glibmm-2.27.97'; then
+		mm-common-prepare --copy --force
+		eautoreconf
+	fi
+}
+
+src_install() {
+	gnome2_src_install
+
+	rm -fr "${ED}"usr/share/doc/libxml++*
+	use doc && dohtml docs/reference/html/*
+}