initial commit

Package-Manager: portage-2.2.0_alpha67/cvs/Linux x86_64

1 files changed, 57 insertions, 0 deletions

diff --git a/dev-db/lib_mysqludf_log/lib_mysqludf_log-0.0.2.ebuild b/dev-db/lib_mysqludf_log/lib_mysqludf_log-0.0.2.ebuild
new file mode 100644
index 000000000000..69cf1a9f8f17
--- /dev/null
+++ b/dev-db/lib_mysqludf_log/lib_mysqludf_log-0.0.2.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-db/lib_mysqludf_log/lib_mysqludf_log-0.0.2.ebuild,v 1.1 2011/10/19 12:15:36 sbriesen Exp $
+
+EAPI=4
+
+inherit eutils toolchain-funcs
+
+DESCRIPTION="MySQL UDF to write to log files"
+HOMEPAGE="http://www.mysqludf.org/lib_mysqludf_log/"
+SRC_URI="http://www.mysqludf.org/${PN}/${PN}_${PV}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND=">=virtual/mysql-5.1"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}"
+
+# compile helper
+_compile() {
+	local CC="$(tc-getCC)"
+	echo "${CC} ${@}" && "${CC}" "${@}"
+}
+
+pkg_setup() {
+	MYSQL_PLUGINDIR="$(mysql_config --plugindir)"
+	MYSQL_INCLUDE="$(mysql_config --include)"
+}
+
+src_prepare() {
+	epatch "${FILESDIR}/${PN}-warnings.patch"
+}
+
+src_compile() {
+	_compile ${CFLAGS} -Wall -fPIC ${MYSQL_INCLUDE} \
+		-shared ${LDFLAGS} -o ${PN}.so ${PN}.c
+}
+
+src_install() {
+	exeinto "${MYSQL_PLUGINDIR}"
+	doexe ${PN}.so
+	dodoc ${PN}.sql
+}
+
+pkg_postinst() {
+	elog
+	elog "Please have a look at the documentation, how to"
+	elog "enable/disable the UDF functions of ${PN}."
+	elog
+	elog "The documentation is located here:"
+	elog "/usr/share/doc/${PF}"
+	elog
+}