Version bump.

Package-Manager: portage-2.2.0_alpha89/cvs/Linux x86_64

2 files changed, 59 insertions, 2 deletions

diff --git a/dev-java/ant-eclipse-ecj/ChangeLog b/dev-java/ant-eclipse-ecj/ChangeLog
index 11a756c72b3f..90b2b1ad678d 100644
--- a/dev-java/ant-eclipse-ecj/ChangeLog
+++ b/dev-java/ant-eclipse-ecj/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-java/ant-eclipse-ecj
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-java/ant-eclipse-ecj/ChangeLog,v 1.29 2011/12/14 18:50:23 ago Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-java/ant-eclipse-ecj/ChangeLog,v 1.30 2012/03/03 22:15:57 caster Exp $
+
+*ant-eclipse-ecj-3.7.2 (03 Mar 2012)
+
+  03 Mar 2012; Vlastimil Babka <caster@gentoo.org>
+  +ant-eclipse-ecj-3.7.2.ebuild:
+  Version bump.
 
   14 Dec 2011; Agostino Sarubbo <ago@gentoo.org> ant-eclipse-ecj-3.7.1.ebuild:
   Stable for AMD64, wrt bug #392391
diff --git a/dev-java/ant-eclipse-ecj/ant-eclipse-ecj-3.7.2.ebuild b/dev-java/ant-eclipse-ecj/ant-eclipse-ecj-3.7.2.ebuild
new file mode 100644
index 000000000000..35e1dbb2ffb3
--- /dev/null
+++ b/dev-java/ant-eclipse-ecj/ant-eclipse-ecj-3.7.2.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-java/ant-eclipse-ecj/ant-eclipse-ecj-3.7.2.ebuild,v 1.1 2012/03/03 22:15:57 caster Exp $
+
+EAPI=4
+
+inherit java-pkg-2
+
+DMF="R-${PV}-201202080800"
+S="${WORKDIR}"
+
+DESCRIPTION="Ant Compiler Adapter for Eclipse Java Compiler"
+HOMEPAGE="http://www.eclipse.org/"
+SRC_URI="http://download.eclipse.org/eclipse/downloads/drops/${DMF/.0}/ecjsrc-${PV}.jar"
+
+LICENSE="EPL-1.0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
+SLOT="3.7"
+IUSE=""
+
+RDEPEND=">=virtual/jre-1.4
+	~dev-java/eclipse-ecj-${PV}
+	>=dev-java/ant-core-1.7"
+DEPEND="${RDEPEND}
+	app-arch/unzip
+	>=virtual/jdk-1.4"
+
+src_unpack() {
+	unpack ${A}
+	mkdir -p src/org/eclipse/jdt/{core,internal}
+	cp org/eclipse/jdt/core/JDTCompilerAdapter.java \
+		src/org/eclipse/jdt/core || die
+	cp -r org/eclipse/jdt/internal/antadapter \
+		src/org/eclipse/jdt/internal || die
+	rm -fr about* org
+}
+
+src_compile() {
+	cd src
+	java-pkg_filter-compiler jikes
+	ejavac -classpath "$(java-pkg_getjars ant-core,eclipse-ecj-${SLOT})" \
+		$(find org/ -name '*.java') || die "ejavac failed!"
+	find org/ -name '*.class' -o -name '*.properties' | \
+			xargs jar cf "${S}/${PN}.jar" || die "jar failed!"
+}
+
+src_install() {
+	java-pkg_dojar ${PN}.jar
+	insinto /usr/share/java-config-2/compiler
+	doins "${FILESDIR}/ecj-${SLOT}"
+}