Support installing Mercury code samples

Package-Manager: portage-2.1.8.3/cvs/Linux x86_64

3 files changed, 210 insertions, 2 deletions

diff --git a/dev-lang/mercury/ChangeLog b/dev-lang/mercury/ChangeLog
index bc934f9d18df..7c6cf1897032 100644
--- a/dev-lang/mercury/ChangeLog
+++ b/dev-lang/mercury/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-lang/mercury
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/mercury/ChangeLog,v 1.120 2010/10/22 21:08:25 keri Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/mercury/ChangeLog,v 1.121 2010/10/22 22:23:30 keri Exp $
+
+*mercury-10.04.2-r1 (22 Oct 2010)
+
+  22 Oct 2010; <keri@gentoo.org> +mercury-10.04.2-r1.ebuild:
+  Support installing Mercury code samples
 
   22 Oct 2010; <keri@gentoo.org> files/mercury-10.04.2-no-reconf.patch:
   Tidy up no-reconf target in Mercury toplevel
diff --git a/dev-lang/mercury/Manifest b/dev-lang/mercury/Manifest
index f302ffe57149..20f65ab666b8 100644
--- a/dev-lang/mercury/Manifest
+++ b/dev-lang/mercury/Manifest
@@ -66,8 +66,9 @@ DIST mercury-tests-10.04.tar.gz 1329423 RMD160 c85e489eea4e36fef6d12fb9bf4e7cd01
 EBUILD mercury-0.13.1-r2.ebuild 3350 RMD160 8a1635d8c301751b2da7260785baaa788b81b620 SHA1 2aae241faf85518b6bb6d162939b2f293eb67649 SHA256 af0a034331b9a7acb0d0a7dea42fc84aafcf9e66de2b6fceddc623f975689c44
 EBUILD mercury-10.04-r1.ebuild 4397 RMD160 ac0c5f73a0468ad0b975c7b4e45fd962cd3d1b42 SHA1 b7d1d4b635f916f1be1a4fc496c2d80f9949ab30 SHA256 55dfdb3ae95f0dfc74014d2f87085d568316c84d78d74805e30c8674f8ece543
 EBUILD mercury-10.04.1.ebuild 4915 RMD160 cac82413b0a1aa53998a83e07b94f1223f2a9ba1 SHA1 6754bbe32a7c4640d3aaf9df80dc30c59ba5d1eb SHA256 4cdaf57b11824775f6095cc0df92bf8b563acddf64a6e8d27b0c92155046f8f6
+EBUILD mercury-10.04.2-r1.ebuild 5317 RMD160 fc32bd39293e2113c664f97b96644eb5e1091dda SHA1 67dc39fe80a7a08f42a0648394c686487a1cdfac SHA256 1e67bc4c72dc15c4362f919dc22302e102d0093e928bfa479a3537e2137cde78
 EBUILD mercury-10.04.2.ebuild 4915 RMD160 488b30f0d614523a5e74f415ba08be5cb52b2e64 SHA1 0f68beff3fe86278634ff59f55fd24d60c7eecb4 SHA256 71c639b3eea70fcc183d5ec6803bd12e14213c590733b1c12b4c608bf5bb6b9f
 EBUILD mercury-10.04.ebuild 4150 RMD160 565ad36c8253f0da62f6a4256cbf45d2655a6223 SHA1 3f6363b22b7b4dcd0fe731f404d6d8dadb6cebff SHA256 943ee918a3113d45d268f4091de5a0767d05e99194f121771ce43c3a9c71eba0
 EBUILD mercury-10.04_beta1.ebuild 3561 RMD160 b608b732acdfccb4a8ccdc4728bdd0b9f3f28283 SHA1 319302199665f6e4ffa9aaff95128fcd8a7d63a0 SHA256 ffbba59515166327f79a698086d516f14fcbcfc8c76f58dbf1116eaa8eb16626
-MISC ChangeLog 24856 RMD160 9032ea4bd245c2dee6eedf62efdb6875e585eba2 SHA1 af6a41bc88cf5ac609a3493c9b38e93ee3d56f8d SHA256 2d0d06508099f09e1a3eaa27a6ec8c322774d16210382a7924899c1f383333a3
+MISC ChangeLog 24995 RMD160 07dd94515598c5670e3e2ceedff168e0bde4aecb SHA1 2bfb242d7b5de05894bee13d9385cc2b216223bf SHA256 32f0f80d8cd042b6ad4a56e2c4bd68704405456f4cf32a17d8b1e1447622ecdc
 MISC metadata.xml 318 RMD160 b9e62c5b9d04f43a6570cfcadd6a6c9a2b9e3f6f SHA1 67893d667419e727696eb2c386565794fd137418 SHA256 5e64767eb2ff6b10d88b169c87648d62b534356fb94c5407a253aeafc2d16935
diff --git a/dev-lang/mercury/mercury-10.04.2-r1.ebuild b/dev-lang/mercury/mercury-10.04.2-r1.ebuild
new file mode 100644
index 000000000000..88b17335ef59
--- /dev/null
+++ b/dev-lang/mercury/mercury-10.04.2-r1.ebuild
@@ -0,0 +1,202 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/mercury/mercury-10.04.2-r1.ebuild,v 1.1 2010/10/22 22:23:30 keri Exp $
+
+inherit autotools elisp-common eutils flag-o-matic java-pkg-opt-2 multilib
+
+MY_P=${PN}-compiler-${PV}
+
+DESCRIPTION="Mercury is a modern general-purpose logic/functional programming language"
+HOMEPAGE="http://www.cs.mu.oz.au/research/mercury/index.html"
+SRC_URI="http://www.mercury.cs.mu.oz.au/download/files/${MY_P}.tar.gz
+	test? ( http://www.mercury.cs.mu.oz.au/download/files/mercury-tests-${PV}.tar.gz )"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+
+IUSE="debug emacs erlang examples java minimal readline test threads"
+
+DEPEND="!dev-libs/mpatrol
+	!dev-util/mono-debugger
+	readline? ( sys-libs/readline )
+	erlang? ( dev-lang/erlang )
+	java? ( >=virtual/jdk-1.5 )"
+
+RDEPEND="${DEPEND}
+	emacs? ( virtual/emacs )"
+
+S="${WORKDIR}"/${MY_P}
+TESTDIR="${WORKDIR}"/${PN}-tests-${PV}
+
+SITEFILE=50${PN}-gentoo.el
+
+src_unpack() {
+	unpack ${A}
+
+	epatch "${FILESDIR}"/${P}-multilib.patch
+	epatch "${FILESDIR}"/${P}-linker-flags.patch
+	epatch "${FILESDIR}"/${P}-bootstrap-depend.patch
+	epatch "${FILESDIR}"/${P}-default-grade.patch
+	epatch "${FILESDIR}"/${P}-boehm_gc.patch
+	epatch "${FILESDIR}"/${P}-sparc-llds-base-grade.patch
+	epatch "${FILESDIR}"/${P}-char-det-from-int.patch
+	epatch "${FILESDIR}"/${P}-docs.patch
+	epatch "${FILESDIR}"/${P}-no-reconf.patch
+
+	sed -i -e "s/@libdir@/$(get_libdir)/" \
+		"${S}"/compiler/file_util.m \
+		"${S}"/compiler/libs.file_util.c \
+		"${S}"/compiler/make.program_target.m \
+		"${S}"/compiler/make.program_target.c \
+		"${S}"/scripts/Mmake.vars.in
+
+	touch "${S}"/compiler/*.date
+	touch "${S}"/compiler/*.date0
+	touch "${S}"/compiler/*.date3
+	touch "${S}"/compiler/*.int
+	touch "${S}"/compiler/*.int0
+	touch "${S}"/compiler/*.int2
+	touch "${S}"/compiler/*.int3
+	touch "${S}"/compiler/*.c_date
+	touch "${S}"/compiler/*.c
+
+	if use test; then
+		epatch "${FILESDIR}"/${P}-tests-workspace.patch
+		epatch "${FILESDIR}"/${P}-tests-sandbox.patch
+		epatch "${FILESDIR}"/${P}-tests-static-link.patch
+	fi
+
+	cd "${S}"
+	eautoreconf
+}
+
+src_compile() {
+	strip-flags
+
+	local myconf
+	myconf="--libdir=/usr/$(get_libdir) \
+		--disable-gcc-back-end \
+		--disable-deep-profiler \
+		--disable-dotnet-grades \
+		$(use_enable erlang erlang-grade) \
+		$(use_enable java java-grade) \
+		$(use_enable debug debug-grades) \
+		$(use_enable threads par-grades) \
+		$(use_enable !minimal most-grades) \
+		$(use_with readline)"
+
+	econf \
+		${myconf} \
+		|| die "econf failed"
+
+	emake \
+		PARALLEL=${MAKEOPTS} \
+		bootstrap_depend || die "emake depend failed"
+
+	emake \
+		PARALLEL=${MAKEOPTS} \
+		EXTRA_MLFLAGS=--no-strip \
+		EXTRA_LDFLAGS="${LDFLAGS}" \
+		EXTRA_LD_LIBFLAGS="${LDFLAGS}" \
+		|| die "emake failed"
+
+	emake \
+		PARALLEL=${MAKEOPTS} \
+		EXTRA_MLFLAGS=--no-strip \
+		EXTRA_LDFLAGS="${LDFLAGS}" \
+		EXTRA_LD_LIBFLAGS="${LDFLAGS}" \
+		MERCURY_COMPILER="${S}"/compiler/mercury_compile \
+		default_grade || die "emake default_grade failed"
+}
+
+src_test() {
+	TEST_GRADE=`scripts/ml --print-grade`
+	if [ -d "${S}"/install_grade_dir.${TEST_GRADE} ] ; then
+		TWS="${S}"/install_grade_dir.${TEST_GRADE}
+		cp browser/mer_browser.init "${TWS}"/browser/
+		cp mdbcomp/mer_mdbcomp.init "${TWS}"/mdbcomp/
+		cp runtime/mer_rt.init "${TWS}"/runtime/
+		cp ssdb/mer_ssdb.init "${TWS}"/ssdb/
+	else
+		TWS="${S}"
+	fi
+
+	cd "${TESTDIR}"
+	sed -i -e "s:@WORKSPACE@:${TWS}:" WS_FLAGS.ws
+
+	PATH="${TWS}"/scripts:"${TWS}"/util:"${TWS}"/slice:"${PATH}" \
+	TERM="" \
+	WORKSPACE="${TWS}" \
+	MERCURY_COMPILER="${TWS}"/compiler/mercury_compile \
+	MERCURY_CONFIG_DIR="${TWS}" \
+	MMAKE_DIR="${TWS}"/scripts \
+	MERCURY_SUPPRESS_STACK_TRACE=yes \
+	GRADE=${TEST_GRADE} \
+	MERCURY_ALL_LOCAL_C_INCL_DIRS=" -I${TWS}/boehm_gc \
+					-I${TWS}/boehm_gc/include \
+					-I${TWS}/runtime \
+					-I${TWS}/library \
+					-I${TWS}/mdbcomp \
+					-I${TWS}/browser \
+					-I${TWS}/trace" \
+		mmake || die "mmake test failed"
+}
+
+src_install() {
+	emake \
+		PARALLEL=${MAKEOPTS} \
+		EXTRA_LDFLAGS="${LDFLAGS}" \
+		EXTRA_LD_LIBFLAGS="${LDFLAGS}" \
+		MERCURY_COMPILER="${S}"/compiler/mercury_compile \
+		INSTALL_PREFIX="${D}"/usr \
+		INSTALL_MAN_DIR="${D}"/usr/share/man \
+		INSTALL_INFO_DIR="${D}"/usr/share/info \
+		INSTALL_HTML_DIR="${D}"/usr/share/doc/${PF}/html \
+		INSTALL_ELISP_DIR="${D}/${SITELISP}"/${PN} \
+		install || die "make install failed"
+
+	if use emacs; then
+		elisp-site-file-install "${FILESDIR}/${SITEFILE}" \
+			|| die "elisp-site-file-install failed"
+	fi
+
+	dodoc \
+		BUGS HISTORY LIMITATIONS NEWS README README.Linux \
+		README.Linux-Alpha README.Linux-m68k README.Linux-PPC \
+		RELEASE_NOTES TODO VERSION WORK_IN_PROGRESS
+
+	if use erlang; then
+		dodoc README.Erlang
+	fi
+
+	if use java; then
+		dodoc README.Java
+	fi
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}/samples
+		doins samples/{*.m,README,Mmakefile}
+		doins -r samples/c_interface \
+			samples/diff \
+			samples/muz \
+			samples/rot13 \
+			samples/solutions \
+			samples/solver_types
+
+		if use java; then
+			doins -r samples/java_interface
+		fi
+
+		rm -rf $(find "${D}"/usr/share/doc/${PF}/samples \
+				-name CVS -o -name .cvsignore)
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}