Change hardcoded machine-id path to /etc wrt #390143 by Ewgenij Starostin

Package-Manager: portage-2.2.0_alpha72/cvs/Linux x86_64

3 files changed, 256 insertions, 6 deletions

diff --git a/dev-libs/glib/ChangeLog b/dev-libs/glib/ChangeLog
index 1334113d1782..43026b0a399a 100644
--- a/dev-libs/glib/ChangeLog
+++ b/dev-libs/glib/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-libs/glib
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.489 2011/10/18 14:28:10 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/ChangeLog,v 1.490 2011/11/11 17:35:20 ssuominen Exp $
+
+*glib-2.30.1-r2 (11 Nov 2011)
+
+  11 Nov 2011; Samuli Suominen <ssuominen@gentoo.org> +glib-2.30.1-r2.ebuild:
+  Change hardcoded machine-id path to /etc wrt #390143 by Ewgenij Starostin
 
   18 Oct 2011; Jeroen Roovers <jer@gentoo.org> glib-2.28.8.ebuild:
   Stable for HPPA (bug #385699).
diff --git a/dev-libs/glib/Manifest b/dev-libs/glib/Manifest
index 841178f2ab9b..5ea0b9a70c73 100644
--- a/dev-libs/glib/Manifest
+++ b/dev-libs/glib/Manifest
@@ -28,13 +28,18 @@ EBUILD glib-2.28.6.ebuild 5649 RMD160 1a57e73c13cae0a708808053ed6bd3e92c1ce29c S
 EBUILD glib-2.28.8.ebuild 7404 RMD160 df5a5f4ee06e7620b6b75a43ea6764e20626b022 SHA1 7a1418dbd1df2b8a6a511e781532a19ebdef6b63 SHA256 e21a8482d3ece513afb5620df8838f25e4b5adbd2c7e6d006e864e755d69d702
 EBUILD glib-2.30.0.ebuild 6784 RMD160 5f5107c9c6edfca27da651367ea9b2b80d400859 SHA1 c24ccc3504a798d613969ad09ac677c0429acbd2 SHA256 6f10287a368a61d99dfd9af9945bd152cad51124ce6f5a8cc94957114bb387de
 EBUILD glib-2.30.1-r1.ebuild 8313 RMD160 314e5fdb8992ddc626e91da22502e43115feafbb SHA1 dadd9966ac41ee07684a4e2e870b3b9149e5720e SHA256 3a65be6a77a78dcf876ac7d0527abb85e8317c0e283515caac77eea8a0250564
+EBUILD glib-2.30.1-r2.ebuild 8500 RMD160 cdd21e95f08c66519e465d1256a06598336ddce8 SHA1 6f5e61fe6db1bdee51ac41064a12595e97b7c863 SHA256 4f726a1fa65ba97ead4dad236729feaa78e14514de5c75d35cae0adc81af1e20
 EBUILD glib-2.30.1.ebuild 6827 RMD160 5b7cd8a5fedf380a92ca0fb70ff5c5281113a4f2 SHA1 f828c171be5e5161565ad22709b8b4a093808b27 SHA256 045bd5c3d152632dae7196d285b2b63bc0333bb976284fbcf34dc7590a495278
-MISC ChangeLog 65102 RMD160 ab2d6e58926b3178f5a41c40e4ac53d7a7591bd6 SHA1 09798e84efbcd912edf9947ee540c818d3b4a587 SHA256 3e69f8d58ee2bc722bbad80d06b2a12cde56edfa43b19ad257f2c15f07bcd516
+MISC ChangeLog 65294 RMD160 418686616ee8e65dac691bcbcef4f264d90abff2 SHA1 fb2449851ce98a64ab5571531eff3e35b5e979a3 SHA256 bfa5236b20c893404bf80f3987923cd2bda1872e92a11157d0799f657f4d121a
 MISC metadata.xml 497 RMD160 447ae0d07ac529dbe1830e383d2ef4eae7359ea7 SHA1 4cb36fafa32d53a0dbeec978b0d75f4e7acb3fa0 SHA256 a1840f7e6af57edc9fe5b54deae9e2083858d27792fda3f4e1e8e04624b17d0d
 -----BEGIN PGP SIGNATURE-----
-Version: GnuPG v2.0.17 (GNU/Linux)
+Version: GnuPG v2.0.18 (GNU/Linux)
 
-iEYEARECAAYFAk6djQAACgkQVWmRsqeSphMi0gCcC/gF9TOlqewXv8qBBWlxwguu
-5AkAnjBvT9C3QZV5f4hKmzWm4j25SFnZ
-=j8/v
+iQEcBAEBAgAGBQJOvVycAAoJEEdUh39IaPFN8OoH/3jF/7LmKktWOU66dzeXgzzP
+Gjt0DGZYvfpHqn9me2RM0xhTPkyqQ2pGi+aIYCdOGyB+mlcJE5/VXASt42E634X+
+16NorF/yD/m2ollXwjqEm0yvikRPuu7gk7hcvfoOmGC1LasGl3Hvvaoax0hD9RDH
+mIg6YEOYuxylaljYBYHeB/kUeS2cZC/T9rf1SZvmJY46HkR1WHJnkX+Ysu/FoMTN
+Wx4qiEDptZfJXaaLGAHWw7WoXNtdMvk3r8X3C0oaA+d/M+0oM9wOyGaDBbSFV5ys
+iERDEgxyb2KKr8wg7XNg0xH52x1lgQfkakziabDa9N3k+a5fIWH7B7OCLwlvHqI=
+=1HdG
 -----END PGP SIGNATURE-----
diff --git a/dev-libs/glib/glib-2.30.1-r2.ebuild b/dev-libs/glib/glib-2.30.1-r2.ebuild
new file mode 100644
index 000000000000..82c944c30892
--- /dev/null
+++ b/dev-libs/glib/glib-2.30.1-r2.ebuild
@@ -0,0 +1,240 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/glib/glib-2.30.1-r2.ebuild,v 1.1 2011/11/11 17:35:20 ssuominen Exp $
+
+EAPI="4"
+PYTHON_DEPEND="utils? 2"
+# Avoid runtime dependency on python when USE=test
+
+inherit autotools gnome.org libtool eutils flag-o-matic multilib pax-utils python virtualx
+
+DESCRIPTION="The GLib library of C routines"
+HOMEPAGE="http://www.gtk.org/"
+SRC_URI="${SRC_URI}
+	http://pkgconfig.freedesktop.org/releases/pkg-config-0.26.tar.gz" # pkg.m4 for eautoreconf
+
+LICENSE="LGPL-2"
+SLOT="2"
+IUSE="debug doc fam selinux +static-libs systemtap test utils xattr"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd ~x86-linux"
+
+RDEPEND="virtual/libiconv
+	virtual/libffi
+	sys-libs/zlib
+	xattr? ( sys-apps/attr )
+	fam? ( virtual/fam )
+	utils? ( >=dev-util/gdbus-codegen-${PV} )"
+DEPEND="${RDEPEND}
+	>=sys-devel/gettext-0.11
+	>=dev-util/gtk-doc-am-1.15
+	doc? (
+		>=dev-libs/libxslt-1.0
+		>=dev-util/gtk-doc-1.15
+		~app-text/docbook-xml-dtd-4.1.2 )
+	systemtap? ( >=dev-util/systemtap-1.3 )
+	test? (
+		sys-devel/gdb
+		=dev-lang/python-2*
+		>=dev-util/gdbus-codegen-${PV}
+		>=sys-apps/dbus-1.4.16-r2 )
+	!<dev-util/gtk-doc-1.15-r2
+	!<sys-apps/dbus-1.4.16-r2"
+PDEPEND="!<gnome-base/gvfs-1.6.4-r990" # Earlier versions do not work with glib
+
+pkg_setup() {
+	# Needed for gio/tests/gdbus-testserver.py
+	if use test ; then
+		python_set_active_version 2
+		python_pkg_setup
+	fi
+}
+
+src_prepare() {
+	mv -vf "${WORKDIR}"/pkg-config-*/pkg.m4 "${WORKDIR}"/ || die
+
+	if use ia64 ; then
+		# Only apply for < 4.1
+		local major=$(gcc-major-version)
+		local minor=$(gcc-minor-version)
+		if (( major < 4 || ( major == 4 && minor == 0 ) )); then
+			epatch "${FILESDIR}/glib-2.10.3-ia64-atomic-ops.patch"
+		fi
+	fi
+
+	# Don't fail gio tests when ran without userpriv, upstream bug 552912
+	# This is only a temporary workaround, remove as soon as possible
+#	epatch "${FILESDIR}/${PN}-2.18.1-workaround-gio-test-failure-without-userpriv.patch"
+
+	# Fix gmodule issues on fbsd; bug #184301
+	epatch "${FILESDIR}"/${PN}-2.12.12-fbsd.patch
+
+	# Fix test failure when upgrading from 2.22 to 2.24, upstream bug 621368
+	epatch "${FILESDIR}/${PN}-2.24-assert-test-failure.patch"
+
+	# Do not try to remove files on live filesystem, upstream bug #619274
+	sed 's:^\(.*"/desktop-app-info/delete".*\):/*\1*/:' \
+		-i "${S}"/gio/tests/desktop-app-info.c || die "sed failed"
+
+	if ! use test; then
+		# don't waste time building tests
+		sed 's/^\(.*\SUBDIRS .*\=.*\)tests\(.*\)$/\1\2/' -i $(find . -name Makefile.am -o -name Makefile.in) || die
+	else
+		# Disable tests requiring dev-util/desktop-file-utils when not installed, bug #286629
+		if ! has_version dev-util/desktop-file-utils ; then
+			ewarn "Some tests will be skipped due dev-util/desktop-file-utils not being present on your system,"
+			ewarn "think on installing it to get these tests run."
+			sed -i -e "/appinfo\/associations/d" gio/tests/appinfo.c || die
+			sed -i -e "/desktop-app-info\/default/d" gio/tests/desktop-app-info.c || die
+			sed -i -e "/desktop-app-info\/fallback/d" gio/tests/desktop-app-info.c || die
+			sed -i -e "/desktop-app-info\/lastused/d" gio/tests/desktop-app-info.c || die
+		fi
+
+		# Disable tests requiring dbus-python and pygobject; bugs #349236, #377549, #384853
+		if ! has_version dev-python/dbus-python || ! has_version 'dev-python/pygobject:2' ; then
+			ewarn "Some tests will be skipped due to dev-python/dbus-python or dev-python/pygobject:2"
+			ewarn "not being present on your system, think on installing them to get these tests run."
+			sed -i -e "/connection\/filter/d" gio/tests/gdbus-connection.c || die
+			sed -i -e "/connection\/large_message/d" gio/tests/gdbus-connection-slow.c || die
+			sed -i -e "/gdbus\/proxy/d" gio/tests/gdbus-proxy.c || die
+			sed -i -e "/gdbus\/proxy-well-known-name/d" gio/tests/gdbus-proxy-well-known-name.c || die
+			sed -i -e "/gdbus\/introspection-parser/d" gio/tests/gdbus-introspection.c || die
+			sed -i -e "/g_test_add_func/d" gio/tests/gdbus-threading.c || die
+			sed -i -e "/gdbus\/method-calls-in-thread/d" gio/tests/gdbus-threading.c || die
+			# needed to prevent gdbus-threading from asserting
+			ln -sfn $(type -P true) gio/tests/gdbus-testserver.py
+		fi
+	fi
+
+	# gdbus-codegen is a separate package
+	epatch "${FILESDIR}/${PN}-2.30.1-external-gdbus-codegen.patch"
+
+	# Handle the G_HOME environment variable to override the passwd entry, upstream bug #142568
+	epatch "${FILESDIR}/${PN}-2.30.1-homedir-env.patch"
+
+	# Fix hardcoded path to machine-id wrt #390143
+	sed -i -e '/g_file_get_contents/s:/var/lib/dbus/machine-id:/etc/machine-id:' gio/gdbusprivate.c || die
+
+	# disable pyc compiling
+	ln -sfn $(type -P true) py-compile
+
+	# Needed for the punt-python-check patch, disabling timeout test
+	# Also needed to prevent croscompile failures, see bug #267603
+	# Also needed for the no-gdbus-codegen patch
+	AT_M4DIR="${WORKDIR}" eautoreconf
+
+	[[ ${CHOST} == *-freebsd* ]] && elibtoolize
+
+	epunt_cxx
+}
+
+src_configure() {
+	# Avoid circular depend with dev-util/pkgconfig
+	if ! has_version dev-util/pkgconfig; then
+		if has_version sys-apps/dbus; then
+			export DBUS1_CFLAGS="-I/usr/include/dbus-1.0 -I/usr/$(get_libdir)/dbus-1.0/include"
+			export DBUS1_LIBS="-ldbus-1"
+		fi
+		export LIBFFI_CFLAGS="-I$(echo /usr/$(get_libdir)/libffi-*/include)"
+		export LIBFFI_LIBS="-lffi"
+	fi
+
+	local myconf
+
+	# Building with --disable-debug highly unrecommended.  It will build glib in
+	# an unusable form as it disables some commonly used API.  Please do not
+	# convert this to the use_enable form, as it results in a broken build.
+	# -- compnerd (3/27/06)
+	use debug && myconf="--enable-debug"
+
+	# Always use internal libpcre, bug #254659
+	econf ${myconf} \
+		$(use_enable xattr) \
+		$(use_enable doc man) \
+		$(use_enable doc gtk-doc) \
+		$(use_enable fam) \
+		$(use_enable selinux) \
+		$(use_enable static-libs static) \
+		$(use_enable systemtap dtrace) \
+		$(use_enable systemtap systemtap) \
+		--enable-regex \
+		--with-pcre=internal \
+		--with-threads=posix
+}
+
+src_install() {
+	local f
+
+	# install-exec-hook substitutes ${PYTHON} in glib/gtester-report
+	emake DESTDIR="${D}" PYTHON="${EPREFIX}/usr/bin/python2" install
+
+	if ! use utils; then
+		rm "${ED}usr/bin/gtester-report"
+	fi
+
+	# Do not install charset.alias even if generated, leave it to libiconv
+	rm -f "${ED}/usr/lib/charset.alias"
+
+	# Don't install gdb python macros, bug 291328
+	rm -rf "${ED}/usr/share/gdb/" "${ED}/usr/share/glib-2.0/gdb/"
+
+	dodoc AUTHORS ChangeLog* NEWS* README
+
+	insinto /usr/share/bash-completion
+	for f in gdbus gsettings; do
+		newins "${ED}/etc/bash_completion.d/${f}-bash-completion.sh" ${f}
+	done
+	rm -rf "${ED}/etc"
+
+	# Completely useless with or without USE static-libs, people need to use
+	# pkg-config
+	find "${D}" -name '*.la' -exec rm -f {} +
+}
+
+src_test() {
+	unset DBUS_SESSION_BUS_ADDRESS
+	export XDG_CONFIG_DIRS=/etc/xdg
+	export XDG_DATA_DIRS=/usr/local/share:/usr/share
+	export G_DBUS_COOKIE_SHA1_KEYRING_DIR="${T}/temp"
+	export XDG_DATA_HOME="${T}"
+	unset GSETTINGS_BACKEND # bug 352451
+
+	# Related test is a bit nitpicking
+	mkdir "$G_DBUS_COOKIE_SHA1_KEYRING_DIR"
+	chmod 0700 "$G_DBUS_COOKIE_SHA1_KEYRING_DIR"
+
+	# Hardened: gdb needs this, bug #338891
+	if host-is-pax ; then
+		pax-mark -mr "${S}"/tests/.libs/assert-msg-test \
+			|| die "Hardened adjustment failed"
+	fi
+
+	# Need X for dbus-launch session X11 initialization
+	Xemake check
+}
+
+pkg_preinst() {
+	# Only give the introspection message if:
+	# * The user has gobject-introspection
+	# * Has glib already installed
+	# * Previous version was different from new version
+	if has_version "dev-libs/gobject-introspection" && ! has_version "=${CATEGORY}/${PF}"; then
+		ewarn "You must rebuild gobject-introspection so that the installed"
+		ewarn "typelibs and girs are regenerated for the new APIs in glib"
+	fi
+}
+
+pkg_postinst() {
+	# Inform users about possible breakage when updating glib and not dbus-glib, bug #297483
+	if has_version dev-libs/dbus-glib; then
+		ewarn "If you experience a breakage after updating dev-libs/glib try"
+		ewarn "rebuilding dev-libs/dbus-glib"
+	fi
+
+	if has_version '<x11-libs/gtk+-3.0.12:3'; then
+		# To have a clear upgrade path for gtk+-3.0.x users, have to resort to
+		# a warning instead of a blocker
+		ewarn
+		ewarn "Using <gtk+-3.0.12:3 with ${P} results in frequent crashes."
+		ewarn "You should upgrade to a newer version of gtk+:3 immediately."
+	fi
+}