Migrate to distutils-r1.

Package-Manager: portage-2.2.0_alpha148/cvs/Linux x86_64
Manifest-Sign-Key: 0x42B9401D

1 files changed, 51 insertions, 0 deletions

diff --git a/dev-python/pygments/pygments-1.5-r1.ebuild b/dev-python/pygments/pygments-1.5-r1.ebuild
new file mode 100644
index 000000000000..dec444f38df3
--- /dev/null
+++ b/dev-python/pygments/pygments-1.5-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pygments/pygments-1.5-r1.ebuild,v 1.1 2012/12/13 10:24:39 mgorny Exp $
+
+EAPI=4
+PYTHON_COMPAT=( python{2_6,2_7,3_1,3_2} pypy{1_8,1_9} )
+
+inherit distutils-r1
+
+MY_PN="Pygments"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Pygments is a syntax highlighting package written in Python."
+HOMEPAGE="http://pygments.org/ http://pypi.python.org/pypi/Pygments"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc test"
+
+RDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		virtual/ttf-fonts
+		dev-texlive/texlive-latexrecommended
+	)"
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS=( CHANGES )
+
+python_test() {
+	cp -r -l tests "${BUILD_DIR}"/ || die
+
+	if [[ ${EPYTHON} == python3.* ]]; then
+		# Notes:
+		#   -W is not supported by python3.1
+		#   -n causes Python to write into hardlinked files
+		2to3 -w "${BUILD_DIR}"/tests/*.py || die
+	fi
+
+	nosetests -w "${BUILD_DIR}"/tests || die
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/build/. )
+
+	distutils-r1_python_install_all
+}