Version bump. Drop x86 keyword, bug 417587.

Package-Manager: portage-2.1.10.49/cvs/Linux x86_64

1 files changed, 48 insertions, 0 deletions

diff --git a/dev-ruby/rspec-expectations/rspec-expectations-2.10.0.ebuild b/dev-ruby/rspec-expectations/rspec-expectations-2.10.0.ebuild
new file mode 100644
index 000000000000..1a263c05d659
--- /dev/null
+++ b/dev-ruby/rspec-expectations/rspec-expectations-2.10.0.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/rspec-expectations/rspec-expectations-2.10.0.ebuild,v 1.1 2012/06/10 06:51:00 graaff Exp $
+
+EAPI=4
+USE_RUBY="ruby18 ree18 ruby19 jruby"
+
+RUBY_FAKEGEM_TASK_TEST="none"
+
+RUBY_FAKEGEM_TASK_DOC=""
+RUBY_FAKEGEM_EXTRADOC="Changelog.md README.md"
+
+inherit ruby-fakegem
+
+DESCRIPTION="A Behaviour Driven Development (BDD) framework for Ruby"
+HOMEPAGE="http://rspec.rubyforge.org/"
+SRC_URI="https://github.com/rspec/${PN}/tarball/v${PV} -> ${P}-git.tgz"
+RUBY_S="rspec-${PN}-*"
+
+LICENSE="MIT"
+SLOT="2"
+KEYWORDS="~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE=""
+
+ruby_add_rdepend ">=dev-ruby/diff-lcs-1.1.2"
+
+ruby_add_bdepend "test? (
+		>=dev-ruby/rspec-core-2.10.0:2
+		dev-ruby/rspec-mocks:2
+	)"
+
+# Not clear yet to what extend we need those (now)
+#	>=dev-ruby/cucumber-0.6.2
+#	>=dev-ruby/aruba-0.1.1"
+
+all_ruby_prepare() {
+	# Don't set up bundler: it doesn't understand our setup.
+	sed -i -e '/[Bb]undler/d' Rakefile || die
+
+	# Remove the Gemfile to avoid running through 'bundle exec'
+	rm Gemfile || die
+}
+
+each_ruby_test() {
+	PATH="${S}/bin:${PATH}" RUBYLIB="${S}/lib" ${RUBY} -S rspec spec || die
+
+	# There are features but they require aruba which we don't have yet.
+}