revbump with installing more of new contrib.

Package-Manager: portage-2.2_rc98/cvs/Linux x86_64

3 files changed, 466 insertions, 2 deletions

diff --git a/dev-vcs/git/ChangeLog b/dev-vcs/git/ChangeLog
index 26c238b2a461..1eed951f33df 100644
--- a/dev-vcs/git/ChangeLog
+++ b/dev-vcs/git/ChangeLog
@@ -1,7 +1,12 @@
 # ChangeLog for dev-vcs/git
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-vcs/git/ChangeLog,v 1.40 2010/10/22 20:22:38 tove Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/git/ChangeLog,v 1.41 2010/10/26 21:06:34 robbat2 Exp $
 
+*git-1.7.3.2-r1 (26 Oct 2010)
+
+  26 Oct 2010; Robin H. Johnson <robbat2@gentoo.org> +git-1.7.3.2-r1.ebuild:
+  revbump with installing more of new contrib.
+  
   22 Oct 2010; Daniel Pielmeier <billie@gentoo.org>
   +files/git-1.6.6.1-interix6.patch, +files/git-1.7.1-interix.patch:
   Interix patches are still needed for some older versions.
diff --git a/dev-vcs/git/Manifest b/dev-vcs/git/Manifest
index d4dd02c07e67..978f2d58f20c 100644
--- a/dev-vcs/git/Manifest
+++ b/dev-vcs/git/Manifest
@@ -48,8 +48,9 @@ EBUILD git-1.7.2.2.ebuild 13349 RMD160 8fe7b57a926639b7ac6363fd07c0ccf13c585bbb
 EBUILD git-1.7.2.3.ebuild 13370 RMD160 3855903ad44eb43608eb5d153ce52ca380fcc4b0 SHA1 a019f5d6de0a538a68a8085fe1a94aeacb068080 SHA256 7de0a88fb6e69083db6d5cc5c42d6d162471872a52f3930548dd8b51317284ef
 EBUILD git-1.7.2.ebuild 11473 RMD160 4a1bdd7d0ffbc8f677fe41216fb7b5e87f70ea3b SHA1 f5c98b2bb8e2240d9dbb43d6f6c4592916dcf5bd SHA256 7748e46b9b8cc17dd4028a4414f9fc578c4e479d85b07a957fff3ddf508bbb0f
 EBUILD git-1.7.3.1.ebuild 13370 RMD160 9d73585d0bc90eba370bd67594f52bc157c69210 SHA1 5fe8b7b5378cea6fb41b33e6bcaedbdda6a84dc3 SHA256 1c2c0328edfe57977ecacc01bfa59835231cb4e9eb5e83d78c739ae95030da72
+EBUILD git-1.7.3.2-r1.ebuild 13178 RMD160 d578bbb31a6e3105e270d9f4112da1affc4cac49 SHA1 e4802e45bc0efbe7e425ebe360e232164b481fda SHA256 b88ab481265c5fe27345ae96eeadbb1cb5efee0009d95fbadb68953b559690d9
 EBUILD git-1.7.3.2.ebuild 12898 RMD160 9b2843892449f4be9ee70344395dfbb5475cb295 SHA1 b4f5b192bf86879124e1feb94d3d933819bcbfdd SHA256 ddd94e13359010ef6c5aaf1a03d2f99fb174a6dbe7f230ec55360321c551fa15
 EBUILD git-1.7.3.ebuild 13368 RMD160 62b50fd606cda218805b236083c5c826420eb9a2 SHA1 f9096b5a7aa7e64927c642e673f914e80316e120 SHA256 e6595b040a14b93a683f0cf2444f7a05a9f9042a524556eb1696ac1d21297831
 EBUILD git-9999.ebuild 11299 RMD160 9d2b7b795c198a8dd1563fc4ee20b9302b8f899d SHA1 f748425d15ef0338f55309538fb4cd15077eb662 SHA256 5bb9372b428fcbfd7573e232d835aca4bb23d1f8dfc21e6b94fb0bf6ef992be2
-MISC ChangeLog 71124 RMD160 e5dd79369838fc2dc9c80ccd6030c3d2cbd88e48 SHA1 1ba99f14ff398e4e4d8b3c9d8b4f40c1529c7f65 SHA256 c72fe5c113d99945f8d2b13939c7a64fd40b0ba008ec49e949fcfa44387632dc
+MISC ChangeLog 71285 RMD160 a2795dcd07339acd6cdafb31c7faec38b451909c SHA1 8350096d192c6a9fa28c11f48507cf42a202c1e8 SHA256 9b72edc80fbc135a47e78fee5acb0f0047f83811c5baf773f6e0fb36b53614ee
 MISC metadata.xml 1609 RMD160 80bd2234e48fccd7a442fd6cce3ad9e2f8a05d33 SHA1 0b3b2f486530e009fbe055a87d58a161722f64b1 SHA256 2450bc31e647972be38e76068c6cf27c34e00cd8077f139a137f9d4c14d52a0b
diff --git a/dev-vcs/git/git-1.7.3.2-r1.ebuild b/dev-vcs/git/git-1.7.3.2-r1.ebuild
new file mode 100644
index 000000000000..978e5b90b650
--- /dev/null
+++ b/dev-vcs/git/git-1.7.3.2-r1.ebuild
@@ -0,0 +1,458 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/git/git-1.7.3.2-r1.ebuild,v 1.1 2010/10/26 21:06:34 robbat2 Exp $
+
+EAPI=3
+
+GENTOO_DEPEND_ON_PERL=no
+inherit toolchain-funcs eutils elisp-common perl-module bash-completion
+[ "$PV" == "9999" ] && inherit git
+
+MY_PV="${PV/_rc/.rc}"
+MY_P="${PN}-${MY_PV}"
+
+DOC_VER=${MY_PV}
+
+DESCRIPTION="GIT - the stupid content tracker, the revision control system heavily used by the Linux kernel team"
+HOMEPAGE="http://www.git-scm.com/"
+if [ "$PV" != "9999" ]; then
+	SRC_URI="mirror://kernel/software/scm/git/${MY_P}.tar.bz2
+			mirror://kernel/software/scm/git/${PN}-manpages-${DOC_VER}.tar.bz2
+			doc? ( mirror://kernel/software/scm/git/${PN}-htmldocs-${DOC_VER}.tar.bz2 )"
+	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~sparc-fbsd ~x86-fbsd ~x86-freebsd ~ia64-hpux ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+else
+	SRC_URI=""
+	EGIT_BRANCH="master"
+	EGIT_REPO_URI="git://git.kernel.org/pub/scm/git/git.git"
+	# EGIT_REPO_URI="http://www.kernel.org/pub/scm/git/git.git"
+	KEYWORDS="~ppc ~ppc64"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+blksha1 +curl cgi doc emacs gtk iconv +perl ppcsha1 tk +threads +webdav xinetd cvs subversion"
+
+# Common to both DEPEND and RDEPEND
+CDEPEND="
+	!blksha1? ( dev-libs/openssl )
+	sys-libs/zlib
+	perl?   ( dev-lang/perl[-build] )
+	tk?     ( dev-lang/tk )
+	curl?   (
+		net-misc/curl
+		webdav? ( dev-libs/expat )
+	)
+	emacs?  ( virtual/emacs )"
+
+RDEPEND="${CDEPEND}
+	perl? ( dev-perl/Error
+			dev-perl/Net-SMTP-SSL
+			dev-perl/Authen-SASL
+			cgi? ( virtual/perl-CGI )
+			cvs? ( >=dev-vcs/cvsps-2.1 dev-perl/DBI dev-perl/DBD-SQLite )
+			subversion? ( dev-vcs/subversion[-dso,perl] dev-perl/libwww-perl dev-perl/TermReadKey )
+			)
+	gtk?
+	(
+		>=dev-python/pygtk-2.8
+		|| ( dev-python/pygtksourceview:2  dev-python/gtksourceview-python )
+	)"
+
+# This is how info docs are created with Git:
+#   .txt/asciidoc --(asciidoc)---------> .xml/docbook
+#   .xml/docbook  --(docbook2texi.pl)--> .texi
+#   .texi         --(makeinfo)---------> .info
+DEPEND="${CDEPEND}
+	app-arch/cpio
+	doc?    (
+		app-text/asciidoc
+		app-text/docbook2X
+		sys-apps/texinfo
+	)"
+
+# Live ebuild builds HTML docs, additionally
+if [ "$PV" == "9999" ]; then
+	DEPEND="${DEPEND}
+		doc?    (
+			app-text/xmlto
+		)"
+fi
+
+SITEFILE=50${PN}-gentoo.el
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	if ! use perl ; then
+		use cgi && ewarn "gitweb needs USE=perl, ignoring USE=cgi"
+		use cvs && ewarn "CVS integration needs USE=perl, ignoring USE=cvs"
+		use subversion && ewarn "git-svn needs USE=perl, it won't work"
+	fi
+	if use webdav && ! use curl ; then
+		ewarn "USE=webdav needs USE=curl. Ignoring"
+	fi
+	if use subversion && has_version dev-vcs/subversion && built_with_use --missing false dev-vcs/subversion dso ; then
+		ewarn "Per Gentoo bugs #223747, #238586, when subversion is built"
+		ewarn "with USE=dso, there may be weird crashes in git-svn. You"
+		ewarn "have been warned."
+	fi
+}
+
+# This is needed because for some obscure reasons future calls to make don't
+# pick up these exports if we export them in src_unpack()
+exportmakeopts() {
+	local myopts
+
+	if use blksha1 ; then
+		myopts="${myopts} BLK_SHA1=YesPlease"
+	elif use ppcsha1 ; then
+		myopts="${myopts} PPC_SHA1=YesPlease"
+	fi
+
+	if use curl ; then
+		use webdav || myopts="${myopts} NO_EXPAT=YesPlease"
+	else
+		myopts="${myopts} NO_CURL=YesPlease"
+	fi
+
+	# broken assumptions, because of broken build system ...
+	myopts="${myopts} NO_FINK=YesPlease NO_DARWIN_PORTS=YesPlease"
+	myopts="${myopts} INSTALL=install TAR=tar"
+	myopts="${myopts} SHELL_PATH=${EPREFIX}/bin/sh"
+	myopts="${myopts} SANE_TOOL_PATH="
+	myopts="${myopts} OLD_ICONV="
+	myopts="${myopts} NO_EXTERNAL_GREP="
+
+	# can't define this to null, since the entire makefile depends on it
+	sed -i -e '/\/usr\/local/s/BASIC_/#BASIC_/' Makefile
+
+	use iconv \
+		|| einfo "Forcing iconv for ${PVR} due to bugs #321895, #322205."
+	#	|| myopts="${myopts} NO_ICONV=YesPlease"
+	# because, above, we need to do this unconditionally (no "&& use iconv")
+	use !elibc_glibc && myopts="${myopts} NEEDS_LIBICONV=YesPlease"
+
+	use tk \
+		|| myopts="${myopts} NO_TCLTK=YesPlease"
+	use perl \
+		&& myopts="${myopts} INSTALLDIRS=vendor" \
+		|| myopts="${myopts} NO_PERL=YesPlease"
+	use threads \
+		&& myopts="${myopts} THREADED_DELTA_SEARCH=YesPlease"
+	use subversion \
+		|| myopts="${myopts} NO_SVN_TESTS=YesPlease"
+# Disabled until ~m68k-mint can be keyworded again
+#	if [[ ${CHOST} == *-mint* ]] ; then
+#		myopts="${myopts} NO_MMAP=YesPlease"
+#		myopts="${myopts} NO_IPV6=YesPlease"
+#		myopts="${myopts} NO_STRLCPY=YesPlease"
+#		myopts="${myopts} NO_MEMMEM=YesPlease"
+#		myopts="${myopts} NO_MKDTEMP=YesPlease"
+#		myopts="${myopts} NO_MKSTEMPS=YesPlease"
+#	fi
+	if [[ ${CHOST} == ia64-*-hpux* ]]; then
+		myopts="${myopts} NO_NSEC=YesPlease"
+	fi
+
+	has_version '>=app-text/asciidoc-8.0' \
+		&& myopts="${myopts} ASCIIDOC8=YesPlease"
+	myopts="${myopts} ASCIIDOC_NO_ROFF=YesPlease"
+
+	# Bug 290465:
+	# builtin-fetch-pack.c:816: error: 'struct stat' has no member named 'st_mtim'
+	[[ "${CHOST}" == *-uclibc* ]] && \
+		myopts="${myopts} NO_NSEC=YesPlease"
+
+	export MY_MAKEOPTS="${myopts}"
+}
+
+src_unpack() {
+	if [ "${PV}" != "9999" ]; then
+		unpack ${MY_P}.tar.bz2
+		cd "${S}"
+		unpack ${PN}-manpages-${DOC_VER}.tar.bz2
+		use doc && \
+			cd "${S}"/Documentation && \
+			unpack ${PN}-htmldocs-${DOC_VER}.tar.bz2
+		cd "${S}"
+	else
+		git_src_unpack
+		cd "${S}"
+		#cp "${FILESDIR}"/GIT-VERSION-GEN .
+	fi
+
+}
+
+src_prepare() {
+	# Noperl is being merged to upstream as of 2009/04/05
+	#epatch "${FILESDIR}"/20090305-git-1.6.2-noperl.patch
+
+	# GetOpt-Long v2.38 is strict
+	# Merged in 1.6.3 final 2009/05/07
+	#epatch "${FILESDIR}"/20090505-git-1.6.2.5-getopt-fixes.patch
+
+	# JS install fixup
+	epatch "${FILESDIR}"/git-1.7.2-always-install-js.patch
+
+	# USE=-iconv causes segfaults, fixed post 1.7.1
+	# Gentoo bug #321895
+	#epatch "${FILESDIR}"/git-1.7.1-noiconv-segfault-fix.patch
+
+	sed -i \
+		-e 's:^\(CFLAGS =\).*$:\1 $(OPTCFLAGS) -Wall:' \
+		-e 's:^\(LDFLAGS =\).*$:\1 $(OPTLDFLAGS):' \
+		-e 's:^\(CC = \).*$:\1$(OPTCC):' \
+		-e 's:^\(AR = \).*$:\1$(OPTAR):' \
+		-e "s:\(PYTHON_PATH = \)\(.*\)$:\1${EPREFIX}\2:" \
+		-e "s:\(PERL_PATH = \)\(.*\)$:\1${EPREFIX}\2:" \
+		Makefile || die "sed failed"
+
+	# Never install the private copy of Error.pm (bug #296310)
+	sed -i \
+		-e '/private-Error.pm/s,^,#,' \
+		perl/Makefile.PL
+
+	# Fix docbook2texi command
+	sed -i 's/DOCBOOK2X_TEXI=docbook2x-texi/DOCBOOK2X_TEXI=docbook2texi.pl/' \
+		Documentation/Makefile || die "sed failed"
+
+	# bug #318289
+	epatch "${FILESDIR}"/git-1.7.3.2-interix.patch
+}
+
+git_emake() {
+	emake ${MY_MAKEOPTS} \
+		DESTDIR="${D}" \
+		OPTCFLAGS="${CFLAGS}" \
+		OPTLDFLAGS="${LDFLAGS}" \
+		OPTCC="$(tc-getCC)" \
+		OPTAR="$(tc-getAR)" \
+		prefix="${EPREFIX}"/usr \
+		htmldir="${EPREFIX}"/usr/share/doc/${PF}/html \
+		sysconfdir="${EPREFIX}"/etc \
+		"$@"
+}
+
+src_configure() {
+	exportmakeopts
+}
+
+src_compile() {
+	git_emake || die "emake failed"
+
+	if use emacs ; then
+		elisp-compile contrib/emacs/git{,-blame}.el \
+			|| die "emacs modules failed"
+	fi
+
+	if use perl && use cgi ; then
+		git_emake \
+			gitweb/gitweb.cgi \
+			|| die "emake gitweb/gitweb.cgi failed"
+	fi
+
+	cd "${S}"/Documentation
+	if [[ "$PV" == "9999" ]] ; then
+		git_emake man \
+			|| die "emake man failed"
+		if use doc ; then
+			git_emake info html \
+				|| die "emake info html failed"
+		fi
+	else
+		if use doc ; then
+			git_emake info \
+				|| die "emake info html failed"
+		fi
+	fi
+}
+
+src_install() {
+	git_emake \
+		install || \
+		die "make install failed"
+
+	doman man?/*.[157] Documentation/*.[157]
+
+	dodoc README Documentation/{SubmittingPatches,CodingGuidelines}
+	use doc && dodir /usr/share/doc/${PF}/html
+	for d in / /howto/ /technical/ ; do
+		docinto ${d}
+		dodoc Documentation${d}*.txt
+		use doc && dohtml -p ${d} Documentation${d}*.html
+	done
+	docinto /
+	# Upstream does not ship this pre-built :-(
+	use doc && doinfo Documentation/{git,gitman}.info
+
+	dobashcompletion contrib/completion/git-completion.bash ${PN}
+
+	if use emacs ; then
+		elisp-install ${PN} contrib/emacs/git.{el,elc} || die
+		elisp-install ${PN} contrib/emacs/git-blame.{el,elc} || die
+		#elisp-install ${PN}/compat contrib/emacs/vc-git.{el,elc} || die
+		# don't add automatically to the load-path, so the sitefile
+		# can do a conditional loading
+		touch "${ED}${SITELISP}/${PN}/compat/.nosearch"
+		elisp-site-file-install "${FILESDIR}"/${SITEFILE} || die
+	fi
+
+	if use gtk ; then
+		dobin "${S}"/contrib/gitview/gitview
+		dodoc "${S}"/contrib/gitview/gitview.txt
+	fi
+
+	dobin contrib/fast-import/git-p4
+	dodoc contrib/fast-import/git-p4.txt
+	newbin contrib/fast-import/import-tars.perl import-tars
+	newbin contrib/git-resurrect.sh git-resurrect
+
+	dodir /usr/share/${PN}/contrib
+	# The following are excluded:
+	# completion - installed above
+	# emacs - installed above
+	# examples - these are stuff that is not used in Git anymore actually
+	# gitview - installed above
+	# p4import - excluded because fast-import has a better one
+	# patches - stuff the Git guys made to go upstream to other places
+	# svnimport - use git-svn
+	# thunderbird-patch-inline - fixes thunderbird
+	for i in \
+		blameview buildsystems ciabot continuous convert-objects fast-import \
+		git-shell-commands hg-to-git hooks remotes2config.sh remotes2config.sh \
+		rerere-train.sh stats svn-fe vim workdir \
+		; do
+		cp -rf \
+			"${S}"/contrib/${i} \
+			"${ED}"/usr/share/${PN}/contrib \
+			|| die "Failed contrib ${i}"
+	done
+
+	if use perl && use cgi ; then
+		exeinto /usr/share/${PN}/gitweb
+		doexe "${S}"/gitweb/gitweb.cgi
+		insinto /usr/share/${PN}/gitweb/static
+		doins "${S}"/gitweb/static/gitweb.css
+		js=gitweb.js
+		[ -f "${S}"/gitweb/static/gitweb.min.js ] && js=gitweb.min.js
+		doins "${S}"/gitweb/static/${js}
+		doins "${S}"/gitweb/static/git-{favicon,logo}.png
+
+		# INSTALL discusses configuration issues, not just installation
+		docinto /
+		newdoc  "${S}"/gitweb/INSTALL INSTALL.gitweb
+		newdoc  "${S}"/gitweb/README README.gitweb
+
+		find "${ED}"/usr/lib64/perl5/ \
+			-name .packlist \
+			-exec rm \{\} \;
+	fi
+	if ! use subversion ; then
+		rm -f "${ED}"/usr/libexec/git-core/git-svn \
+			"${ED}"/usr/share/man/man1/git-svn.1*
+	fi
+
+	if use xinetd ; then
+		insinto /etc/xinetd.d
+		newins "${FILESDIR}"/git-daemon.xinetd git-daemon
+	fi
+
+	newinitd "${FILESDIR}"/git-daemon.initd git-daemon
+	newconfd "${FILESDIR}"/git-daemon.confd git-daemon
+
+	fixlocalpod
+}
+
+src_test() {
+	local disabled=""
+	local tests_cvs="t9200-git-cvsexportcommit.sh \
+					t9400-git-cvsserver-server.sh \
+					t9401-git-cvsserver-crlf.sh \
+					t9600-cvsimport.sh \
+					t9601-cvsimport-vendor-branch.sh \
+					t9602-cvsimport-branches-tags.sh \
+					t9603-cvsimport-patchsets.sh"
+	local tests_perl="t5502-quickfetch.sh \
+					t5512-ls-remote.sh \
+					t5520-pull.sh"
+	# Bug #225601 - t0004 is not suitable for root perm
+	# Bug #219839 - t1004 is not suitable for root perm
+	# t0001-init.sh - check for init notices EPERM*  fails
+	local tests_nonroot="t0001-init.sh \
+		t0004-unwritable.sh \
+		t1004-read-tree-m-u-wf.sh \
+		t3700-add.sh \
+		t7300-clean.sh"
+
+	# Unzip is used only for the testcase code, not by any normal parts of Git.
+	if ! has_version app-arch/unzip ; then
+		einfo "Disabling tar-tree tests"
+		disabled="${disabled} t5000-tar-tree.sh"
+	fi
+
+	cvs=0
+	use cvs && let cvs=$cvs+1
+	if [[ ${EUID} -eq 0 ]]; then
+		if [[ $cvs -eq 1 ]]; then
+			ewarn "Skipping CVS tests because CVS does not work as root!"
+			ewarn "You should retest with FEATURES=userpriv!"
+			disabled="${disabled} ${tests_cvs}"
+		fi
+		einfo "Skipping other tests that require being non-root"
+		disabled="${disabled} ${tests_nonroot}"
+	else
+		[[ $cvs -gt 0 ]] && \
+			has_version dev-vcs/cvs && \
+			let cvs=$cvs+1
+		[[ $cvs -gt 1 ]] && \
+			built_with_use dev-vcs/cvs server && \
+			let cvs=$cvs+1
+		if [[ $cvs -lt 3 ]]; then
+			einfo "Disabling CVS tests (needs dev-vcs/cvs[USE=server])"
+			disabled="${disabled} ${tests_cvs}"
+		fi
+	fi
+
+	if ! use perl ; then
+		einfo "Disabling tests that need Perl"
+		disabled="${disabled} ${tests_perl}"
+	fi
+
+	# Reset all previously disabled tests
+	cd "${S}/t"
+	for i in *.sh.DISABLED ; do
+		[[ -f "${i}" ]] && mv -f "${i}" "${i%.DISABLED}"
+	done
+	einfo "Disabled tests:"
+	for i in ${disabled} ; do
+		[[ -f "${i}" ]] && mv -f "${i}" "${i}.DISABLED" && einfo "Disabled $i"
+	done
+	cd "${S}"
+	# Now run the tests
+	einfo "Start test run"
+	git_emake \
+		test || die "tests failed"
+}
+
+showpkgdeps() {
+	local pkg=$1
+	shift
+	elog "  $(printf "%-17s:" ${pkg}) ${@}"
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+	if use subversion && has_version dev-vcs/subversion && ! built_with_use --missing false dev-vcs/subversion perl ; then
+		ewarn "You must build dev-vcs/subversion with USE=perl"
+		ewarn "to get the full functionality of git-svn!"
+	fi
+	elog "These additional scripts need some dependencies:"
+	echo
+	showpkgdeps git-quiltimport "dev-util/quilt"
+	showpkgdeps git-instaweb \
+		"|| ( www-servers/lighttpd www-servers/apache )"
+	echo
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}