bump a new snapshot

Package-Manager: portage-2.2_rc67/cvs/Linux x86_64

1 files changed, 61 insertions, 0 deletions

diff --git a/media-libs/x264/x264-0.0.20100605.ebuild b/media-libs/x264/x264-0.0.20100605.ebuild
new file mode 100644
index 000000000000..08145ca6f902
--- /dev/null
+++ b/media-libs/x264/x264-0.0.20100605.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/x264/x264-0.0.20100605.ebuild,v 1.1 2010/06/06 10:37:33 aballier Exp $
+
+EAPI=2
+inherit eutils multilib toolchain-funcs versionator
+
+MY_P=x264-snapshot-$(get_version_component_range 3)-2245
+
+DESCRIPTION="A free library for encoding X264/AVC streams"
+HOMEPAGE="http://www.videolan.org/developers/x264.html"
+SRC_URI="ftp://ftp.videolan.org/pub/videolan/x264/snapshots/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="debug +threads pic"
+
+RDEPEND=""
+DEPEND="amd64? ( >=dev-lang/yasm-0.6.2 )
+	x86? ( >=dev-lang/yasm-0.6.2 )
+	x86-fbsd? ( >=dev-lang/yasm-0.6.2 )"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-nostrip.patch \
+		"${FILESDIR}"/${PN}-onlylib-20100605.patch
+}
+
+src_configure() {
+	tc-export CC
+
+	local myconf=""
+	use debug && myconf="${myconf} --enable-debug"
+
+	if use x86 && use pic; then
+		myconf="${myconf} --disable-asm"
+	fi
+
+	./configure \
+		--prefix=/usr \
+		--libdir=/usr/$(get_libdir) \
+		--disable-avs-input \
+		--disable-lavf-input \
+		--disable-mp4-output \
+		$(use_enable threads pthread) \
+		--enable-pic \
+		--enable-shared \
+		--extra-asflags="${ASFLAGS}" \
+		--extra-cflags="${CFLAGS}" \
+		--extra-ldflags="${LDFLAGS}" \
+		--host="${CHOST}" \
+		${myconf} \
+		|| die
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+	dodoc AUTHORS doc/*.txt
+}