Fix MAX_PATH to be the same as the system. Bug #299385

Package-Manager: portage-2.2_rc61/cvs/Linux x86_64

3 files changed, 329 insertions, 3 deletions

diff --git a/sys-apps/hal/ChangeLog b/sys-apps/hal/ChangeLog
index a7cbbb9260ff..3904f7f5097c 100644
--- a/sys-apps/hal/ChangeLog
+++ b/sys-apps/hal/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sys-apps/hal
-# Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/hal/ChangeLog,v 1.311 2009/12/13 18:46:24 nirbheek Exp $
+# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/hal/ChangeLog,v 1.312 2010/01/07 13:28:04 dang Exp $
+
+*hal-0.5.14-r1 (07 Jan 2010)
+
+  07 Jan 2010; Daniel Gryniewicz <dang@gentoo.org> +hal-0.5.14-r1.ebuild:
+  Fix MAX_PATH to be the same as the system. Bug #299385
+
 
   13 Dec 2009; Nirbheek Chauhan <nirbheek@gentoo.org> hal-0.5.14.ebuild:
   Fix blockers due to a combination of hal[consolekit,-policykit] and polkit
diff --git a/sys-apps/hal/Manifest b/sys-apps/hal/Manifest
index 816822b68679..ba3e1a994fde 100644
--- a/sys-apps/hal/Manifest
+++ b/sys-apps/hal/Manifest
@@ -9,12 +9,14 @@ DIST hal-0.5.12rc1.tar.bz2 1160384 RMD160 dce660d600c18bfd910814516b675f141d3698
 DIST hal-0.5.13-gentoo-patches-1.tar.bz2 4049 RMD160 82aa03e2c99a92aadd68f6ada69cc2b06b2371e2 SHA1 546d6752147535607e34ebcb622aabc2948ed13a SHA256 0354b295a4b5f520a28030bb1282101dac9556326648b91c7ca7045ad5a559d6
 DIST hal-0.5.13.tar.bz2 918835 RMD160 34537d5f8bfb96c52ca066e787282b354179eb8f SHA1 788485fa78b2aa7a9d6b7de537a68ceff1564420 SHA256 d47c9799c18929cffbce5bfa48f35c89657d7f630c6da682f193928697c71ab5
 DIST hal-0.5.14-gentoo-patches-1.tar.bz2 4379 RMD160 ecaec00d31ef2009caf8258c3f406deeaef6816a SHA1 27a849a75a930f344aba4a41f7e724f697fc4d87 SHA256 65d3a42d333f2f5a9392d58b124e9009cc399f9019bfef9237ca9f648f050732
+DIST hal-0.5.14-gentoo-patches-2.tar.bz2 4491 RMD160 d8d4c55210d440b21383d931f76a476032df8e02 SHA1 bceb3836f3a480d6c674c7f8bd324fdaf7d23eec SHA256 0f56bb5ab7684723aea06c315f9df1004200413d6cc6336df0adcb96beb8d37e
 DIST hal-0.5.14.tar.bz2 942954 RMD160 0314dace9512bf49a62bd1556963fc60a6c9caf9 SHA1 a6ec098d78112e18e2773afa5f9ed642b00c4c59 SHA256 c4c5ecc5d50d5d9c061dc06c405461b1f71c12f2c60ed062350b2e6db2f1c51e
 EBUILD hal-0.5.11-r9.ebuild 8893 RMD160 82350f2795c3be604aabd4d67fefbf45b98a742e SHA1 1f47d075d01d759b7bf287ba3f4b4bb8cad19b2d SHA256 af6589feba9fb9395f7d1e23bede156800fe3a870b94750c48c31c6a5572e5e8
 EBUILD hal-0.5.12_rc1-r6.ebuild 9821 RMD160 3861e904a70e10534fbde7af2c2c88f46f154c5d SHA1 c91f15233b0af3fd5661ae66a58646317d9a606e SHA256 f367e528a48ecdf93bd1334299462ec093e8674810b567ceaa9b747f9038b634
 EBUILD hal-0.5.12_rc1-r7.ebuild 9769 RMD160 95a92aa81f15944ef2f10b425933f2dfb5418dbb SHA1 bc45ad8afdadf32cf745cb417d3dd14cac55edf7 SHA256 818095452fa1458bc069a3fbb56f853ee91bfa4208d04706e5b471e242f0af3d
 EBUILD hal-0.5.12_rc1-r8.ebuild 9668 RMD160 54494d2f817d932db9350595e81a9870870d6809 SHA1 1bf9009c77de925fed98f2817ebe0b5a85260abb SHA256 83a08f6d6827ca290cfaca916119f8be8f7842db965e614114f97aff492b4b6f
 EBUILD hal-0.5.13-r2.ebuild 9793 RMD160 dcd8f938dccd0decc0134a06be9a628ea5c0954e SHA1 c3f8d1beb9ed79d885da59bd97294d4795e42775 SHA256 a35466fa8b1cfee9963fe72aef729a28c3528ee10dd59bf87d3175e033c09757
+EBUILD hal-0.5.14-r1.ebuild 9864 RMD160 1240479f004973aeef8c23677563e618b1f1a56a SHA1 b0b89e2a47593047eb979dafa77b1d1a5b3c4fa3 SHA256 12d35778c646e50ef617864cc77c404b26bf688aa099abcc3bfe307827824851
 EBUILD hal-0.5.14.ebuild 9865 RMD160 5f2c448e12431680ef3691fc0df49889f45fef1b SHA1 64dcc78ddda9c8a455fa5910203ce8bbfd5a5554 SHA256 9af3aa58cbad6ae47ee67b3da8e205c13c0a0c1113f85c7d0db181f5a587c5a4
-MISC ChangeLog 55234 RMD160 08a3aa8f5524fbef2c29687b5a5b69a96f2fbdcc SHA1 7ef030808123edfa6ef96ca123314fa339268415 SHA256 54e0ceb360ede4efbf78c3a4a35e464112782502be6cac9d123806ec88c79b4b
+MISC ChangeLog 55393 RMD160 c5bf294d6bffd9c0555d98ea7562442a8943b22a SHA1 e194644fa322dba8aa455d5867bc37b721d97937 SHA256 b31fc0272f97a41435e50c45fe1b70d83f5381a6680129f11303a05bbc8f78d7
 MISC metadata.xml 2017 RMD160 90b6fed11f5582fce64fe36354e94b811478d21e SHA1 2b2693c7d677adf363e41e16cc71787fbe01d383 SHA256 910ab10f73ca0bccdea716f39dd3d3cc3d594bd25f6bbb7e25b70082be194048
diff --git a/sys-apps/hal/hal-0.5.14-r1.ebuild b/sys-apps/hal/hal-0.5.14-r1.ebuild
new file mode 100644
index 000000000000..3637fbf14430
--- /dev/null
+++ b/sys-apps/hal/hal-0.5.14-r1.ebuild
@@ -0,0 +1,318 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/hal/hal-0.5.14-r1.ebuild,v 1.1 2010/01/07 13:28:04 dang Exp $
+
+EAPI="2"
+
+inherit eutils linux-info autotools flag-o-matic multilib
+
+PATCH_VERSION="2"
+
+MY_P=${P/_/}
+S=${WORKDIR}/${MY_P}
+PATCHNAME="${MY_P}-gentoo-patches-${PATCH_VERSION}"
+DESCRIPTION="Hardware Abstraction Layer"
+HOMEPAGE="http://www.freedesktop.org/wiki/Software/hal"
+SRC_URI="http://hal.freedesktop.org/releases/${MY_P}.tar.bz2
+	 http://dev.gentoo.org/~dang/files/${PATCHNAME}.tar.bz2"
+
+LICENSE="|| ( GPL-2 AFL-2.0 )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 -x86-fbsd"
+
+KERNEL_IUSE="kernel_linux kernel_FreeBSD"
+IUSE="X acpi apm crypt consolekit debug dell disk-partition doc laptop policykit selinux ${KERNEL_IUSE}"
+
+RDEPEND=">=dev-libs/dbus-glib-0.61
+		 >=dev-libs/glib-2.14
+		 >=dev-libs/expat-1.95.8
+		 =virtual/libusb-0*
+		 >=sys-apps/pciutils-2.2.7-r1
+		   sys-apps/usbutils
+		   virtual/eject
+		 amd64? ( >=sys-apps/dmidecode-2.7 )
+		 dell? ( >=sys-libs/libsmbios-0.13.4 )
+		 disk-partition? ( >=sys-apps/parted-1.8.0 )
+		 ia64? ( >=sys-apps/dmidecode-2.7 )
+		 kernel_linux?	(
+							>=sys-fs/udev-125
+							>=sys-apps/util-linux-2.16
+							>=sys-kernel/linux-headers-2.6.22
+							crypt?	( >=sys-fs/cryptsetup-1.0.5 )
+						)
+		 kernel_FreeBSD? ( >=dev-libs/libvolume_id-0.77 )
+		 x86? ( >=sys-apps/dmidecode-2.7 )
+		 selinux? ( sys-libs/libselinux sec-policy/selinux-hal )
+		 consolekit?	(
+		 					|| (
+									<sys-auth/consolekit-0.4[policykit=]
+		 							>=sys-auth/consolekit-0.4
+								)
+					)
+		 policykit?	(
+		 					sys-auth/consolekit[policykit]
+							sys-auth/policykit[pam]
+		 			)"
+DEPEND="${RDEPEND}
+		dev-util/pkgconfig
+		 >=dev-util/gperf-3.0.3
+		>=dev-util/intltool-0.35
+		doc?	(
+					app-text/xmlto
+					dev-libs/libxml2
+					dev-util/gtk-doc
+					app-text/docbook-sgml-utils
+				)"
+PDEPEND=">=app-misc/hal-info-20081219
+	!gnome-extra/hal-device-manager
+	laptop? ( >=sys-power/pm-utils-0.99.3 )"
+
+## HAL Daemon drops privledges so we need group access to read disks
+HALDAEMON_GROUPS_LINUX="haldaemon,plugdev,disk,cdrom,cdrw,floppy,usb"
+HALDAEMON_GROUPS_FREEBSD="haldaemon,plugdev,operator"
+
+function check_hotplug_net() {
+	local CONFIG_CHECK="~HOTPLUG ~NET"
+	local WARNING_HOTPLUG="CONFIG_HOTPLUG:\tis not set (required for HAL)\n"
+	local WARNING_NET="CONFIG_NET:\tis not set (required for HAL)\n"
+	check_extra_config
+}
+
+function check_inotify() {
+	local CONFIG_CHECK="~INOTIFY_USER"
+	local WARNING_INOTIFY_USER="CONFIG_INOTIFY_USER:\tis not set (required for HAL)\n"
+	check_extra_config
+}
+
+function check_acpi_proc() {
+	local CONFIG_CHECK="~ACPI_PROCFS ~ACPI_PROC_EVENT"
+	local WARNING_ACPI_PROCFS="CONFIG_ACPI_PROCFS:\tis not set (required for HAL)\n"
+	local WARNING_ACPI_PROC_EVENT="CONFIG_ACPI_PROC_EVENT:\tis not set (required for HAL)\n"
+	check_extra_config
+}
+
+pkg_setup() {
+	if use kernel_linux ; then
+		if [[ -e "${ROOT}/usr/src/linux/.config" ]] ; then
+			kernel_is ge 2 6 19 || ewarn "HAL requires a kernel version 2.6.19 or newer"
+
+			if kernel_is lt 2 6 23 && use acpi ; then
+				check_acpi_proc
+			fi
+		fi
+
+		check_hotplug_net
+		check_inotify
+	fi
+
+	# http://devmanual.gentoo.org/ebuild-writing/functions/
+	# http://bugs.gentoo.org/show_bug.cgi?id=191605
+
+	# Create groups for hotplugging and HAL
+	enewgroup haldaemon
+	enewgroup plugdev
+
+	# HAL drops priviledges by default now ...
+	# ... so we must make sure it can read disk/cdrom info (ie. be in ${HALDAEMON_GROUPS} groups)
+	if use kernel_linux; then
+		enewuser haldaemon -1 "-1" /dev/null ${HALDAEMON_GROUPS_LINUX}
+	elif use kernel_FreeBSD; then
+		enewuser haldaemon -1 "-1" /dev/null ${HALDAEMON_GROUPS_FREEBSD}
+	fi
+
+	# Make sure that the haldaemon user is in the ${HALDAEMON_GROUPS}
+	# If users have a problem with this, let them file a bug
+	if [[ ${ROOT} == / ]] ; then
+		if use kernel_linux; then
+			usermod -G ${HALDAEMON_GROUPS_LINUX} haldaemon
+		elif use kernel_FreeBSD; then
+			pw usermod haldaemon -G ${HALDAEMON_GROUPS_FREEBSD}
+		fi
+	fi
+}
+
+src_prepare() {
+	# Only apply one of the policy patches.  Bug #267042
+	if use policykit ; then
+		rm "${WORKDIR}/${PATCHNAME}/patches/0001-plugdev-dbus-policy.patch"
+	else
+		rm "${WORKDIR}/${PATCHNAME}/patches/0002-policykit-dbus-policy.patch"
+	fi
+
+	EPATCH_MULTI_MSG="Applying Gentoo Patchset ..." \
+	EPATCH_SUFFIX="patch" \
+	EPATCH_SOURCE="${WORKDIR}/${PATCHNAME}/patches/" \
+	EPATCH_FORCE="yes" \
+	epatch
+
+	eautoreconf
+}
+
+src_configure() {
+	local acpi="$(use_enable acpi)"
+	local backend=
+	local hardware=
+	local consolekit="$(use_enable consolekit console-kit)"
+
+	append-flags -rdynamic
+
+	if use kernel_linux ; then
+		backend="linux"
+	elif use kernel_FreeBSD ; then
+		backend="freebsd"
+	else
+		eerror "Invalid backend"
+	fi
+
+	if use kernel_linux ; then
+		if use acpi ; then
+			# Using IBM ACPI and Toshiba ACPI results in double notification as this
+			# was merged into the Linux Kernel 2.6.22
+			if kernel_is lt 2 6 22 ; then
+				acpi="$acpi --enable-acpi-ibm --enable-acpi-toshiba"
+			else
+				acpi="$acpi --disable-acpi-ibm --disable-acpi-toshiba"
+			fi
+
+			acpi="$acpi --enable-acpi-proc --enable-acpi-acpid"
+		else
+			acpi="$acpi --disable-acpi-ibm --disable-acpi-toshiba"
+			acpi="$acpi --disable-acpi-proc --disable-acpi-acpid"
+		fi
+
+		hardware="--with-cpufreq --with-usb-csr --with-keymaps"
+		use arm && hardware="$hardware --with-omap --enable-pmu"
+		use ppc && hardware="$hardware --enable-pmu"
+		if use x86 || use amd64; then
+			hardware="$hardware --with-macbook --with-macbookpro"
+		fi
+
+		if use dell ; then
+			hardware="$hardware --with-dell-backlight"
+		else
+			hardware="$hardware --without-dell-backlight"
+		fi
+
+		hardware="$hardware --enable-sonypic"
+	else
+		hardware="--without-cpufreq --without-usb-csr --without-keymaps"
+		hardware="$hardware --without-omap"
+		hardware="$hardware --without-dell-backlight"
+		hardware="$hardware --enable-acpi-ibm --enable-acpi-toshiba"
+		hardware="$hardware --disable-sonypic"
+	fi
+
+	# Policykit support depends on consolekit support.  Therefore, force on
+	# consolekit, even if it's USE flag is off, if policykit support is on.
+	# This enables packages to USE-depend on hal[policykit?]
+	if use policykit ; then
+		consolekit="--enable-console-kit"
+	fi
+
+	econf --with-backend=${backend} \
+		  --with-os-type=gentoo \
+		  --with-pid-file=/var/run/hald.pid \
+		  --with-hwdata=/usr/share/misc \
+		  --with-socket-dir=/var/run/hald \
+		  --with-udev-prefix=/etc \
+		  --enable-umount-helper \
+		  --enable-man-pages \
+		  --disable-acl-management \
+		  --enable-pci \
+		  $(use_enable apm) \
+		  $(use_enable debug verbose-mode) \
+		  $(use_enable disk-partition parted) \
+		  $(use_enable doc docbook-docs) \
+		  $(use_enable doc gtk-doc) \
+		  $(use_enable policykit policy-kit) \
+		  ${consolekit} \
+		  --docdir=/usr/share/doc/${PF} \
+		  --localstatedir=/var \
+		  ${acpi} ${hardware} \
+	|| die "configure failed"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+	dodoc AUTHORS ChangeLog NEWS README || die "docs failed"
+
+	# hal umount for unclean unmounts
+	exeinto /$(get_libdir)/udev/
+	newexe "${FILESDIR}/hal-unmount.dev" hal_unmount || die "udev helper failed"
+
+	# initscript
+	newinitd "${FILESDIR}/0.5.10-hald.rc" hald || die "init script failed"
+
+	# configuration
+	cp "${FILESDIR}/0.5.10-hald.conf" "${WORKDIR}/" || \
+		die "failed to copy hald.conf"
+
+	if use debug; then
+		sed -e 's:HALD_VERBOSE="no":HALD_VERBOSE="yes":' \
+			-i "${WORKDIR}/0.5.10-hald.conf" || die "failed to change verbose"
+	fi
+	newconfd "${WORKDIR}/0.5.10-hald.conf" hald || \
+		die "failed to install hald.conf"
+
+	if use X ; then
+		# New Configuration Snippets
+		dodoc "${WORKDIR}/${PATCHNAME}/config-examples/"*.fdi || \
+			die "dodoc X examples failed"
+	fi
+
+	# We now create and keep /media here as both gnome-mount and pmount
+	# use these directories, to avoid collision.
+	keepdir /media
+
+	# We also need to create and keep /etc/fdi/{information,policy,preprobe}
+	# or else hal bombs.
+	keepdir /etc/hal/fdi/{information,policy,preprobe}
+
+	# HAL stores it's fdi cache in /var/cache/hald
+	keepdir /var/cache/hald
+
+	# HAL keeps its unix socket here
+	keepdir /var/run/hald
+	keepdir /var/lib/hal
+}
+
+pkg_postinst() {
+	# Despite what people keep changing this location. Either one works.. it doesn't matter
+	# http://dev.gentoo.org/~plasmaroo/devmanual/ebuild-writing/functions/
+
+	elog "The HAL daemon needs to be running for certain applications to"
+	elog "work. Suggested is to add the init script to your start-up"
+	elog "scripts, this should be done like this :"
+	elog "\`rc-update add hald default\`"
+	echo
+	elog "Access to hal is not protected by either policykit or the plugdev group."
+	elog "If you have problems discovering/configuring hardware, try adding"
+	elog "yourself to plugdev."
+	echo
+	elog "IF you have additional applications which consume ACPI events, you"
+	elog "should consider installing acpid to allow applications to share ACPI"
+	elog "events."
+	if use X ; then
+		echo
+		elog "If you wish to use a non US layout, you may do so by executing:"
+		elog "setxkbmap <layout> or by utilizing your Desktop Environment's"
+		elog "Keyboard Layout Settings mechanism."
+		elog "Under GNOME, this is gnome-keyboard-properties, and under KDE"
+		elog "it is kxkb."
+	fi
+	echo
+	elog "In order have suspend/hibernate function with HAL or apps that use HAL"
+	elog "(such as gnome-power-manager), you should build HAL with the laptop"
+	elog "useflag which will install pm-utils."
+	if use X ; then
+		echo
+		elog "X Input Hotplugging (if you build xorg-server with the HAL useflag)"
+		elog "reads user specific configuration from /etc/hal/fdi/policy/."
+		echo
+		elog "You should remove the Input sections from your xorg.conf once you have"
+		elog "migrated the rules to a HAL fdi file."
+	fi
+
+	ebeep 5
+	epause 5
+}