Add fixes from upstream for grep regexp ranges #311885 by Martin von Gagern and for XZ support #269742 by Martin Väth.

Package-Manager: portage-2.2.0_alpha20/cvs/Linux x86_64

1 files changed, 50 insertions, 0 deletions

diff --git a/sys-apps/texinfo/texinfo-4.13-r1.ebuild b/sys-apps/texinfo/texinfo-4.13-r1.ebuild
new file mode 100644
index 000000000000..8c150ff3d9b0
--- /dev/null
+++ b/sys-apps/texinfo/texinfo-4.13-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/texinfo/texinfo-4.13-r1.ebuild,v 1.1 2011/02/10 03:42:03 vapier Exp $
+
+EAPI="2"
+
+inherit flag-o-matic
+
+DESCRIPTION="The GNU info program and utilities"
+HOMEPAGE="http://www.gnu.org/software/texinfo/"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.lzma"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~sparc-fbsd ~x86-fbsd"
+IUSE="nls static"
+
+RDEPEND="!=app-text/tetex-2*
+	>=sys-libs/ncurses-5.2-r2
+	nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	nls? ( sys-devel/gettext )"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-xz.patch #269742
+	epatch "${FILESDIR}"/${P}-texi2dvi-regexp-range.patch #311885
+}
+
+src_configure() {
+	use static && append-ldflags -static
+	econf $(use_enable nls)
+}
+
+src_compile() {
+	# Make cross-compiler safe (#196041)
+	if tc-is-cross-compiler ; then
+		emake -C tools/gnulib/lib || die
+	fi
+
+	emake || die
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+
+	dodoc AUTHORS ChangeLog INTRODUCTION NEWS README TODO
+	newdoc info/README README.info
+	newdoc makeinfo/README README.makeinfo
+}