Version bump.

Package-Manager: portage-2.2.0_alpha94/cvs/Linux x86_64

1 files changed, 55 insertions, 0 deletions

diff --git a/x11-libs/libdrm/libdrm-2.4.33.ebuild b/x11-libs/libdrm/libdrm-2.4.33.ebuild
new file mode 100644
index 000000000000..7059aff15537
--- /dev/null
+++ b/x11-libs/libdrm/libdrm-2.4.33.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-libs/libdrm/libdrm-2.4.33.ebuild,v 1.1 2012/03/29 12:24:24 chithanh Exp $
+
+EAPI=4
+inherit xorg-2
+
+EGIT_REPO_URI="git://anongit.freedesktop.org/git/mesa/drm"
+
+DESCRIPTION="X.Org libdrm library"
+HOMEPAGE="http://dri.freedesktop.org/"
+if [[ ${PV} = 9999* ]]; then
+	SRC_URI=""
+else
+	SRC_URI="http://dri.freedesktop.org/${PN}/${P}.tar.bz2"
+fi
+
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~x64-freebsd ~x86-freebsd ~amd64-linux ~x86-linux ~sparc-solaris ~x64-solaris ~x86-solaris"
+VIDEO_CARDS="intel nouveau omap radeon vmware"
+for card in ${VIDEO_CARDS}; do
+	IUSE_VIDEO_CARDS+=" video_cards_${card}"
+done
+
+IUSE="${IUSE_VIDEO_CARDS} libkms"
+RESTRICT="test" # see bug #236845
+
+RDEPEND="dev-libs/libpthread-stubs
+	video_cards_intel? ( >=x11-libs/libpciaccess-0.10 )"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2.4.28-solaris.patch
+)
+
+pkg_setup() {
+	XORG_CONFIGURE_OPTIONS=(
+		--enable-udev
+		$(use_enable video_cards_intel intel)
+		$(use_enable video_cards_nouveau nouveau-experimental-api)
+		$(use_enable video_cards_omap omap-experimental-api)
+		$(use_enable video_cards_radeon radeon)
+		$(use_enable video_cards_vmware vmwgfx-experimental-api)
+		$(use_enable libkms)
+	)
+
+	xorg-2_pkg_setup
+}
+
+src_prepare() {
+	if [[ ${PV} = 9999* ]]; then
+		# tests are restricted, no point in building them
+		sed -ie 's/tests //' "${S}"/Makefile.am
+	fi
+	xorg-2_src_prepare
+}