Fix Qt dep for bug 248038 and in the process fix bug 225117 by applying

suggested as-needed patch.
Package-Manager: portage-2.2_rc22/cvs/Linux 2.6.28-hh1 i686

1 files changed, 47 insertions, 0 deletions

diff --git a/x11-misc/qterm/qterm-0.5.2-r2.ebuild b/x11-misc/qterm/qterm-0.5.2-r2.ebuild
new file mode 100644
index 000000000000..f4b82fb9eca9
--- /dev/null
+++ b/x11-misc/qterm/qterm-0.5.2-r2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/qterm/qterm-0.5.2-r2.ebuild,v 1.1 2009/01/20 06:43:55 yngwin Exp $
+
+EAPI="1"
+inherit cmake-utils eutils
+
+DESCRIPTION="A BBS client for Linux"
+HOMEPAGE="http://qterm.sourceforge.net/"
+SRC_URI="mirror://sourceforge/qterm/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE=""
+
+RDEPEND="x11-libs/qt-gui:4
+	dev-libs/openssl"
+
+DEPEND="${RDEPEND}
+	>=dev-util/cmake-2.4.7"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	# bug #228225
+	epatch "${FILESDIR}/${P}-abs.patch"
+	# bug #225117
+	epatch "${FILESDIR}/${P}-as-needed.patch"
+	sed -i -e '/^Exec/s/qterm/QTerm/' src/qterm.desktop.in || die
+
+	# fix the broken language files
+	lrelease src/po/qterm_ch*.ts || die
+}
+
+src_install() {
+	cmake-utils_src_install
+	mv "${D}"/usr/bin/qterm "${D}"/usr/bin/QTerm || die
+	dodoc README TODO
+}
+
+pkg_postinst() {
+	elog
+	elog "Since 0.4.0-r1, /usr/bin/qterm has been renamed to /usr/bin/QTerm."
+	elog "Please see bug #176533 for more information."
+	elog
+}