1 files changed, 69 insertions, 0 deletions
diff --git a/app-editors/bluefish/bluefish-1.3.2.ebuild b/app-editors/bluefish/bluefish-1.3.2.ebuild
new file mode 100644
index 000000000000..75468c33d1ff
--- /dev/null
+++ b/app-editors/bluefish/bluefish-1.3.2.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-editors/bluefish/bluefish-1.3.2.ebuild,v 1.1 2009/02/22 11:42:01 hanno Exp $
+
+inherit eutils fdo-mime
+
+IUSE="nls spell gnome python"
+
+MY_P="${PN}-unstable-${PV}"
+
+DESCRIPTION="A GTK HTML editor for the experienced web designer or programmer."
+SRC_URI="http://www.bennewitz.com/bluefish/devel/source/${MY_P}.tar.bz2"
+HOMEPAGE="http://bluefish.openoffice.nl/"
+
+LICENSE="GPL-2"
+KEYWORDS="~alpha ~amd64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+SLOT="0"
+
+RDEPEND=">=x11-libs/gtk+-2
+	dev-libs/libpcre
+	spell? ( app-text/aspell )"
+
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	>=dev-libs/glib-2
+	x11-libs/pango
+	gnome-base/gnome-vfs
+	dev-libs/libxml2
+	nls? ( sys-devel/gettext )
+	gnome? ( gnome-base/libgnomeui )
+	python? ( dev-lang/python )"
+
+S="${WORKDIR}/${MY_P}"
+
+src_compile() {
+	econf --disable-update-databases \
+		--disable-xml-catalog-update \
+		$(use_enable nls) \
+		$(use_enable python) \
+		$(use_enable gnome libgnomeui) || die
+	emake || die
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+
+	einfo "Adding XML catalog entries..."
+	/usr/bin/xmlcatalog  --noout \
+		--add 'public' 'Bluefish/DTD/Bflang' 'bflang.dtd' \
+		--add 'system' 'http://bluefish.openoffice.nl/DTD/bflang.dtd' 'bflang.dtd' \
+		--add 'rewriteURI' 'http://bluefish.openoffice.nl/DTD' '/usr/share/xml/bluefish-unstable' \
+		/etc/xml/catalog \
+		|| ewarn "Failed to add XML catalog entries."
+}
+
+pkg_postrm() {
+	einfo "Removing XML catalog entries..."
+	/usr/bin/xmlcatalog  --noout \
+		--del 'Bluefish/DTD/Bflang' \
+		--del 'http://bluefish.openoffice.nl/DTD/bflang.dtd' \
+		--del 'http://bluefish.openoffice.nl/DTD' \
+		/etc/xml/catalog \
+		|| ewarn "Failed to remove XML catalog entries."
+}