1 files changed, 62 insertions, 0 deletions
diff --git a/app-misc/task/task-2.3.0-r1.ebuild b/app-misc/task/task-2.3.0-r1.ebuild
new file mode 100644
index 000000000000..7775046b5815
--- /dev/null
+++ b/app-misc/task/task-2.3.0-r1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-misc/task/task-2.3.0-r1.ebuild,v 1.1 2014/11/28 18:00:46 radhermit Exp $
+
+EAPI=5
+
+inherit eutils cmake-utils bash-completion-r1
+
+DESCRIPTION="Taskwarrior is a command-line todo list manager"
+HOMEPAGE="http://taskwarrior.org/"
+SRC_URI="http://taskwarrior.org/download/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86 ~x64-macos"
+IUSE="gnutls vim-syntax zsh-completion"
+
+DEPEND="gnutls? ( net-libs/gnutls )
+	sys-libs/readline
+	elibc_glibc? ( sys-apps/util-linux )"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	# use the correct directory locations
+	sed -i "s:/usr/local/bin:${EPREFIX}/usr/bin:" \
+		scripts/add-ons/* || die
+
+	# don't automatically install scripts
+	sed -i '/scripts/d' CMakeLists.txt || die
+
+	epatch "${FILESDIR}"/${P}-issue-1473-rcdir-fix.patch
+	epatch "${FILESDIR}"/${P}-gnutls-automagic.patch
+}
+
+src_configure() {
+	mycmakeargs=(
+		$(cmake-utils_use_use gnutls GNUTLS)
+		-DTASK_DOCDIR=share/doc/${PF}
+		-DTASK_RCDIR=share/${PN}/rc
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	newbashcomp scripts/bash/task.sh task
+
+	if use vim-syntax ; then
+		rm scripts/vim/README
+		insinto /usr/share/vim/vimfiles
+		doins -r scripts/vim/*
+	fi
+
+	if use zsh-completion ; then
+		insinto /usr/share/zsh/site-functions
+		doins scripts/zsh/*
+	fi
+
+	exeinto /usr/share/${PN}/scripts
+	doexe scripts/add-ons/*
+}