1 files changed, 37 insertions, 0 deletions
diff --git a/dev-python/qrcode/qrcode-3.1.ebuild b/dev-python/qrcode/qrcode-3.1.ebuild
new file mode 100644
index 000000000000..e03e6a2bc9fd
--- /dev/null
+++ b/dev-python/qrcode/qrcode-3.1.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/qrcode/qrcode-3.1.ebuild,v 1.1 2013/09/07 11:36:36 mgorny Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7} )
+
+inherit distutils-r1
+
+DESCRIPTION="QR Code generator on top of PIL"
+HOMEPAGE="https://pypi.python.org/pypi/qrcode"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+# optional deps:
+# - dev-python/lxml for svg backend
+# - virtual/pil for PIL backend
+RDEPEND="dev-python/six[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	test? (
+		dev-python/lxml[${PYTHON_USEDEP}]
+		virtual/python-unittest2[${PYTHON_USEDEP}] )"
+
+python_test() {
+	cd "${BUILD_DIR}"/lib || die
+
+	local m=unittest
+	[[ ${EPYTHON} == python2.6 ]] && m=unittest2.__main__
+	set -- "${PYTHON}" -m ${m} qrcode.tests
+	echo "$@" >&2
+	"$@" || die "Tests failed with ${EPYTHON}"
+}