1 files changed, 76 insertions, 0 deletions
diff --git a/kde-base/kde-l10n/kde-l10n-4.2.0.ebuild b/kde-base/kde-l10n/kde-l10n-4.2.0.ebuild
new file mode 100644
index 000000000000..2268f3023061
--- /dev/null
+++ b/kde-base/kde-l10n/kde-l10n-4.2.0.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/kde-base/kde-l10n/kde-l10n-4.2.0.ebuild,v 1.1 2009/01/27 19:21:26 alexxy Exp $
+
+EAPI="2"
+
+inherit kde4-base
+
+DESCRIPTION="KDE internationalization package"
+HOMEPAGE="http://www.kde.org/"
+LICENSE="GPL-2"
+
+DEPEND="sys-devel/gettext"
+RDEPEND=""
+
+KEYWORDS="~amd64 ~x86"
+IUSE="htmlhandbook"
+
+MY_LANGS="ar bg bn_IN ca cs csb da de el en_GB es et eu fi fr ga gl gu he hi hu
+		is it ja kk km kn ko ku lt lv mai mk ml mr nb nds nl nn pa pl pt pt_BR
+		ro ru sl sr sv tg th tr uk wa zh_CN zh_TW"
+
+URI_BASE="${SRC_URI/-${PV}.tar.bz2/}"
+SRC_URI=""
+
+for MY_LANG in ${MY_LANGS} ; do
+	IUSE="${IUSE} linguas_${MY_LANG}"
+	SRC_URI="${SRC_URI} linguas_${MY_LANG}? ( ${URI_BASE}/${PN}-${MY_LANG}-${PV}.tar.bz2 )"
+done
+
+S="${WORKDIR}"
+
+src_unpack() {
+	local LNG DIR
+	if [[ -z ${A} ]]; then
+		elog
+		elog "You either have the LINGUAS variable unset, or it only"
+		elog "contains languages not supported by ${P}."
+		elog "You won't have any additional language support."
+		elog
+		elog "${P} supports these language codes:"
+		elog "${MY_LANGS}"
+		elog
+	fi
+
+	[[ -n ${A} ]] && unpack ${A}
+	cd "${S}"
+
+	# add all linguas to cmake
+	if [[ -n ${A} ]]; then
+		for LNG in ${LINGUAS}; do
+			DIR="${PN}-${LNG}-${PV}"
+			if [[ -d "${DIR}" ]] ; then
+				echo "add_subdirectory( ${DIR} )" >> "${S}"/CMakeLists.txt
+				if ! use htmlhandbook; then
+					sed -i \
+						-e "/docs/ s:^:#DONOTWANT:" \
+						${DIR}/CMakeLists.txt \
+						|| die "Disabling docs for ${lng} failed."
+				fi
+			fi
+		done
+	fi
+}
+
+src_configure() {
+	[[ -n ${A} ]] && kde4-base_src_configure
+}
+
+src_compile() {
+	[[ -n ${A} ]] && kde4-base_src_compile
+}
+
+src_install() {
+	[[ -n ${A} ]] && kde4-base_src_install
+}