1 files changed, 45 insertions, 0 deletions
diff --git a/media-libs/libdv/libdv-1.0.0.ebuild b/media-libs/libdv/libdv-1.0.0.ebuild
new file mode 100644
index 000000000000..a2d7fec35250
--- /dev/null
+++ b/media-libs/libdv/libdv-1.0.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/libdv/libdv-1.0.0.ebuild,v 1.1 2006/09/25 21:46:46 vapier Exp $
+
+inherit eutils flag-o-matic libtool
+
+DESCRIPTION="Software codec for dv-format video (camcorders etc)"
+HOMEPAGE="http://libdv.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="debug gtk sdl xv"
+
+RDEPEND="dev-libs/popt
+	gtk? ( =x11-libs/gtk+-1.2* )
+	sdl? ( >=media-libs/libsdl-1.2.5 )
+	xv? ( x11-libs/libXv )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	gtk? ( x11-proto/xextproto x11-libs/libXt )"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+	epatch "${FILESDIR}"/${PN}-0.99-2.6.patch
+	elibtoolize
+	epunt_cxx #74497
+}
+
+src_compile() {
+	econf \
+		$(use_with debug) \
+		$(use_enable gtk) $(use_enable gtk gtktest) \
+		$(use_enable sdl) \
+		$(use_enable xv) \
+		|| die "econf failed"
+	emake || die "compile problem"
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die
+	dodoc AUTHORS ChangeLog INSTALL NEWS README* TODO
+}